Programming twisted pyramids based on polygon spirals

Question

I'm interested in polygonal spirals and after reading Filling Space with Pursuit Polygons, I was curious if I could extend the program to create twisted pyramids as 3D-objects. My goal is something like this picture:

although I would like to be able to vary parameters like shape of the chords from base to top (straight, concave or convex).

I already tried to draw objects like this in AutoCAD, but the process was rather tedious and I'm not yet knowledgeable enough in programming to do something like that from scratch. Here are some of my attempts:

I would also like to know if my red pyramid model would also be possible to be modelled with a script like that:

My approach to this model was different to the other two: instead of just connecting the corners with a point on the edge of the square the next level up to create the 4 lines winding up in a spiral and end up with a wire model, I tried to make a solid model by connecting the point of the next level up with all the adjacent corners below.

Thank you in advance!

Edit: I'm not asking you to write that code for me, I'm interested whether a script to create a polygon spiral can be used to create a 3D object with a simple extension to it.

Answer 1

Original

For two points a and b, we rotation and scale the segment t*a + (1 - t)*b in the plane and then lift it to space,all of the transformation according to the parametric θ.

we do the same thing for all the lines of the polygon,then we construct the desired surface.

pts = CirclePoints[5];
draw[a_, b_] := 
  ParametricPlot3D[
   TranslationTransform[{0, 0, -θ}]@PadRight[#, 3] &@
    ScalingTransform[θ*{1, 1}]@
     RotationTransform[-θ][t*a + (1 - t)*b], {t, 0, 
    1}, {θ, 1, 0}, ColorFunction -> Hue, 
   MeshFunctions -> (#3 &)];
Show[draw @@@ Partition[pts, 2, 1, 1], PlotRange -> All, 
 Boxed -> False, Axes -> False, ViewPoint -> {1.3, -2.4, 2.}]

Test another method.

Table[Region[
    TransformedRegion[
     RegionProduct[RegionBoundary@RegularPolygon[5], Point[{0}]], 
     TranslationTransform[{0, 0, -θ}]@*
      ScalingTransform[θ*{1, 1, 1}]@*
      RotationTransform[-θ, {0, 0, 1}]]] // 
   Evaluate, {θ, 0, 1, .04}] // Show

Edit-1

curve[t_] = Normalize[{Cos[t], Sin[t], 0}, Norm[#, 1] &];
ParametricPlot3D[
 TranslationTransform[{0, 0, -θ}]@
  ScalingTransform[θ*{1, 1, 1}]@
   RotationTransform[-θ, {0, 0, 1}]@curve[t]// Evaluate, {t, 0, 
  2 π}, {θ, 1, 0}, ColorFunction -> Hue, 
 MeshFunctions -> (#3 &)]

n = 5;
pts = Append[#, First[#]] &[PadRight[#, 3] & /@ CirclePoints[n]];
curve = BSplineFunction[pts, SplineDegree -> 1];
(*curve[t_]=Piecewise[Thread[{MapThread[ReplaceAll[#1,Rule[t,#2]]&,{\
Function[{x,y},(1-t)*x+t*y]@@@Partition[pts,2,1,1],Rescale[t,#,{0,1}]&\
/@Partition[Subdivide[0,1,n],2,1]}],#1≤t≤#2&@@@\
Partition[Subdivide[0,1,n],2,1]}]];*)
ParametricPlot3D[
 TranslationTransform[{0, 0, -θ}]@
   ScalingTransform[θ*{1, 1, 1}]@
    RotationTransform[-θ, {0, 0, 1}]@curve[Mod[t, 1]] // 
  Evaluate, {t, 0, 1}, {θ, 1, 0}, ColorFunction -> Hue, 
 MeshFunctions -> (#3 &), PlotPoints -> 80, Boxed -> False, 
 Axes -> False]

Edit-2

Clear["Global`*"];
pts = PadRight[#, 3] & /@ CirclePoints[5];
n = Length@pts;
curve[t_] = 
  Sum[UnitStep[t - i/n, 
     Mod[i + 1, n, 1]/n - 
      t]*{1 - Rescale[t, {i/n, Mod[(i + 1), n, 1]/n}, {0, 1}], 
      Rescale[t, {i/n, Mod[(i + 1), n, 1]/n}, {0, 
        1}]} . {pts[[Mod[i, n, 1]]], pts[[Mod[i + 1, n, 1]]]}, {i, 0, 
    n}];
ParametricPlot3D[
 TranslationTransform[{0, 0, -θ}]@
   ScalingTransform[θ*{1, 1, 1}]@
    RotationTransform[-θ, {0, 0, 1}]@curve[Mod[t, 1]] // 
  Evaluate, {t, 0, 1}, {θ, 1, 0}, ColorFunction -> Hue, 
 MeshFunctions -> (#3 &), PlotPoints -> 80, Boxed -> False, 
 Axes -> False, Exclusions -> None]