Plotting an oriented contour

Question

I'd like to add at least one arrow to a closed contour in the plane to show that e.g. a circumference is counterclockwise oriented. If I use e.g.

ParametricPlot[ReIm[Exp[I t]], {t, 0, 2 \[Pi]}]

how can I insert an option to add arrows along the circumference or other closed contour?

Bob Hanlon · Answer 1 · 2021-08-02T14:28:26.617

5

$Version

(* "12.3.1 for Mac OS X x86 (64-bit) (June 19, 2021)" *)

Clear["Global`*"]

pp = ParametricPlot[ReIm[Exp[I t]], {t, 0, 2 π}];

Show[pp,
 Graphics[Arrow /@ 
   Partition[Cases[pp, Line[pts_] :> pts, Infinity][[1]], 221]],
 Frame -> True]

EDIT: Re question in comments, to reverse the arrows change the Graphics to

Graphics[Arrow /@ 
  Partition[Reverse[Cases[pp, Line[pts_] :> pts, Infinity][[1]]], 
   221]]

edited Aug 02 '21 at 14:28

answered Aug 01 '21 at 17:46

Bob Hanlon

157,611
7
77
198

Thanks, very interesting. – CharlesG Aug 02 '21 at 14:01
Thank you, very useful. If the orientation would be clockwise, what must be changed? – CharlesG Aug 02 '21 at 14:13
@CharlesG - See edit above – Bob Hanlon Aug 02 '21 at 14:29

andre314 · Answer 2 · 2021-08-01T18:14:59.160

5

ParametricPlot[ReIm[Exp[I t]], {t, 0, 2 \[Pi]}] /. 
 Line[data___] :>  {Arrowheads[{{.1, 0.1}, {.1, 0.5}}], Arrow[data]}

There are a lot of explanations about the post-processing .../.Line[data__] :> ... Here

In Arrowheads[{{.1, .09}, {.1, 0.5}}] the .1 specify the size of the arrows, .09 and 0.5 their location along the Line. See Arrowheads documentation.

edited Aug 01 '21 at 18:14

answered Aug 01 '21 at 18:02

andre314

18,474
1
36
69

Thank you for this – CharlesG Aug 02 '21 at 14:00
Thank you, very useful. If the orientation would be clockwise, what must be changed? – CharlesG Aug 02 '21 at 14:13
@CharlesG Negative sizes invert the arrows. Try for exemple : Arrowheads[{{-.1, 0.1}, {.1, 0.5}}] – andre314 Aug 02 '21 at 19:01

kglr · Answer 3 · 2021-08-02T21:05:58.527

3

ParametricPlot[ReIm[Exp[I t]], {t, 0, 2 π}, 
 PlotStyle -> Arrowheads[Table[Large, 4]]] /. Line -> Arrow

ParametricPlot[ReIm[Exp[I t]], {t, 0, 2 π}, 
  PlotStyle -> Arrowheads[Table[-Large, 4]]] /. Line -> Arrow

edited Aug 02 '21 at 21:05

answered Aug 02 '21 at 08:24

kglr

394,356
18
477
896

Thank you, very useful. – CharlesG Aug 02 '21 at 13:58
If the orientation would be clockwise, what must be changed? – CharlesG Aug 02 '21 at 14:13
ParametricPlot[ReIm[Exp[-I t]], {t, 0, 2 Pi}, PlotStyle -> Arrowheads[Table[Large, 4]], Axes -> False, Frame -> True] /. Line -> Arrow – mjw Aug 02 '21 at 21:01
@CharlesG, please see the update. – kglr Aug 02 '21 at 21:06

Plotting an oriented contour

3 Answers3