Drawing a surface of revolution

Question

I am trying to draw using parametricplot3d a surface of revolution.(i know i could use revolutionplot3d but i want to try and draw it with parametricplot3d instead)

Here is my code but for some reason i'm not getting the desired image.

eq = Function[x, c*Cosh[x/c]]
sol = NSolve[{eq[-1] == 2, eq[1] == 2}, {c}, Reals]
{c1, c2} = c /. sol
f1 = Function[x, c1Cosh[x/c1]]
F1[x] = 2Pif1[x]Sqrt[1 + f1'[x]^2];
sol2 = Integrate[F1[x], {x, -1, 1}]
f2 = Function[x, c2Cosh[x/c2]]
F2[x] = 2Pif2[x]Sqrt[1 + f2'[x]^2];
sol3 = Integrate[F2[x], {x, -1, 1}]
ParametricPlot3D[{u, c1Cosh[u/c1], c2Cosh[u/c2]}, {u, -1, 1}, 
 AxesLabel -> {x, y, z}]

I am looking to get an image simillar to this:

But instead im getting this:

What am i doing wrong here?

Answer 1

Perhaps the following:

f1[x_] := c1*Cosh[x/c1];
f2[x_] := c2*Cosh[x/c2];
ParametricPlot3D[{u, f1[u] Cos[ϕ], f2[u] Sin[ϕ]}, {ϕ, 
  0, 2 π}, {u, -1, 1}, AxesLabel -> {x, y, z}]

If the constants {c1,c2} go to 1, you will get a regular hyperboloid.

Answer 2

There are two parametric curves in the plane: {u, c1*Cosh[u/c1]} and {u, c2*Cosh[u/c2]},we need to draw two surfacdes.(catenary surface https://en.wikipedia.org/wiki/Minimal_surface_of_revolution)

Method-1

• RevolutionPlot3D and set RevolutionAxis -> "X".

{RevolutionPlot3D[{u, c1*Cosh[u/c1]}, {u, -1, 1}, {θ, 0, 
   2 π}, RevolutionAxis -> "X"], 
 RevolutionPlot3D[{u, c2*Cosh[u/c2]}, {u, -1, 1}, {θ, 0, 
   2 π}, RevolutionAxis -> "X"]}

Method-2

• for parametric curve {x[u],y[u]}, the revolution surface around x-axis is

{x[u], y[u]*Cos[θ], y[u]*Sin[θ]}

x[u_] = u;
y1[u_] = c1*Cosh[u/c1];
y2[u_] = c2*Cosh[u/c2];
{ParametricPlot3D[{x[u], y1[u]*Cos[θ], y1[u]*Sin[θ]}, {u, -1, 1}, {θ, 0, 2 π}],ParametricPlot3D[{x[u], y2[u]*Cos[θ], y2[u]*Sin[θ]}, {u, -1, 1}, {θ, 0, 2 π}]}