Dimensionless units like Percent are not treated consistently by functions like Exp or Log. How can pitfalls be avoided?

Question

There are so many false calculations out there that working with Quantity und units—at least initially—should be mandatory in many applications.

Alas, implementation in the Wolfram Language sometimes seems to be in the way. I will give a simple calculation of compound interest as example:

r =  Quantity[ 5, "Percent"/"Years" ]; (* a continuously compounding rate *)
t = Quantity[ 10, "Years" ]; (* time for interest to accrue *)
initialCapital = Quantity[ 1000, "USDollars" ];
initialCapital Exp[ r t ]

While in this special case using Normal and N come to the rescue, it seems that the treatment of units that are compatible to "DimensionlessUnit" like Percent is not consistent accross WL functions.

Note the following:

Log[ 1. + 5 Quantity["Percent"] ]
(* 0.0487902 *)
Log[ 1. + Quantity[ 5, "Percent"] ]
(* 0.0487902 *)
Exp[ 5. Quantity["Percent"] ]
(* E^Quantity[5., "Percent"] *)

Is there some principle here? How to best work with units in these cases?

---

A support case with the identification [CASE:4935014] was created. Please include this ID in any future correspondence with Wolfram Technical Support regarding this issue.

Answer 1

While the approaches in the comments (thanks a lot!) solve the issue, the question triggered me to try to "have my cake and eat it as well", i.e., enter quantities but decide globally whether they are used and what will happen if I just want magnitudes—after all using Quantity slows down things.

A Litte Package For Conditional Quantities

The use of quantities with appropriate units should be mandatory for any mathematical model of reality, so that we may have a chance to validate equations.

While using Quantity is the way to go, there is a price to pay with regard to performance—likely a reason that using Quantity may be avoided and mere comments are used for units, which have the downside, that we can't let Mathematica help us.

So a nice thing to have may actually be to allow the verbose use of Quantity so that users can enter 10 Quantity["Percent"] instead of 0.1 (don't laugh, it happens). But at the same time, we may use ConditionalQuantity as a wrapper to guide conversion with regard to the use in our models.

The following package thus has two main functions:

1. Allow to use On["Quantities"] and Off["Quantities"] to switch between UnitConvert and QuantityMagnitude for quanties as appropriate.
2. Tell Mathematica how we would like to have our verbose units be interpreted either for UnitConvert or QuantityMagnitude.

We can achieve (2) by using:

• ConditionalQuantity[quantity] to use QuantityMagnitude as is or to keep quantity as is, i.e., no target units are provided.
• ConditionalQuantity[quantity, "Canonical" ] to try to go for the canonical unit, if it exists.
• ConditionalQuantity[quantity, "Normal" ] to get rid of all units that are compatible to "DimensionlessUnit" (i.e., replace those units by 1), but leave the other units unchanged.
• ConditionalQuantity[quantity, unit] to tell QuantityMagnitude and UnitConvert that unit is the target unit. (Instead of unit we also provide a reference Quantity.)

Code

BeginPackage[ "ConditionalQuantities`" ]
Quantity::inuse = "Quantities in use."
QuantitiesOffQ::usage = "

QuantitiesOffQ[] returns True, if messages related to Quantities have been switched off using Off["Quantities"].

The function will by default be used by ConditionalQuantity to decide whether a magnitude or a quantity is to be returned."
$numericalUnitRules = "

$numericalUnitRules is a list of replacement rules for numerical units like Percent, BasisPoints, Thousand etc."
ConditionalQuantity::usage = "

ConditionalQuantity[quantity] will return QuantityMagnitude[quantity] if QuantitiesOffQ[] is True and quantity, if this is not the case.\n

ConditionalQuantity[quantity, "Canonical" ] will call ConditionalQuantity[quantity, unit], where unit is the canonical unit.\n

ConditionalQuantity[quantity, "Normal" ] will call ConditionalQuantity[quantity, unit], where unit is QuantityUnit[quantity] where all parts

 compatible to "DimensionlessUnit" have been replaced by 1.\n

ConditionalQuantity[quantity, refQuantity] will call ConditionalQuantity[quantity, QuantityUnit[refQuantity]].\n

ConditionalQuantity[quantity, unit] will return QuantityMagnitude[quantity,unit] or UnitConversion[quantity, unit] depending on QuantitiesOffQ[].

 If units is are not compatible, unit input is disregarded and ConditionalQuantity[quantity] is called."
Begin["Private"]
$numericalUnitRules = Map[
    Rule[ #, 1 ]&,
        {
            "Percent",
            "BasisPoints",
            "Dozen",
            "Hundred",
            "Thousand",
            "HundredThousand",
            "Million",
            "Billion",
            "Trillion"
        }
]
$MessageGroups = Join[ $MessageGroups, { "Quantities" :> { Quantity::inuse } } ]
QuantitiesOffQ[] := HoldPattern[ Quantity::inuse ] /. Messages[ Quantity ] // Not @* FreeQ[ $Off ]
ConditionalQuantity[ q_Quantity ] := If[ QuantitiesOffQ[], QuantityMagnitude @ q, q ]
ConditionalQuantity[ q_Quantity, refq_Quantity ] := ConditionalQuantity[ q, QuantityUnit @ refq ]
ConditionalQuantity[ q_Quantity, "Canonical" ] := Enclose[
    With[
        {
            canonicalUnit = ConfirmQuiet[
                QuantityVariableCanonicalUnit @ QuantityVariable @ UnitDimensions @ q
            ]
        }
        ,
        ConditionalQuantity[ q, canonicalUnit ]
    ]
]
ConditionalQuantity[ q_Quantity, "Normal" ] := With[
    {
        normalUnit = QuantityUnit[ q ] /. $numericalUnitRules
    }
    , 
    If[ normalUnit === 1, 
        (* then ) ConditionalQuantity[ q, "DimensionlessUnit" ],
        ( else *) ConditionalQuantity[ q, normalUnit ] 
    ]
]
ConditionalQuantity[ q_Quantity, unit_ ] /; CompatibleUnitQ[ q, unit ] unit := If[ QuantitiesOffQ[],
    (* then )
    QuantityMagnitude[ q, unit ],
    ( else *)
    UnitConvert[ q, unit ]
]
ConditionalQuantity[ q_Quantity, unit_ ] /; Not @ CompatibleUnitQ[ q, unit ] := ConditionalQuantity[q]
End[]
EndPackage[]

Examples

Assuming that we loaded the package with <<ConditionalQuantities` or Needs, we can now do the following:

On["Quantities"] (* Not really necessary since it is default *)
r := ConditionalQuantity[ Quantity[5., "Percent"/"Years"], "Normal" ];
t := ConditionalQuantity[ Quantity[10, "Years"] ]; 
initialCapital := ConditionalQuantity[ Quantity[1000, "USDollars"] ];
initialCapital Exp[r t]
(* $1648.72 *)
r
(* 0.05 per year *)
Do[ initialCapital Exp[r t], 1000] // RepeatedTiming
{0.957131, Null}
Off["Quantities"]
initialCapital Exp[ r t ]
(* 1648.72 *)
r
(* 0.05 *)
Do[ initialCapital Exp[r t], 1000] // RepeatedTiming
{0.413421, Null}

Answer 2

You can use UnitDimensions and UnitConvert to unwrap dimensionless quantities.

With r, t, and initialCapital in OP and

dimensionlessQuantityQ[q_Quantity] := UnitDimensions[q] === {}

then

N[initialCapital Exp[r t]] /. q_Quantity?dimensionlessQuantityQ :> UnitConvert[q]

Quantity[1648.7212707001281`, "USDollars"]

Hope this helps.

Answer 3

Personally, I think it's better to be explicit in telling Mathematica when you want percents to be treated as units or as numbers. In the original post, the problem was setup with percent as a unit. At some point, the desire was to convert to a representation where the percent was a number. Rather than expect Mathematica to correctly infer when such conversions are desired, why not just be explicit? Any of the following, or any similar "forcing" to a new representation, seem appropriate to me:

initialCapital Exp[r t] /. q_Quantity :> Normal[q]
initialCapital Exp[r t] /. q : Quantity[_, "Percent"] :> Normal[q]
initialCapital Exp[r t] /. q_Quantity :> UnitConvert[q]
initialCapital Exp[r t] /. q : Quantity[_, "Percent"] :> UnitConvert[q]