How can I make MMA give me \mathrm{d} when converting definite integrals into Latex code?

Question

Recently my work contains a lot of expressions with definite integrals, and I need to convert them into latex code to present my results. To my disappointment, MMA always converts the differential operator \[DifferentialD] in those integrals into normal italic $d$, which does not conform to the regulations I need to obey.

In pure mathematics literature, using such normal italic $d$ notation for differential operator is common, but for physics and engineering literature, normal italic $d$ notation may already stand for a quantity or variable like distance or thickness, which has to be distinguished from the differential operator \[DifferentialD],as a result I need to use "\mathrm{d}" or $\mathrm{d}$ to represent the differential operator in integrals.

I have already tried to modify the built-in Tex rules to achieve the "\mathrm{d}" in integrals. But unfortunately, it works when the expr is a pure differential. As long as it comes to a definite integral, it fails, which has given me a feelilng that the definite integral is parsed as whole in MMA and when doing so MMA ignores my self-introduced Tex rules.

My habitual way to generate latex code from MMA is right-click->Copy as->Latex. But I also welcome method that fulfill my needs by generating the latex code some other way in MMA.

Any ideas to achieve so?

Answer 1

Simple enough as mentioned in the question:

System`Convert`TeXFormDump`maketex["\[DifferentialD]"]="\\mathrm{d}";

should do the trick. And it actually does

"\[DifferentialD]"//TeXForm (* -> \mathrm{d} *)

But curiously

Integrate[f[x],x]//StandardForm
%//TeXForm (* -> \int f(x) \, dx *)

does not yield the expected result even though the StandartForm (boxed Mathematica representation) clearly uses \[DifferentialD]. The reason why the TeXForm is incorrect here is as OP guessed a problem and to be frank just a lazy oversight of the programmers of Mathematica:

GeneralUtilities`Definitions@System`Convert`TeXFormDump`maketex;
Select[ToString[#]&/@%,StringContainsQ[#,"integrand"]&];
%//TableForm

lets us look under the hood (the default tool of choice PrintDefinitions from GeneralUtilities does not work because it only prints when there are less then 257 definitions). From the 1059 definitions (in version 13) of maketex we select the ones which involve the string "integrand" and we get

HoldPattern[System`Convert`TeXFormDump`maketex[RowBox[{\[Integral], RowBox[{System`Convert`TeXFormDump`integrand_, RowBox[{\[DifferentialD], System`Convert`TeXFormDump`var_}]}]}]]] :> \int <>System`Convert`TeXFormDump`MakeTeX[System`Convert`TeXFormDump`integrand]<> \, d<>System`Convert`TeXFormDump`MakeTeX[System`Convert`TeXFormDump`var]
HoldPattern[System`Convert`TeXFormDump`maketex[RowBox[{SubsuperscriptBox[\[Integral], System`Convert`TeXFormDump`sub_, System`Convert`TeXFormDump`super_, ___], RowBox[{System`Convert`TeXFormDump`integrand_, RowBox[{\[DifferentialD], System`Convert`TeXFormDump`var_}]}]}]]] :> \int_<>System`Convert`TeXFormDump`MakeScript[System`Convert`TeXFormDump`sub]<>^<>System`Convert`TeXFormDump`MakeScript[System`Convert`TeXFormDump`super]<> <>System`Convert`TeXFormDump`MakeTeX[System`Convert`TeXFormDump`integrand]<> \, d<>System`Convert`TeXFormDump`MakeTeX[System`Convert`TeXFormDump`var]

with the critical segment ...\, d<>System.... They clearly did not account for the option to properly set a TeXForm for \[DifferentialD]. Related to this is this discussion What's the proper way to typeset a differential operator? on wether differential operators (and in this context mathematical constants like the imaginary unit, Eulers constant and even Pi) should be typeset upright. On a personal note: I like them upright (all of them including \uppi see this) to clearly differentiate between operators/constant and variables. Coming back from my ramblings to the problem. Lets fix the two functions

System`Convert`TeXFormDump`maketex[RowBox[{"\[Integral]",RowBox[{integrand_,RowBox[{"\[DifferentialD]",var_}]}]}]]:="\\int "<>System`Convert`TeXFormDump`MakeTeX[integrand]<> "\\," System`Convert`TeXFormDump`MakeTeX["\[DifferentialD]"]<>System`Convert`TeXFormDump`MakeTeX[var]
SystemConvertTeXFormDumpmaketex[RowBox[{SubsuperscriptBox[&quot;\[Integral]&quot;, sub_,super_,___], RowBox[{integrand_, RowBox[{&quot;\[DifferentialD]&quot;, var_}]}]}]] :=&quot;\\int_&quot;&lt;&gt;SystemConvertTeXFormDumpMakeScript[sub]<>"^"<>SystemConvertTeXFormDumpMakeScript[super]&lt;&gt;&quot; &quot;&lt;&gt;SystemConvertTeXFormDumpMakeTeX[integrand]<> "\,"<>SystemConvertTeXFormDumpMakeTeX[&quot;\[DifferentialD]&quot;]&lt;&gt;SystemConvertTeXFormDumpMakeTeX[var]

which fixes the issue for Integrate

Integrate[f[x],x]//StandardForm
%//TeXForm (* -> \int f(x)\, \mathrm{d}x *)

and

Integrate[f[x], {x, 0, 1}] // StandardForm
% // TeXForm  (* -> \int_0^1 f(x)\,\mathrm{d}x*)

both work as expected:

as do multidimensional integrals. For occurrences of \[DifferentialD] outside of Integrate further modifications along this line will most likely be necessary. I personally would also consider to add a thin space \, or \mkern2mu between the differential operator and the variable.

The last side note related to earlier ramblings:

System`Convert`TeXFormDump`maketex["\[DifferentialD]"]="\\mathrm{d}";
System`Convert`TeXFormDump`maketex["I"]="\\mathrm{i}";
System`Convert`TeXFormDump`maketex["E"]="\\mathrm{e}";
System`Convert`TeXFormDump`maketex["\[Pi]"]="\\uppi";

leads to the proper typesetting of Euler's formula (the solution for Pi is not ideal but it normally only appears in Mathematica as the mathematical constant)

Exp[I Pi x] // StandardForm
% // TeXForm (* -> \mathrm{e}^{\mathrm{i}\uppi x}*)