How to get a membership condition for RegionBoundary using RegionMember

Question

This is my first question on this forum, but by no means my first problem with Mathematica (which I've been using daily for years).

Consider

Clear[x, y]
reg = RegionBoundary[ImplicitRegion[0 < x < 2 \[And] 0 < y < -2 x + 4, {x, y}]];

In Mathematica 10.3, the expression

RegionMember[reg, {x, y}]

evaluates to the following logical condition

(x | y) \[Element] Reals && ((x == 0 && 
 0 <= y <= 4) || (0 < x < 2 && (y == 0 || y == 4 - 2 x)) || (x == 
  2 && y == 0))

which is correct. However, since version 12 (at least) the result is not a symbolic condition anymore, but a RegionMemberFunction expression.

How can one get the predicate above or something equivalent?

RegionMember gives logical condition for implicit regions, so I thought to try RegionConvert[reg,"Implicit"]. But that doesn't evaluate. Alternatively, first converting to mesh with Chop[RegionConvert[DiscretizeRegion[reg], "Implicit"]] gives the full region, not the boundary. — tad, Jun 15 '22 at 23:04
CylindricalDecomposition[0<x<2&&0<y<-2 x+4,{x,y},"Boundary"]//Simplify — chyanog, Jun 16 '22 at 05:07
I don't even get a RegionMemberFunction in MMA 12.0, I just get the expression returned unevaluated. — N.J.Evans, Jun 16 '22 at 13:33

score 8 · Answer 1 · answered Jun 16 '22 at 12:57

8

cond = CylindricalDecomposition[0 < x < 2 && 0 < y < -2 x + 4, {x, y}, "Boundary"
  ] // Simplify

(x == 0 && y >= 0 && 2 x + y <= 4) || (0 <= x && ((y == 0 && x <= 2) || (2 x + y == 4 && x < 2)))

RegionPlot[ImplicitRegion[cond, {x, y}], Frame -> False]

answered Jun 16 '22 at 12:57

chyanog

chyanog, thank you very much for the answer, especially for bringing attention to CylindricalDecomposition and its topological powers acquired in version 11.2 (which I had forgotten about!). – Gregos Troianos Educacional Jun 16 '22 at 21:56
@GregosTroianosEducacional It’s my pleasure. – chyanog Jun 17 '22 at 04:36

1 Answers1