Display information as fractions in dataset

Question

I have some data that I want to display as rationals.
someData={<|"utilization fraction" -> 1, "power fraction" -> 1|>, <|"utilization fraction" -> 7/8, "power fraction" -> 224/225|>, <|"utilization fraction" -> 3/4, "power fraction" -> 48/49|>, <|"utilization fraction" -> 5/8, "power fraction" -> 160/169|>, <|"utilization fraction" -> 1/2, "power fraction" -> 8/9|>, <|"utilization fraction" -> 3/8, "power fraction" -> 96/121|>, <|"utilization fraction" -> 1/4, "power fraction" -> 16/25|>, <|"utilization fraction" -> 1/8, "power fraction" -> 32/81|>}; Dataset[someData]

When I display this as a dataset, some of the entries are displayed as rationals and others are converted to decimals. The underlying data only has rational numbers so why do some get converted and how do I stop this?

I have tried various options on ItemSize in hopes that it would keep fractions but none are working. Is there some obscure option that will keep the entries as fractions?

For example,

Dataset[someData,ItemSize->{Full,3}]

doesn't change the view.

I am putting this into a report and my current (awful) solution is to redraw this as an Excel table and copy that.

It is interesting that Identity[] InputForm[] and # all yield what I wanted. Thanks to all for the suggestions! — Mark R, Dec 29 '21 at 01:24
I think you can ask WRI if this is a known bug. If it is, then please come back and update this question with the bugs tag. There is no apparent reason that the default formatting should switch every few rows without an explanation. Also I would request members to test it on various versions/platforms and add comments as necessary. — Syed, Dec 29 '21 at 06:55
Thanks for the suggestion @Syed. I've reached out to WRI and if they confirm that it is a bug, I'll update the tag as you suggest. — Mark R, Dec 30 '21 at 08:32

score 10 · Accepted Answer · answered Dec 28 '21 at 19:30

10

You may use the ItemDisplayFunction option of Dataset.

With someData as in OP, then

Dataset[someData,
 ItemDisplayFunction -> (Identity[#] &)
 ]

You can also target certain columns or cells with ItemDisplayFunction.

Hope this helps.

answered Dec 28 '21 at 19:30

Edmund

42,267
3
51
143

score 7 · Answer 2 · answered Dec 28 '21 at 19:35

7

I am not sure what changes rationals to decimals.

However, we may fix this by specifying an explicit "ItemDisplayFunction" choosing "InputForm":

Dataset[someData, ItemDisplayFunction -> (InputForm@# &)]

You may as well choose "StandardForm" or an other form you fancy.

answered Dec 28 '21 at 19:35

Daniel Huber

51,463
1
23
57

An interesting observation: this shows the numbers using "/" rather than the horizontal dividing bar. Strangely, Identity[#] is currently showing a mixture of these values for new data. Meaning some use "/" and some use the horizontal dividing bar. – Mark R Dec 30 '21 at 19:16

score 7 · Answer 3 · answered Dec 28 '21 at 22:51

7

There is a "neat example" in the documentation page for ItemDisplayFunction. I extended it a bit for this question as I really like how the fractions are visualized this way:

Dataset[someData, ItemDisplayFunction -> (
    Labeled[
        Style[
            Spacer[{100 #, 15}],
            Background -> Cyan],
        #, Right] & )]

answered Dec 28 '21 at 22:51

Gustavo Delfino

8,348
1
28
58

This is an interesting way to visualize. Thanks for sending! – Mark R Dec 29 '21 at 01:23

score 6 · Answer 4 · answered Dec 28 '21 at 19:34

6

ds = Dataset[someData, ItemDisplayFunction -> (# &)]

answered Dec 28 '21 at 19:34

Syed

52,495
4
30
85

Display information as fractions in dataset

4 Answers4