How show multiplication of more than two matrix in just one line?

Question

I have been going though some matrix multiplication problem and there I faced this kind of problem where I am trying to show the whole multiplication form in the next line of H.S.T.H.zero // MatrixForm but it's not working and I have to put all the matrix elements manually.

zero = {{1}, {0}} // MatrixForm
H = 1/sqrt[2] {{1, 1}, {1, -1}} // MatrixForm
S = {{1, 0}, {0, I}} // MatrixForm
T = {{1, 0}, {0 , E^(I Pi/4)}} // MatrixForm
H.S.T.H.zero // MatrixForm

the output it's showing --->

But the output I want ----->

If there any way to solve this please let me know! I would be very greatful.

score 4 · Answer 1 · answered Nov 12 '22 at 15:32

$Version

(* "13.1.0 for Mac OS X x86 (64-bit) (June 16, 2022)" *)

Clear["Global`*"]

sqrt should be Sqrt. All built-in functions start with a capital letter.

zero = {{1}, {0}};
H = 1/Sqrt[2] {{1, 1}, {1, -1}};
S = {{1, 0}, {0, I}};
T = {{1, 0}, {0, E^(I Pi/4)}};
(eqn = Inactivate[(H . S . T . H . zero), Dot] == 
    Simplify[H . S . T . H . zero]) /. mat_?MatrixQ :> MatrixForm[mat]

Activate@eqn
(* True *)

score 1 · Accepted Answer · answered Nov 12 '22 at 21:54

if you like Latex, you could also use Matex package.

<< MaTeX`
SetOptions[MaTeX, Magnification -> 2]
zero = {{1}, {0}}
H = 1/Sqrt[2] {{1, 1}, {1, -1}}
S = {{1, 0}, {0, I}}
T = {{1, 0}, {0, E^(I Pi/4)}}
result = H . S . T . H . zero

And now

Row[{MaTeX[MatrixForm@H],
  MaTeX[MatrixForm@S],
  MaTeX[MatrixForm@T],
  MaTeX[MatrixForm@H],
  MaTeX[MatrixForm@zero],
  MaTeX["="],
  MaTeX[MatrixForm@result]
  }]

If you want an explicit multiplication between them, (even though I do not think it is needed) you can do

Row[{MaTeX[MatrixForm@H],
  MaTeX["\\times"],
  MaTeX[MatrixForm@S],
  MaTeX["\\times"],
  MaTeX[MatrixForm@T],
  MaTeX["\\times"],
  MaTeX[MatrixForm@H],
  MaTeX["\\times"],
  MaTeX[MatrixForm@zero],
  MaTeX["="],
  MaTeX[MatrixForm@result]
  }]

But if you prefer dot for multiplication

Row[{MaTeX[MatrixForm@H],
  MaTeX["\\cdot"],
  MaTeX[MatrixForm@S],
  MaTeX["\\cdot"],
  MaTeX[MatrixForm@T],
  MaTeX["\\cdot"],
  MaTeX[MatrixForm@H],
  MaTeX["\\cdot"],
  MaTeX[MatrixForm@zero],
  MaTeX["="],
  MaTeX[MatrixForm@result]
  }]

How show multiplication of more than two matrix in just one line?

2 Answers2