Cases do not pick up Sqrt?

Question

I'm trying to understand how Cases work in Mathematica, and I'm a bit curios why i't wont pick up the Sqrt function?

Consider the following expressions

Cases[Erfc[b], _Erfc, Infinity]
Cases[a*Erfc[b], _Erfc, Infinity]
Cases[a*Sqrt[b], _Sqrt, Infinity]
Cases[a*Sqrt[b], _Sqrt, Infinity]
Cases[a*Sqrt[a]*Erfc[b], _Erfc, Infinity]
Cases[a*Sqrt[a]*Erfc[b], _Sqrt, Infinity]

they give respectively

{}
{Erfc[b]}
{}
{}
{Erfc[b]}
{}

Why does Cases fail in the cases that give {}?

See FullForm[Sqrt[x]]. It returns Power[x, Rational[1, 2]] which corresponds to x^(1/2), and either you have to prevent evaluation or match this form. — kirma, Apr 30 '21 at 12:14
Related: https://mathematica.stackexchange.com/a/29219, https://mathematica.stackexchange.com/q/114685 — Michael E2, Apr 30 '21 at 16:30
Also: https://mathematica.stackexchange.com/q/221369, https://mathematica.stackexchange.com/q/22948 — Michael E2, Apr 30 '21 at 16:41

score 5 · Accepted Answer · answered Apr 30 '21 at 16:08

In the first case:

Cases[Erfc[b], _Erfc, Infinity]

"Infinity" means: {1,Infinity}. But Erfc[b] is at level 0. Therefore, you need:

Cases[Erfc[b], _Erfc, {0,Infinity}]

Further, the next problem:

Cases[a*Sqrt[b], _Sqrt, Infinity]

The full form of Sqrt[b] is Power[..] (You may use "FullForm" to see the full form). Therefore, you need:

Cases[a*Sqrt[b], _Power,  Infinity]

To get:

{Sqrt[b]}

Then the case of:

Cases[a*Sqrt[a]*Erfc[b], _Sqrt, Infinity]

Because arguments are evaluated before sending them to functions, a*Sqrt[a] is simplified to a^(3/2) and by:

Cases[a*Sqrt[a]*Erfc[b], _Power, Infinity]

you get:

{a^(3/2)}

I.M. · Answer 2 · 2021-04-30T15:31:56.777

4

Check FullForm, arg of Cases is evaluated before matching:

FullForm[a*Sqrt[b]]
Cases[HoldForm[a*Sqrt[b]], _Sqrt, Infinity]
MatchQ[f[x], f[x]]
Symbol === Head[f]
Cases[f[x], _f, Infinity]
Cases[{f[x]}, _f, Infinity]

edited Apr 30 '21 at 15:31

answered Apr 30 '21 at 12:06

I.M.

2,926
1
13
18

Does this also explain why Cases[Erfc[b], _Erfc, Infinity] gives {}? – Mikael Fremling Apr 30 '21 at 13:31
@MikaelFremling, no, this seems to be related to expression Head being a symbol, see the edit, not sure why – I.M. Apr 30 '21 at 15:31
2

@MikaelFremling Try Cases[Erfc[b], _Erfc, {0, Infinity}]. The level spec Infinity is equivalent to {1, Infinity}. – Michael E2 Apr 30 '21 at 16:46

score 3 · Answer 3 · answered Apr 30 '21 at 15:59

Try HoldForm

Cases[HoldForm[ Erfc[b]], _Erfc, Infinity]
Cases[HoldForm[ a*Erfc[b]], _Erfc, Infinity]
Cases[HoldForm[ a*Sqrt[b]], _Sqrt, Infinity]
Cases[HoldForm[ a*Sqrt[b]], _Sqrt, Infinity]
Cases[HoldForm[ a*Sqrt[a]*Erfc[b]], _Erfc, Infinity]
Cases[HoldForm[ a*Sqrt[a]*Erfc[b]], _Sqrt, Infinity]

Cases do not pick up Sqrt?

3 Answers3