How to prove or disprove an inequality with Mathematica?

Question

I mean there exist $\lambda>0, x\in \mathbb R$ s.t. the inequality $$ \frac{3^{\lambda } e^x+e^{3 x}+1}{2^{\lambda } e^{2 x}}<\frac{1}{10^{100}}$$ is valid.

Here are my unsuccessful attempts.

Resolve[Exists[\[Lambda], \[Lambda] > 0, Exists[x, (1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 
10^-100]], Reals]

returns the input. The same issue with

Minimize[{(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x), \[Lambda] > 0}, {\[Lambda], x}]

and

FindInstance[(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 
1/10^100 && \[Lambda] > 0, {\[Lambda], x}, Reals]

The result of the command

NMinimize[{(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x), \[Lambda] > 0}, {\[Lambda], x}]

{0., {\[Lambda] -> 425.496, x -> 236.227}}

is not any proof because 0. may be greater than 0.

The command MinLimit[(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/ E^(2 x), {\[Lambda], x} -> {Infinity, Infinity}, Direction -> "FromBelow"] results in -Infinity which is wrong since the function takes only positive values. — user64494, Mar 03 '22 at 06:55

Akku14 · Accepted Answer · 2022-03-03T16:37:33.380

2

It is easier to solve equations and impose conditions on parameters (here fval ), than to solve inequations.

(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 
   10^-100 /. \[Lambda] -> 1800 /. x -> Log[10^420]
(*   True   *)

f = (1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x);

Get rid of the Exp

sol1 = Flatten@Solve[E^x == ex, x,Reals] // Quiet

Transform f < 10^-100 to f == fval with fval < 10^-100

f2 = f - fval /. sol1 // Together // Numerator

Get solutions for ex (=E^x) with conditions for fval and lambda

sol = Solve[f2 == 0 && ex > 0 && \[Lambda] > 0 && fval < 10^-100, ex, 
       Reals, Method -> Reduce];
sol // N
(*   {{ex -> ConditionalExpression[
Root[1 + 3^[Lambda] #1 - 2^[Lambda] fval #1^2 + #1^3 &, 2], 
Root[-27 - 4 3^(3 [Lambda]) - 
     2^(1 + [Lambda]) 3^(2 + [Lambda]) #1 + 
     6^(2 [Lambda]) #1^2 + 2^(2 + 3 [Lambda]) #1^3 &, 3] < 
  fval < 1.*10^-100 
&& [Lambda] > 1605.6]},
{ex -> 
  ConditionalExpression[
  Root[1 + 3^[Lambda] #1 - 2^[Lambda] fval #1^2 + #1^3 &, 3], 
  Root[-27 - 4 3^(3 [Lambda]) - 
     2^(1 + [Lambda]) 3^(2 + [Lambda]) #1 + 
     6^(2 [Lambda]) #1^2 + 2^(2 + 3 [Lambda]) #1^3 &, 3] < 
  fval < 1.10^-100 
&& [Lambda] > 1605.6]}}   )

{{ex -> ConditionalExpression[ Root[1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 2], Root[-27 - 4 3^(3 \[Lambda]) - 2^(1 + \[Lambda]) 3^(2 + \[Lambda]) #1 + 6^(2 \[Lambda]) #1^2 + 2^(2 + 3 \[Lambda]) #1^3 &, 3] < fval < 1.*10^-100 && \[Lambda] > 1605.6]}, {ex -> ConditionalExpression[ Root[1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 3], Root[-27 - 4 3^(3 \[Lambda]) - 2^(1 + \[Lambda]) 3^(2 + \[Lambda]) #1 + 6^(2 \[Lambda]) #1^2 + 2^(2 + 3 \[Lambda]) #1^3 &, 3] < fval < 1.*10^-100 && \[Lambda] > 1605.6]}}

Retransform x==Log[ex]

(Log[ex] /. sol) /. \[Lambda] -> 2500 /. fval -> 6/10 10^-100 // 
 N[#, 10] &
(*   {1244.432105, 1502.098616}   *)
Reduce[f2 == 0 && ex > 0 && [Lambda] > 0 && fval < 10^-100, ex,         Reals]//N

\[Lambda] > 1605.6 && ((fval == Root[-27 - 4 3^(3 \[Lambda]) - 2^(1 + \[Lambda]) 3^(2 + \[Lambda]) #1 + 6^(2 \[Lambda]) #1^2 + 2^(2 + 3 \[Lambda]) #1^3 &, 3] && ex == Root[1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 2]) || (Root[-27 - 4 3^(3 \[Lambda]) - 2^(1 + \[Lambda]) 3^(2 + \[Lambda]) #1 + 6^(2 \[Lambda]) #1^2 + 2^(2 + 3 \[Lambda]) #1^3 &, 3] < fval < 1.*10^-100 && (ex == Root[1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 2] || ex == Root[ 1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 3])))

Edit made by @user6494. For the user's convenience (In order not to read the below comments.), I fixed the omitted Reals in sol1 = Flatten@Solve[E^x == ex, x,Reals] // Quiet.

In version my version 8.0 Reals is not neccessary. (Akku14)

edited Mar 03 '22 at 16:37

answered Mar 03 '22 at 08:04

Akku14

17,287
14
32

Thank you. I will be waiting for a systematic solution produced by Mathematica. – user64494 Mar 03 '22 at 10:21
Ehank you for your edit. 1. Unfortunately, your code is not commented. 2. sol = Solve[f2 == 0 && ex > 0 && \[Lambda] > 0 && fval < 10^-100, ex, Reals, Method -> Reduce] returns the input – user64494 Mar 03 '22 at 11:30
Solve[ConditionalExpression[-(( 2^-\[Lambda] E^(-4 I \[Pi] ConditionalExpression[ 1, \[Placeholder]]) (-1 - 3^\[Lambda] E^( 2 I \[Pi] ConditionalExpression[1, \[Placeholder]]) ex - E^(6 I \[Pi] ConditionalExpression[1, \[Placeholder]]) ex^3 + 2^\[Lambda] E^( 4 I \[Pi] ConditionalExpression[1, \[Placeholder]]) ex^2 fval))/ex^2) == 0 && ex > 0 && \[Lambda] > 0 && fval < 1/ 100000000000.... 000000000000000000000000000000000000, ConditionalExpression[1, \[Placeholder]] \[Element] Integers] for me. – user64494 Mar 03 '22 at 11:30
Works fine in version 8.0 – Akku14 Mar 03 '22 at 11:32
Akku14 (@ does not work.): Can you present the executed *.nb file and/or its PDF export through Dropbox? – user64494 Mar 03 '22 at 11:35
Made some explanations. Try it with Reduce. – Akku14 Mar 03 '22 at 11:51
sol = Reduce[f2 == 0 && ex > 0 && \[Lambda] > 0 && fval < 10^-100, ex, Reals] also returns the input and a message "The system Subscript[[ConstantC],
1][Element][DoubleStruckCapitalZ]&&-((2^-[Lambda] <<1>> (-1-3^
[Lambda] E^<<1>> ex-E^<<1>> <<1>>+2^[Lambda] E^(4 I [Pi]
Subscript[[ConstantC], <<1>>]) ex^2
fval))/ex^2)==0&&ex>0&&[Lambda]>0&&fval<1/
1000000000000000000000000000000000000000000000000000000000000000000000
00000...00000 contains a nonreal constant -4 I.
With the domain [DoubleStruckCapitalR] specified, all constants
should be real". – user64494 Mar 03 '22 at 12:00
Your code works with sol1 = Flatten@Solve[E^x == ex, x, Reals] instead of sol1 = Flatten@Solve[E^x == ex, x]. However, then sol = Reduce[f2 == 0 && ex > 0 && \[Lambda] > 0 && fval < 10^-100, ex, Reals]//N produces – user64494 Mar 03 '22 at 13:24
\[Lambda] > 1605.6 && ((fval == Root[-27 - 4 3^(3 \[Lambda]) - 2^(1 + \[Lambda]) 3^(2 + \[Lambda]) #1 + 6^(2 \[Lambda]) #1^2 + 2^(2 + 3 \[Lambda]) #1^3 &, 3] && ex == Root[1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 2]) || (Root[-27 - 4 3^(3 \[Lambda]) - 2^(1 + \[Lambda]) 3^(2 + \[Lambda]) #1 + 6^(2 \[Lambda]) #1^2 + 2^(2 + 3 \[Lambda]) #1^3 &, 3] < fval < 1.*10^-100 && (ex == Root[1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 2] || – user64494 Mar 03 '22 at 13:25
ex == Root[ 1 + 3^\[Lambda] #1 - 2^\[Lambda] fval #1^2 + #1^3 &, 3]))) without any ConditionalExpression. – user64494 Mar 03 '22 at 13:25
Your Result for Reduce ... is exactly the same as i get, if i apply additional //N. Thats the right result. You may apply Solve on that result. Of course, Reduce yields no ConditionalExpression, only Solve does. – Akku14 Mar 03 '22 at 13:43
For the user's convenience, can you kindly fix the issue with Reals in your good answer? TIA. – user64494 Mar 03 '22 at 14:29
I find this answer more or less completely describing the solutions, so I accept it. – user64494 Mar 03 '22 at 16:28
I am sure most of users don't use version 8. – user64494 Mar 03 '22 at 16:50

Ulrich Neumann · Answer 2 · 2022-03-03T11:05:19.947

2

RegionPlot shows the possible solution space.

Assuming ((1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x))>0 (shown by OP):

eps = 10 ^-100;
gr=RegionPlot[Log[((1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x))] < 
Log[eps], {\[Lambda], 0, 2500}, { x, 0, 2500 } , 
PlotPoints -> 500, FrameLabel -> {"\[Lambda]", " x "},MaxRecursion -> 5] // Quiet

gr[[1,1]][[1]] (*{{1613.23, 886.774}, {1618.24, 886.774}, {1623.25, 891.784},...}*) gives a lengthy list of solutionpoints.

edited Mar 03 '22 at 11:05

answered Mar 03 '22 at 10:44

Ulrich Neumann

53,729
2
23
55

Thank you. Can you extract and indicate some values of \[Lambda] and x validating the inequality from the above plot? It works without Quiet for me in 13 on Windows 10. – user64494 Mar 03 '22 at 10:58
@user64494 Added to my answer – Ulrich Neumann Mar 03 '22 at 11:07
Thank you for your edit. 1. Can you comment your gr[[1,1]][[1]] to be understandable for an average user? 2. Executing (1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 10^-100 /. {\[Lambda] -> 1613.2264514500012, x -> 886.7735485500076}, I obtain a warning "General::munfl: Exp[-1773.55] is too small to represent as a normalized machine number; precision may be lost. ", not only True, so this True is doubtful. – user64494 Mar 03 '22 at 11:38
gr[[1,1]][[1]] gives the list of points used in the GraphiComplex gr. Have a look inside gr witth ??gr . The condition includes numbers O[10^-100], you should adapt Workingprecision to get trusting "True". – Ulrich Neumann Mar 03 '22 at 11:38
Thank you. 1. Is "gr[[1,1]][[1]] gives the list of points used in the GraphiComplex gr. " described in the documentation? If so, can you give a reference ?. 2. How to adapt WorkingPrecision in (1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 10^-100 /. {\[Lambda] -> 1613.2264514500012, x -> 886.7735485500076}? – user64494 Mar 03 '22 at 11:43
Try (1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 10^-100 /. Rationalize[{\[Lambda] -> 1613.2264514500012 , x -> 886.7735485500076}, 0] – Ulrich Neumann Mar 03 '22 at 11:52
Thank you. Works. However, gr[[1,1]][[1]] is still not explained according to the documentation. – user64494 Mar 03 '22 at 12:04
1

I don't think that I have to lead you through documentation! Lookup info GraphicsComplex as proposed by me some comments ago. – Ulrich Neumann Mar 03 '22 at 12:47
Sorry, I don't see any explanation there. Your gr[[1,1]][[1]] seems to be undocumented. – user64494 Mar 03 '22 at 12:51
Perhaps halirutan's answer helps – Ulrich Neumann Mar 03 '22 at 13:09
I don't think so. 1. That was about Graphics3D. 2. The result of gr is not a polygon. What are vertices of gr? – user64494 Mar 03 '22 at 13:29
One more remark. In any case, so-called vertices belong to the boundary of the region defined by the strict inequality under consideration. Therefore, their coordinates may not satisfy the inequality. – user64494 Mar 03 '22 at 14:00
@user64494 Am yet again and again amazed: While you are asking for information you simultanously claim remarks, which aren't true. #1 Mathematica vertices are all points of a Graphics object. #2 Of course gr contains polygons. – Ulrich Neumann Mar 03 '22 at 14:49
Is your statement " Mathematica vertices are all points of a Graphics object" true? Let us consider an example from the documentation: g = GraphicsComplex[{{0, 0}, {Sqrt[3], Sqrt[3]/2}}, {Point[1], Line[{1, 2}]}];g[[1, 1]][[1]] which results in0, but Graphics[g] shows more than this. 2. Please, be correct in your conversation. –

user64494

Mar 03 '22 at 16:36

Without enclosing Graphics you get the points with g[[1,1]] – Ulrich Neumann Mar 03 '22 at 20:06

user64494 · Answer 3 · 2022-03-03T15:18:02.453

Here is my tricky answer. First, the result of

Limit[(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) /. 
x -> Log[3]/2*\[Lambda], \[Lambda] -> Infinity]

0

guarantees the existence of the required solution. Second,

NSolve[Expand[(1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) /. 
 x -> Log[3]/2*\[Lambda]] == 1/2*10^-100 && \[Lambda] >= 0 && \[Lambda] <= 3000 , \[Lambda]]

{{\[Lambda] -> 1610.42}}

finds a one solution of the inequality under consideration.

Addition. A simple approach which uses NMinimize is as follows.

NMinimize[{1, (1 + 3^\[Lambda]*E^x + E^(3 x))/2^\[Lambda]/E^(2 x) < 
10^-100 && x^2 + \[Lambda]^2 >= 2*10^6 && 
x^2 + \[Lambda]^2 <= 10^7}, {x, \[Lambda]}, 
WorkingPrecision -> 100, Method -> "DifferentialEvolution"]

{1.0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000,{x->1792.682158676924591695765318215658904932218868106718701333477115390170263646455485621517086104184032,\[Lambda]->2605.050993351464904744268828659450449353575490756371168671954922778805769014234476770620073231372436}}

One may take a somewhat greater or smaller number than Log[3]/2. — user64494, Mar 03 '22 at 14:06

How to prove or disprove an inequality with Mathematica?

3 Answers3