Improving progress bar code (10 years latter)

Question

In the last 10 years (see this post) when I want to track the result of a longer calculation, I use the following pattern:

SetAttributes[progressBar,HoldFirst]
progressBar[i_,total_]:= Module[{},
    Echo@Dynamic@Row[
        {ProgressIndicator[i,{0,total}]," ",NumberForm[100.i/total,{\[Infinity],2}],"% ",i}
    ]
]

so I can monitor a function as follows, using progressBar

progressExample[data_List]:= Module[{i = 0,len = Length@data},
    progressBar[i,len];
    Scan[(i++;Pause[0.1];f[#])&,data]
]
progressExample[Range[10]]

The problem is that this code crashes for long runs, I think because of the use of Dynamic. Some idea for a better way to do that? Any suggestions for a more modern or native solution?

I think almost any solution will need to use Dynamic in some way. So if you are experiencing crashes that you want to prevent, we'll need some kind of example to reproduce them. — Lukas Lang, Aug 13 '22 at 13:01
If the crash is reliably reproducible we'd definitely like to have an example that shows it. (I guess this is paradoxically asking for reliable unreliability.) — Daniel Lichtblau, Aug 17 '22 at 08:51

Nasser · Answer 1 · 2022-08-13T05:31:25.943

If you are willing to explicitly insert a call inside your computation loop to a progress updating small function, then you can do this in much simpler way without using Dynamics at all.

It is not a progress indicator, but prints the progress % only. It only uses PrintTemporary. So you have to make this explicit call anywhere in your code you want to update the progress. I would put it at the bottom of the loop for example.

Video

Code

CurrentValue[$FrontEnd, {"PrintAction"}] = {"PrintToNotebook"}
progressBar[currentValue_?NumericQ, maxValue_?NumericQ] := Module[{per},
      NotebookDelete[temp]; 
      per = Row[{NumberForm[100. currentValue/maxValue, {∞, 2}], "% "}];
      temp = PrintTemporary[per];
  ]
progressExample[data_List] := Module[{i = 0, len = Length@data},
      Scan[
            (i++; Pause[0.2];
              progressBar[i, len];
              f[#]) &, data
        ]
   ];
progressExample[Range[60]]

Version that uses PrintTemporary with ProgressIndicator

This version adds the actual bar, but still does not use Dynamics. Only PrintTemporary

progressBarV2[currentValue_?NumericQ, maxValue_?NumericQ] := Module[{per},
      NotebookDelete[temp]; 
      per = Row[{Spacer[5], NumberForm[100. currentValue/maxValue, {∞, 2}], "%"}];
      temp = PrintTemporary@Row[{ProgressIndicator[currentValue, {0, maxValue}], per}]
  ]

So just call the above V2 instead. This is the result

While this doesn't use Dynamic, it does perform notebook manipulation (printing and deleting cells). And in my experience, cell creation can be worse for performance than a suitably optimized dynamic expression. But of course, if the Dynamic expressions are actually causing the crash, this might help. (Assuming the repeated cell creation doesn't upset the front-end even more) — Lukas Lang, Aug 13 '22 at 13:23

score 3 · Answer 2 · answered Aug 13 '22 at 19:59

progressBar[i_, high_] := Module[{},
  Row[{
    ProgressIndicator[i, {0, high}],
    Spacer[10], i,
    " (", NumberForm[100. i/high, {\[Infinity], 2}], "%)"
    }]
  ]

progressExample[data_List] := Module[{i = 0, len = Length@data},
  Monitor[
   Scan[(i++; Pause[0.1]; f[#]) &, data],
   progressBar[i, len]
   ]
  ]

progressExample[Range[150]]

Improving progress bar code (10 years latter)

2 Answers2

Video

Code

Version that uses PrintTemporary with ProgressIndicator