How to save a sequence as a plain text file?

Question

I would like to be able to generate data files like the ones provided with NIST SP 800-22 (binary expansions of irrational constants), which contain data akin to

1010011111001

According to the documentation the following Mathematica code is used to generate the data:

BinExp[num_,d_] := Module[{n,L},
                     If[d > $MaxPrecision, $MaxPrecision = d];
                        n = N[num,d];
                        L = First[RealDigits[n,2]]
                     ];
SE = BinExp[E,302500];
Save["data.e",{SE}];

However, when I run said code I get a file that begins with

SE = {1, 0, 1, 0, 1, 1, 0, 1, 1, 1, 1, 1, 1, 0, 0, 0, 0, 1, 0, 1, 0, 1, 0, 0, ...

What can I do to make the saved file like th first example of just the 1s and 0s?

It is customary to stay responsive to comments as it is to provide feedback for the answers posted. — Syed, Nov 07 '22 at 11:48

Nasser · Accepted Answer · 2022-11-07T15:12:33.203

2

This works. But may be there is better way

SetDirectory[NotebookDirectory[]]
binExp[num_, d_] := 
  Module[{n, L}, If[d > $MaxPrecision, $MaxPrecision = d];
   n = N[num, d];
   L = First[RealDigits[n, 2]]];
SE = binExp[E, 302500]
Export["data.txt", StringJoin[ToString[#] & /@ SE]];

Screen shot of the file (the line is very long, over 1 million digits) this the start of it:

Update

Another option instead of explicitly converting the output to string is to use Character8 for format thanks to suggestion by Ben Izd below.

 Export["data.txt", SE, "Character8"]

Both methods give the same exact output file.

edited Nov 07 '22 at 15:12

answered Nov 07 '22 at 03:53

Nasser

143,286
11
154
359

I believe that this is a solution! – YaGoi Root Nov 07 '22 at 14:02
1

Appreciate the answer. It could be even more straightforward with "Character8" format. – Ben Izd Nov 07 '22 at 14:18
@BenIzd thanks, updated answer with your suggestion. – Nasser Nov 07 '22 at 14:24
1

You can use the Export's third argument to specify the format to make it even better ;) – Ben Izd Nov 07 '22 at 14:28
@BenIzd Yes, this is even better, I did not know about "character8", that is useful format to know. – Nasser Nov 07 '22 at 15:05

Roman · Answer 2 · 2022-11-07T15:38:46.630

2

BinExp[num_, d_] := IntegerString[Round[2^d num], 2]
SE = BinExp[E, 302500];
Export["data.txt", SE]

Maybe use Floor instead of Round, depending on what you need for the last digit.

edited Nov 07 '22 at 15:38

answered Nov 07 '22 at 15:20

Roman

47,322
2
55
121

How to save a sequence as a plain text file?

2 Answers2