How to make the following modification to the table?

Question

Consider the an example table

TableTest = 
  Table[{{521, 1, 1}, {18000, 2, 1}, {-423, 1, 111}, {-13, 435, 
     2}, {-421, 12, 39}, {321, 11, 34}, {-211, 994, 324}}, {i, 1, 5, 
    1}];

It has the form of "blocks":

TabTest[[1]]

Could you please tell me how to remove the rows with -423, and move the row -421 to the placement of the removed -423 row, such that the modified blocks look like

Edit: I have found a solution. It is not very elegant but works fast:

TableCut1 = Drop[TableTest, None, {3, 7}]
TableCut2 = Drop[Drop[TableTest, None, {1, 3}], None, {2, 4}];
TableCut3 = Drop[Drop[TableTest, None, {1, 4}], None, {2, 3}];
TableCut4 = Drop[TableTest, None, {1, 5}];
TableTestModified = Transpose@
   Join[Transpose@TableCut1, Transpose@TableCut3, Transpose@TableCut2,
     Transpose@TableCut4];

Check out Drop (to remove parts)...and to rearrange parts try Part — Joshua Schrier, Dec 17 '21 at 15:59
Or (Delete[TabTest[[1]], 3]) // MatrixForm deletes the third row — Nasser, Dec 17 '21 at 16:01
https://mathematica.stackexchange.com/questions/3069/elegant-operations-on-matrix-rows-and-columns — march, Dec 17 '21 at 17:00
Does this answer your question? Elegant operations on matrix rows and columns — MarcoB, Dec 18 '21 at 00:36

score 1 · Answer 1 · answered Dec 17 '21 at 17:05

ttest = Table[{{521, 1, 1}, {18000, 2, 1}, {-423, 1, 111}, {-13, 435, 
     2}, {-421, 12, 39}, {321, 11, 34}, {-211, 994, 324}}, {i, 1, 5, 
    1}];

Define a utility function:

Clear[f, k, pos1, pos2];
f[mat_List] := Module[{pos1, pos2, k},
  k = mat;
  pos1 = Flatten@Position[mat, {-423, _, _}];
  pos2 = Flatten@Position[mat, {-421, _, _}];
  (*Echo[k];
  Echo[pos1];
  Echo[pos2];*)
  k[[pos1]] = k[[pos2]];
  k[[pos2]] = Nothing;
  (*Echo[k];*)
  k
  ]
(new = f /@ ttest) // MatrixForm

Daniel Huber · Accepted Answer · 2021-12-18T10:49:46.193

1

You can do this using "ReplacePart" and the 3 argument form of of "Drop":

t = ReplacePart[TableTest, {i_, 3} :> TableTest[[i, 5]]];
t = Drop[t, None, {5}];
t[[1]]
{{521, 1, 1}, {18000, 2, 1}, {-421, 12, 39}, {-13, 435, 2}, {321, 11, 

34}, {-211, 994, 324}}

edited Dec 18 '21 at 10:49

answered Dec 17 '21 at 20:28

Daniel Huber

51,463
1
23
57

But in this case, the row with -421 does not move. – John Taylor Dec 17 '21 at 21:18
@John Taylor. You are right, I overread this. It is corrected now. – Daniel Huber Dec 18 '21 at 10:50

kglr · Answer 3 · 2021-12-18T11:32:55.780

Update: From the method used in OP, it looks like the positions to be modified are known. In that case, we get the desired result with a simple application of Part:

TableTest4 = TableTest[[All,{1,2,5,4,6,7}]];
TableTest4 == TableTestModified

True

Original answer:

You can use SubsetReplace or SequenceReplace as follows:

TableTest2 = SubsetReplace[{a : {-423, __}, b : {-421, __}} :>  b]] /@ TableTest;
TableTest3 = SequenceReplace[{a:{-423, __}, b___, c:{-421, __}} :> Sequence[c, b]] /@
  TableTest;
TableTest2 == TableTest3 == TableTestModified

True

Grid[{Style[#, 16] & /@ {"TableTest", "TableTest2", "TableTest3"}, 
    MatrixForm[#, TableDirections -> {Column, Column}] & /@ 
      {TableTest, TableTest2, TableTest3}}, 
    Dividers -> {None, {{-1, 1, -1}}}]

How to make the following modification to the table?

3 Answers3