What kind of method does Solve use to solve a system of overdetermined linear equations?

Question

I have a singular homogeneous linear system of equations, which easily can be solved by applying Solve:

equs = {x2 == z2, x3 == z3, x5 == z5, w2 == y2,
   w4 == y4, w5 == y5, x1 == y1, x4 == y4,
   x3 == y5, w1 == z1, w4 == z4, w5 == z3,
   x1 == z1, x4 == z4, x5 == z5, w1 == y1,
   w3 == y3, w4 == y4, x2 == y2, x5 == y3,
   x4 == y5, w2 == z2, w3 == z5, w5 == z4};
vars = {x1, x2, x3, x4, x5, y1, y2, y3, y4, y5, z1, z2, z3, z4, z5, 
   w1, w2, w3, w4, w5};
Solve[equs, vars]
{{x1 -> w1, x2 -> w2, x3 -> w5, x4 -> w5, x5 -> w3, y1 -> w1, 
  y2 -> w2, y3 -> w3, y4 -> w5, y5 -> w5, z1 -> w1, z2 -> w2, 
  z3 -> w5, z4 -> w5, z5 -> w3, w4 -> w5}}

The problem I have is that "Solve" is a "black box" for me. I would like to know the method applied by "Solve" dealing with the kind of equations given above. Is there any other (more specific) method available in Mathematica to deal with these kind of equations?

Answer 1

You need a null-space solver.

equs = {x2 == z2, x3 == z3, x5 == z5, w2 == y2, w4 == y4, w5 == y5,
        x1 == y1, x4 == y4, x3 == y5, w1 == z1, w4 == z4, w5 == z3,
        x1 == z1, x4 == z4, x5 == z5, w1 == y1, w3 == y3, w4 == y4, 
        x2 == y2, x5 == y3, x4 == y5, w2 == z2, w3 == z5, w5 == z4};

Let's first convert your equations a bit. Convert to a list of terms that must be zero:

zero = equs /. Equal -> Subtract
(*    {x2 - z2, x3 - z3, x5 - z5, w2 - y2, w4 - y4, w5 - y5, x1 - y1,
       x4 - y4, x3 - y5, w1 - z1, w4 - z4, w5 - z3, x1 - z1, x4 - z4,
       x5 - z5, w1 - y1, w3 - y3, w4 - y4, x2 - y2, x5 - y3, x4 - y5,
       w2 - z2, w3 - z5, w5 - z4}                                        *)

Extract the list of variables:

vars = Sort@Variables[Times @@ zero]
(*    {w1, w2, w3, w4, w5, x1, x2, x3, x4, x5, y1, y2, y3, y4, y5, z1, z2, z3, z4, z5}    *)

Express the equations as a matrix $M$ that, when multiplied by the list of variables, must give a zero vector:

M = D[zero, {vars}]

$$ \left( \begin{array}{cccccccccccccccccccc} 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 \\ 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 \\ 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 \\ 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 \\ 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 & 0 & 0 \\ 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 & 0 & 0 \\ 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 \\ 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & 0 & -1 & 0 \\ \end{array} \right) $$

Now we know that M . vars must give zeros, so vars must be a linear combination of vectors from the null space of M:

nullvecs = NullSpace[M]
(*    {{0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1},
       {0, 0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 1, 1, 0, 0, 1, 1, 0},
       {0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 0, 0},
       {1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0}}    *)

So any solution vector that is such a linear combination will satisfy the equations:

sol = {a, b, c, d} . nullvecs
(*    {d, c, a, b, b, d, c, b, b, a, d, c, a, b, b, d, c, b, b, a}    *)

Check:

equs /. Thread[vars -> sol]
(*    {True, True, True, True, True, True, True, True, True, True,
       True, True, True, True, True, True, True, True, True, True,
       True, True, True, True}                                        *)