3

I am trying to find the normal and tangent of acceleration. I know the formula for the tangent of acceleration is $((Acceleration . Velocity)/(Velocity.Velocity))*Velocity$ and the normal of acceleration is the same but with $Velocity$ replaced with the perpendicular of velocity. I think my errors arise because I am trying to manipulate parametric functions incorrectly.

Anyway, here is my attempt:

Clear[t,x,y,z,P,velocity,acceleration,atan,tanvector];
x[t_] = 2 Sin[t]; 
y[t_] = 6 Sin[t/2]^2;
z[t_] = 3 Cos[t];
P[t_] = {x[t], y[t], z[t]}; 

curveplot = ParametricPlot3D[P[t],{t,1,6},PlotStyle->Thickness[0.01]];
velocity[t_] = {x'[t], y'[t], Z'[t]};
acceleration[t_] = {x''[t], y''[t], z''[t]};

atan[t_] = ((acceleration[t].velocity[t])/(velocity[t].velocity[t]))*velocity[t];
tanvector[t_]:= Vector[atan[t],Tail->P[t],VectorColor->Blue]

Show[curveplot,Table[tanvector[t],{t,1,6,(6-1)/10}],
  PlotRange -> All, AxesLabel -> {"x","y","z"}]

This question is different from this question: Finding unit tangent normal and binormal vectors because I am asking for the tangent and normal of acceleration using the equation: $((Acceleration . Velocity)/(Velocity.Velocity))*Velocity$.

I am missing an undertanding of how to manipulate parametric plots.

Community
  • 1
J. Musk
  • 157
  • 1
  • 8
  • 1
    Please note that you can format your question better using Markdown. See for more information the question mark button at the top right of the edit box – Sjoerd C. de Vries Jun 23 '13 at 21:31
  • Site users are accustomed to read code formatted as I have done (and as Sjoerd hinted that you do). It's hard for users to quickly parse unformatted code. With it now being formatted, one thing that pops out is that for the Dot product, you should use a period, not a center dot: acceleration[t].velocity[t], and so forth. – Michael E2 Jun 24 '13 at 00:02
  • I'd like to believe this site is useful for some people, but so far, it seems like people just mark questions as duplicates because they dont feel like responding. These duplicates end up being related only by name and not by solution. Sigh... I'll search for a different forum. – J. Musk Jun 24 '13 at 00:53
  • I think you're right, this isn't a duplicate of the other question. I think people may have been misled by your terminology; what you want are called the normal acceleration and tangential acceleration. Hopefully, someone with enough points will vote to reopen the question. // By the way, I can't try out your code to see what's wrong because it doesn't work without a definition of Vector (same problem as with your last question). –  Jun 24 '13 at 04:15
  • 2
    @J.Musk - I have reopened your question for the time being. Please understand that people aren't closing questions because they don't feel like answering them; sometimes they can be genuinely misled by confusing terminology, as in this case. Please also understand that everyone here is volunteering their own time to help others with their questions, and it helps us to help you if you provide complete minimum working examples and make some effort to format your post to be legible. – Verbeia Jun 24 '13 at 04:32
  • 1
    @J.Musk - I'd also point out that marking a question is duplicate is not the same as closing it for some problem (e.g. being off-topic). It is not intended as negative feedback. It's a device for saving everyone some time. If your issue has already been answered adequately elsewhere, then you will get quicker resolution by being pointed to that answer than by waiting for someone to come up with another version of the same solution. – Verbeia Jun 24 '13 at 04:40

1 Answers1

2

You had a typo in the definition of velocity: capital Z instead of z. With this typo fixed, you may be able to get the result you want. However, I can't use your plot commands directly to verify this because Vector isn't defined. So I use a simple replacement by Arrow for this purpose:

Clear[t, x, y, z, P, velocity, acceleration, atan, tanvector];
x[t_] = 2 Sin[t];
y[t_] = 6 Sin[t/2]^2;
z[t_] = 3 Cos[t];
P[t_] = {x[t], y[t], z[t]};

curveplot = 
  ParametricPlot3D[P[t], {t, 1, 6}, PlotStyle -> Thickness[0.01]];
velocity[t_] = {x'[t], y'[t], z'[t]};
acceleration[t_] = {x''[t], y''[t], z''[t]};


atan[t_] = ((acceleration[t].velocity[t])/(velocity[t].velocity[t]))*
   velocity[t];
tanvector[t_] := {Blue, Arrow[{#, # + atan[t]} &@P[t]]}

Show[curveplot, Graphics3D@Table[tanvector[t], {t, 1, 6, (6 - 1)/10}],
  PlotRange -> All, AxesLabel -> {"x", "y", "z"}]

plot3d

Jens
  • 97,245
  • 7
  • 213
  • 499