Is there any particularity of Sum/Product in replacement

Question

Here is an simple replacement:

 Log[x[k]] /. Log[a_] -> a*xbar

I get the answer in my mind:

xbar x[k]

Similarly, I use another replacement:

Sum[x[k],{k,1,n}]/.Sum[a_,{k,1,n}]->a*xbar

Should the answer be x[k]*xbar ? However, the replacement is disappointing:

I remain puzzled after much pondering. It seems the function Product at it also is deceptive.

What is the particularity of Sum/Product in replacement? Why is that?

What do you expect after applying the rule? Sum[x[k] xbar,{k,1,n}]? — Ulrich Neumann, Feb 17 '22 at 14:39

xzczd · Answer 1 · 2022-02-17T14:55:18.263

4

If a function doesn't own Hold* attribute, it'll evaluate its arguments from left to right. ReplaceAll (/.) and Rule (/.) don't own Hold* attribute. In other words, Sum[a_, {k, 1, n}] evaluates before the replacement happens. There's no explicit k in a_, so Sum thinks it's a constant and evaluates to n a_. This can be checked with Trace:

Sum[x[k], {k, 1, n}] /. Sum[a_, {k, 1, n}] -> a xbar // Trace

Then how to fix? Just stop summing with HoldPattern:

Sum[x[k], {k, 1, n}] /. HoldPattern@Sum[a_, {k, 1, n}] -> a xbar

Alternatively:

Sum[x[k], {k, 1, n}] /. (h : Sum)[a_, {k, 1, n}] -> a xbar

Or:

Sum[x[k], {k, 1, n}] /. Verbatim[Sum][a_, {k, 1, n}] -> a xbar

edited Feb 17 '22 at 14:55

answered Feb 17 '22 at 14:35

xzczd

65,995
9
163
468

2

Or make the index a pattern: Sum[x[k], {k, 1, n}] /. Sum[a_, {k_, 1, n}] :> a*xbar – Bob Hanlon Feb 17 '22 at 14:59
@bob Interesting, I didn't know summing will stop evaluation in this case. (Even Sum[a_, {h : k, 1, n}] evaluates to n a_! ) – xzczd Feb 17 '22 at 15:08
I am only guessing but I suspect that in the process of localizing the index variable, internally k doesn't look like k. Using a pattern would cause a match to whatever its representation. – Bob Hanlon Feb 17 '22 at 15:14
Thanks. I've learned Attrbute of Hold*, useful Trace. – jerry Feb 17 '22 at 15:15
@BobHanlon I wonder how you find it, accidentally. – jerry Feb 17 '22 at 15:17
@xzczd These techniques seems advanced to a layman like me. Is there any excellent book detailed for in-depth study? MMA is so powerful. – jerry Feb 17 '22 at 15:22
@jerry - As I indicated, I guessed that localization might change the representation, and generalized the form of the LHS of the rule to see if that helped. – Bob Hanlon Feb 17 '22 at 15:22
@BobHanlon Cool! – jerry Feb 17 '22 at 15:24
@jerry - Make use of the online documentation. Wolfram's book is online. – Bob Hanlon Feb 17 '22 at 15:37
@BobHanlon Ok. Thanks! – jerry Feb 17 '22 at 15:43
@jerry Also, don't miss Leonid Shifrin's book: http://mathprogramming-intro.org/ You can find more resource here: https://mathematica.stackexchange.com/q/18/1871 – xzczd Feb 18 '22 at 02:29

Is there any particularity of Sum/Product in replacement

1 Answers1