11

It is easy to see that NumericArray is a construct underlying Image:

img = Import["ExampleData/coneflower.jpg", IncludeMetaInformation -> None];
ResourceFunction["ShortInputForm"][img]

output

At the same time, unlike Image, we can directly manipulate NumericArray using such handy functions as Part, Flatten etc. Of course, we can convert Image into a packed array using ImageData, but resulting array will occupy much more memory than the original image:

ByteCount /@ {img, ImageData[img, "Byte"]}

{55248, 407016}

The function ShortInputForm uses a hack identical to the Nucleus function by Carl Woll for accessing the internal structure of atomic objects. This hack allows extracting the NumericArray:

Nucleus[img][[1]]

output

But of course it would be much better to have a non-hackish way to do this, which wouldn't depend on undocumented details of implementation of LinkWrite and LinkRead, and hopefully would also be more efficient.

Hence my question: What is the idiomatic way to extract NumericArray from Image?

Alexey Popkov
  • 61,809
  • 7
  • 149
  • 368
  • 4
    Like any NoEntryQ object you can grab its parts all you want via Replace[img, _[x_, ___] :> x], but that's hardly idiomatic is it? I would think you are unlikely to find a builtin solution that doesn't have the words "Private" or "Internal" in the function name. – Jason B. May 23 '22 at 19:50
  • @JasonB. I will be happy also with a function from the Internal` context. At least, do not define a special hackish function for such a basic task... – Alexey Popkov May 23 '22 at 19:52
  • @JasonB. Replace[img, _[x_, ___] :> x] could be an acceptable solution, thank you! You can post this as an answer. – Alexey Popkov May 23 '22 at 19:56
  • 1
    the Replace method I think is a bit heavy handed so I posted a couple of other methods. – Jason B. May 23 '22 at 20:48

1 Answers1

11

I think this is the most idiomatic way to get the image data as a numeric array:

In[141]:= img = Import["ExampleData/coneflower.jpg", IncludeMetaInformation -> None];

In[143]:= NumericArray[ImageData[img, "Byte"]] // OutputForm


Out[143]//OutputForm= NumericArray[<113,150,3>, UnsignedInteger8]

This does require recreating the NumericArray object from the image data, so has that level of inefficiency.

If you were to go spelunking, by calling PrintDefinitions on Image to see the formatting value, you would see the suggestively named Image`InternalImageData. Being the curious type, you would find it gives the same data as above

In[147]:= SameQ[%143, Image`InternalImageData[img]]

Out[147]= True

All the usual caveats about undocumented functionality apply (namely that this internal function could disappear in a future release).

Jason B.
  • 68,381
  • 3
  • 139
  • 286
  • Excellent. I would add that Image`InternalImageData accepts the usual option Interleaving, what is also very handy. For example: Image`InternalImageData[img, Interleaving -> True]. Also it accepts the option DataReversed. – Alexey Popkov May 24 '22 at 04:54