How can I generate a tridiagonal block matrix?

Question

$$\begin{pmatrix}C&D&&&&\\D&C&D&&&\\&\ddots&\ddots&\ddots&&\\&&&D&C&D\\&&&&D&C\end{pmatrix}$$

I want to generate a block tridiagonal matrix like the one depicted above, where $C$ and $D$ are both $2\times 2$ matrices. For example, I want a matrix with 5 $C$ entries. I tried many functions, but I have failed.

m=SparseArray[{Band[{1, 1}] -> c, Band[{1, 2}] -> d, Band[{2, 1}] -> d}, {5, 5}]; m // MatrixForm — cvgmt, Jun 11 '22 at 09:11
I'll write a more detailed answer later unless someone beats me to it; for now, look at SparseArray[{Band[{4, 1}] -> ConstantArray[HilbertMatrix[3], 4], Band[{1, 1}] -> ConstantArray[ToeplitzMatrix[3], 5], Band[{1, 4}] -> ConstantArray[HilbertMatrix[3], 4]}]. — J. M.'s missing motivation, Jun 11 '22 at 09:43
Courtesy of @yarchik, you can also use ToeplitzMatrix[{c, d, 0, 0, 0}] /. {c -> {{1, 1}, {1, 1}}, d -> {{2, 2}, {2, 2}}} // ArrayFlatten. The key is ArrayFlatten. — Ben Izd, Jun 11 '22 at 10:27

cvgmt · Answer 1 · 2022-06-11T09:51:55.490

4

It must be many ways to do this,here we provide one way.

Clear[matrix];
matrix = (SparseArray[{Band[{1, 1}] -> c, Band[{1, 2}] -> d, 
        Band[{2, 1}] -> d}, {8, 8}] // 
      Normal) /. {c -> {{x, y}, {z, w}}, d -> {{m, n}, {p, q}}} // 
   ArrayFlatten;
matrix // MatrixForm

edited Jun 11 '22 at 09:51

answered Jun 11 '22 at 09:37

cvgmt

72,231
4
75
133

score 2 · Answer 2 · answered Jun 11 '22 at 15:29

The matrix you have is block tridiagonal and block Toeplitz.

I'll give two methods: one that uses nothing but documented functionality, and one that uses undocumented functionality.

First up is an extension of the method I gave in the comments, which hinges on the ability of SparseArray[] + Band[] to handle a list of matrices (of conforming dimensions):

cmat = Array[C, {2, 2}];
dmat = Array[\[FormalCapitalD], {2, 2}];
With[{m = 5, k = Length[cmat]},
     bigMat = SparseArray[{Band[{k + 1, 1}] -> ConstantArray[dmat, m - 1], 
                           Band[{1, 1}] -> ConstantArray[cmat, m], 
                           Band[{1, k + 1}] -> ConstantArray[dmat, m - 1]}]];
MatrixForm[bigMat]

big matrix

The important part here is the specification of Band[] for the off-diagonal blocks, which depends on the sizes of the blocks.

For the method using undocumented functions, here is one that uses SparseArray`SparseBlockMatrix[], which has previously featured in past answers on block matrices (here I use the same definitions as above):

With[{m = 5, k = Length[cmat]},
  bigMat = SparseArray`SparseBlockMatrix[
     Join[MapIndexed[Join[#2, #2] -> #1 &, ConstantArray[cmat, m]], 
          MapIndexed[Join[#2, #2 + 1] | Join[#2 + 1, #2] -> #1 &, 
                     ConstantArray[dmat, m - 1]]]]];

which should give the same matrix.

(Perhaps someday, Mathematica will have better handling of block matrices.)

How can I generate a tridiagonal block matrix?

2 Answers2