How can I make a Plot over a discrete set of domain points?

Question

I want to plot the function $y=2^x$ at the $x$-values given by Table[Prime[n], {n,20}]

How should I write the plot function? Like so?

list = Table[Prime[n], {n,20}]
Plot[y = 2^x, Evaluate[list]]

ListPlot. To connect the dots: Joined->True or ListLinePlot. — swish, May 10 '13 at 02:03
I'm sorry. Maybe I didn't make myself clear. I'd like to pass the result of a Table[] as the Plot[] range "{x,min, max}" — Ehsan Irannejad, May 10 '13 at 02:11
I think you need to look at the syntax structure for Plot. You simply need a function, and then the variable range in the form {x,xmin,xmax}. — Jonathan Shock, May 10 '13 at 02:13
Ok. Then let me reword the question. How can I tell Mathematica to plot y=2^x for x =Table[Prime[n],{n,20}] — Ehsan Irannejad, May 10 '13 at 02:15
Do you mean ListPlot[2^list], or better still ListLogPlot[2^list]? — Jonathan Shock, May 10 '13 at 02:45

score 6 · Answer 1 · answered May 10 '13 at 02:26

6

Alternatively, you can use a function dedicated to plotting discrete data:

DiscretePlot[2^Prime[n], {n, 1, 7}, Filling -> None, Frame -> True, Joined -> True]

exponential at prime values

answered May 10 '13 at 02:26

J. M.'s missing motivation

124,525
11
401
574

Brett Champion · Accepted Answer · 2016-06-22T14:45:00.147

All the solutions so far have plotted {n, 2^Prime[n]} for integer values of n, which means that the points will be evenly spaced along the horizontal axis. Here's how to do what was actually asked, plotting {x, 2^x} for prime values of x.

Since 2^x grows so quickly, I'll demonstrate instead with Sqrt[x] so that it's easier to see the uneven distribution of primes along the horizontal axis.

Using ListPlot, you want to specify the horizontal position using {x,y} pairs, rather than just a list of heights:
```
primes = Table[Prime[n], {n, 20}];
ListPlot[Table[{x, Sqrt[x]}, {x, primes}]]
```
Using DiscretePlot, you want to provide the horizontal positions using the {x, {x1, x2, ..., xn}} variable specification:
```
primes = Table[Prime[n], {n, 20}];
DiscretePlot[Sqrt[x], {x, primes}]
```

score 3 · Answer 3 · answered May 10 '13 at 02:15

3

x = Table[Prime[n], {n, 20}];
y = 2^x;
ListLinePlot[y]

answered May 10 '13 at 02:15

swish

7,881
26
48

OMG!! you're the god and I really need to learn the mathematica basics here!! Thank you a lot!! – Ehsan Irannejad May 10 '13 at 02:17
No problem. You can start from here and here. – swish May 10 '13 at 02:24
Awesome!! Thanks a bunch! – Ehsan Irannejad May 10 '13 at 02:25

score 3 · Answer 4 · edited May 10 '13 at 02:57

3

Exponential functions increase too fast:

ListPlot[2^Table[Prime[n], {n, 20}], Joined -> True]

exponential at prime values

Instead, it is better to work with ListLogPlot (plotting a given function in the logarithmic scale) or just DiscretePlot of the Log :

GraphicsRow[
    { ListLogPlot[2^Table[Prime[n], {n, 20}], Joined -> True, PlotStyle -> Thick], 
      DiscretePlot[Log[2^Prime[n]], {n, 20},  PlotMarkers -> {Automatic, Medium}]}]

plots of logarithms

edited May 10 '13 at 02:57

J. M.'s missing motivation

124,525
11
401
574

answered May 10 '13 at 02:27

Artes

57,212
12
157
245

Thank you very much for the explanation. – Ehsan Irannejad May 10 '13 at 03:57

How can I make a Plot over a discrete set of domain points?

4 Answers4