Rotating 3D graphics inside Show separately by clicking and dragging

Question

Is there a way how to rotate by clicking and dragging just one of the 3D graphics inside Show?

For example rotating the cube without rotating the tetrahedron in this code:

Show[Graphics3D[{Opacity[0.5], Cube[]}, Boxed -> False], 
 Graphics3D[{Opacity[0.5], Tetrahedron[]}, Boxed -> False]]

I know how to do it by code, I just want to know whether there exist some parameter for Graphics3D that disables rotating by mouse, something like RotationDisable->True. And then one graphics would have RotationDisable->True and the other RotationDisable->False.

If there is no way how to do it for Show then what would be the easiest way to achieve rotating of cube by mouse while tetrahedron stays stationary?

Answer 1

angularSlider[Dynamic[angle_]] := 
 DynamicModule[{p = {1, 0}, angleCalc}, 
  LocatorPane[Dynamic[p, (angleCalc @@ Normalize /@ {#, p}) &], 
   Graphics[{Circle[], Arrowheads[0.15], Arrow[Dynamic[{{0, 0}, p}]]},
     ImageSize -> Tiny], Appearance -> None], 
  Initialization :> (angle = 0; 
    angleCalc[newp_, 
      oldp_] := (angle = 
       angle + ArcCos[newp.oldp] Sign[Cross[newp].(newp - oldp)]; 
      p = {Cos[angle], Sin[angle]}))]

Then using this code:

angularSlider[Dynamic[\[Theta]]]
Graphics3D[{Opacity[0.7], Cube[1/2], 
  GeometricTransformation[Tetrahedron[], 
   RotationMatrix[Dynamic[\[Theta]], {0, 1, 1}]]}, Boxed -> False, 
 SphericalRegion -> True, ViewVector -> {{3, 3, 3}, {0, 0, 0}}, 
 RotationAction -> "Clip", PlotRange -> 2]

You can rotate whole graphics with mouse as usually, plus you can rotate only tetrahedron using the mouse on the arrow inside circle.

Lots of code for a trivial thing to do... I think it should be implemented in Mathematica naturally to rotate graphics inside Show separately, because doing this by code is very cumbersome and still not as good as if rotated by mouse dragging straight on the graphics itself.