Solve this equality of permutations

Question

Is it possible to solve an equality such as:

$$(123)=\sigma (32) \sigma (31)$$

in term of $\sigma$? I was thinking about Cycles but I couldn't figure out a way to use it.

EDIT As a partial answer to my question, I have found that I can use PermutationProduct to solve manually the equality as follows:

p1 = Cycles[{{3, 2}}]
p2 = Cycles[{{3, 1}}]
s = Cycles[{{1, 3}}];
PermutationProduct[s, p1, s, p2]

giving $\sigma=(1,3)$. I would like to have an automatic solution if possible.

If you represent permutations as matrices you can reduce this to an integer linear programming problem. — Daniel Lichtblau, Mar 16 '21 at 13:43
@DanielLichtblau That's a start, but in the case I report in my question I should solve a linear system with 9 unknown and 3 equations. — mattiav27, Mar 16 '21 at 14:49
@mattiav27 How do you come with 9 unknowns. There are at most 6 permutations of 3 letters. — yarchik, Mar 16 '21 at 18:42
@yarchik thats true, but the 3X3 matrix has 9 entries: how do you decide which corresponds to 1 and which to 0? — mattiav27, Mar 16 '21 at 18:59
@mattiav27 There are constraints that the sum of elements of each row and column is 1, isn't it? — yarchik, Mar 16 '21 at 19:34

score 4 · Accepted Answer · answered Mar 16 '21 at 18:21

Riffing off of Daniel's suggestion in comments, and with the big caveat that I know little about permutations and their representation, I tried the following approach.

Generate matrix representations of the permutations:

pgen = Function[list, Permute[IdentityMatrix[3], Cycles[{list}]]];
{p123, p32, p31} = pgen /@ {{1, 2, 3}, {3, 2}, {3, 1}};

Select among all possible permutations of the appropriately chosen identity matrix those that satisfy the equation given:

results = Select[
   Permutations[IdentityMatrix[3]],
   p123 == p31.#.p32.# &
  ]
(* Out: {{{0, 0, 1}, {0, 1, 0}, {1, 0, 0}}} *)

Convert it back to Cycles representation:

FindPermutation[IdentityMatrix[3], #] & /@ results
(* Out: {Cycles[{{1, 3}}]} *)

Solve this equality of permutations

1 Answers1