How do I map a function pairwise?

Question

Given a list of pairs:

data = {{a,b},{c,d},{e,f},{g,h},{i,j}}

I need the moving map:

MapPair[F,data]

{ F[{a,b},{c,d}], F[{c,d},{e,f}], F[{e,f},{g,h}], F[{g,h},{i,j}] }

The built-in function MovingMap does not work:

MovingMap[F,data,2]

Which built-in function does maps a function F pairwise over the data?

I need a built-in function that essentially does this: myMapPair[func_, data_] := Array[func[data[[#1]], data[[#1 + 1]]] &, Length[data] - 1] — QuantumDot, Jun 08 '22 at 20:50
I like the BlockMap idea. You can also try mapPair[f_, v_] := f @@@ Partition[ v, 2, 1] — irchans, Jun 08 '22 at 21:00

score 14 · Accepted Answer · answered Jun 08 '22 at 21:05

14

BlockMap[Apply[F], data, 2, 1]

answered Jun 08 '22 at 21:05

lericr

i usually use mapthread when i have multiple variables but i knew there had to be a shorter more robust MMA "blackbelt" configuration. i havent tried it but assuming this works this should be at the very top and i definitely be using next time i need to break out with sewing needles. – Jules Manson Jun 10 '22 at 16:55

score 6 · Answer 2 · answered Jun 09 '22 at 03:46

6

Using MapAt:

MapAt[Apply[F], Partition[data, {2}, 1], All]
(*{F[{a, b}, {c, d}], F[{c, d}, {e, f}], F[{e, f}, {g, h}], F[{g, h}, {i, j}]}*)

answered Jun 09 '22 at 03:46

E. Chan-López

score 3 · Answer 3 · answered Jun 09 '22 at 10:50

MapThread[F, {Most@#, Rest@#}]&[data]

(* {F[{a, b}, {c, d}], F[{c, d}, {e, f}], F[{e, f}, {g, h}], F[{g, h}, {i, j}]} *)

In addition, as kglr has pointed out here, Partition can take an undocumented sixth argument.

Partition[data,2,1,{1,-1},{},F]
(* {F[{a, b}, {c, d}], F[{c, d}, {e, f}], F[{e, f}, {g, h}], F[{g, h}, {i, j}]} *)

score 2 · Answer 4 · answered Nov 04 '23 at 23:11

2 more possibilities:

data = {{a, b}, {c, d}, {e, f}, {g, h}, {i, j}};
Most @ MapThread[F, {data, RotateLeft @ data}]

{F[{a, b}, {c, d}], F[{c, d}, {e, f}], F[{e, f}, {g, h}], F[{g, h}, {i, j}]}

F @@@ Transpose[{data[[;; -2]], data[[2 ;;]]}]

{F[{a, b}, {c, d}], F[{c, d}, {e, f}], F[{e, f}, {g, h}], F[{g, h}, {i, j}]}

kglr · Answer 5 · 2023-11-05T02:31:36.423

The first argument of Partition can have any Head. So we can use

List @@ Partition[F @@ data, 2, 1]

{F[{a, b}, {c, d}], 
 F[{c, d}, {e, f}],   
 F[{e, f}, {g, h}],   
 F[{g, h}, {i, j}]}

Generalizing:

partitionMap = List @@ Partition[# @@ #2, ##3] &;
partitionMap[F, data, 2, 1]

{F[{a, b}, {c, d}], 
 F[{c, d}, {e, f}],   
 F[{e, f}, {g, h}],   
 F[{g, h}, {i, j}]}

partitionMap[F, data, 3, 1]

 {F[{a, b}, {c, d}, {e, f}],   
  F[{c, d}, {e, f}, {g, h}],   
  F[{e, f}, {g, h}, {i, j}]}

5 Answers5