How can I use variables instead of slots in DeleteCases?

Question

Here is a toy example to illustrate my problem. I have a list of 3-tuples and I want to delete elements from this list that satisfy a condition shown below.

tuples = Tuples[{-1, -2, 3}, {3}];
DeleteCases[tuples, _?((#[[1]] + 2 #[[2]] + #[[3]] == 0) &)]

This works perfectly. However, because each element of tuples has this form {a,b,c} and symbols a, b, c have problem-specific meanings attached to them, the code would become more readable if written as follows:

tuples = Tuples[{-1, -2, 3}, {3}];
DeleteCases[tuples, _?((a + 2*b + c == 0) &)]

The motivation is that a + 2*b + c == 0 is easier for a human to read and understand than (#[[1]] + 2 #[[2]] + #[[3]] == 0.

Question Is it possible to write this code using variables instead of slots?

If your problem has the same structure, you can use something like Pick[tuples,Unitize@Total[Transpose[tuples]*{1, 2, 1}], 1] — Ben Izd, May 03 '22 at 07:43
@BenIzd Or Unitize[tuples . {1, 2, 1}] for the selection vector. — Michael E2, May 04 '22 at 01:59

score 12 · Accepted Answer · answered May 03 '22 at 07:46

12

tuples = {{1, 1, -3}, {1, 2, 3}};

(* Solution 1: *)
DeleteCases[tuples, {a_, b_, c_} /; a + 2 b + c == 0]
(* {{1, 2, 3}} *)

(* Solution 2: *)
DeleteCases[tuples, _?(({a, b, c} |-> a + 2 b + c == 0) @@ ## &)]
(* {{1, 2, 3}} *)

(* Solution 3: *)
test[{a_, b_, c_}] := a + 2 b + c == 0  
DeleteCases[tuples, _?test]
(* {{1, 2, 3}} *)

answered May 03 '22 at 07:46

xzczd

65,995
9
163
468

nice, I probably go for test function as I have many conditions. – hana May 03 '22 at 07:53
2

@hana And Select is a choice, too: test2[{a_, b_, c_}] := ! a + 2 b + c == 0; Select[tuples, test2] – xzczd May 03 '22 at 07:58
2

Or with Select[tuples, Not@*test] – Ben Izd May 03 '22 at 07:59

score 12 · Answer 2 · answered May 03 '22 at 08:15

12

Pick could also be useful:

Pick[tuples, Function[{a, b, c}, a + 2 b + c == 0] @@@ tuples, False]

answered May 03 '22 at 08:15

Ben Izd

9,229
1
14
45

Ulrich Neumann · Answer 3 · 2022-05-03T09:24:25.803

8

Perhaps (Thanks to comment/correction @BenIzd )

DeleteCases[tuples, _?(Apply@Function[{a, b, c}, a + 2 b + c == 0])]

is what you are looking for?

edited May 03 '22 at 09:24

answered May 03 '22 at 07:21

Ulrich Neumann

53,729
2
23
55

Yeah, I forgot that you can use Function like that. – hana May 03 '22 at 07:22
2

@hana ……This answer is incorrect. 2nd argument of DeleteCases is not a function. Try tuples = {{1, 1, -3}}; – xzczd May 03 '22 at 07:37
2

DeleteCases[tuples, _?(Apply@Function[{a, b, c}, a + 2 b + c == 0])] – Ben Izd May 03 '22 at 07:50
@xzczd I see, it doesn't remove anything. – hana May 03 '22 at 07:52

score 8 · Answer 4 · answered May 03 '22 at 07:59

8

g[{a_, b_, c_}] := a + 2 b + c == 0

Using the operator form:

DeleteCases[x_ /; g[x]][tuples]

answered May 03 '22 at 07:59

Syed

52,495
4
30
85

How can I use variables instead of slots in DeleteCases?

4 Answers4