How can I rotate the x and y axis?

Question

I would like to know if it is possible to carry out a rotation involving the x and y axis (the gridline too) cause I know how to do it with a vector and an arrow but not with the axis.

If you want a rotated object for visualization that is not a graphics object Rotate[Plot[x^2, {x, -2, 2}], 45 Degree] — userrandrand, Dec 01 '22 at 19:21
If you want an image : Plot[x^2, {x, -2, 2}] // Image // ImageRotate[#, 45 Degree] & — userrandrand, Dec 01 '22 at 19:21
If you want a graphics object then maybe you would need to construct the plot as a graphics object first. see here for how to extract the ticks. For the curve you can use Plot[x^2, {x, -2, 2}] //Cases[#,_Line,All] & — userrandrand, Dec 01 '22 at 19:26
You can also make a graphics Object from the image with errors using ImageGraphics — userrandrand, Dec 01 '22 at 19:27
Please post a draft to illustrate the meaning of rotate the x,y and gridlines. — cvgmt, Dec 04 '22 at 04:09

score 3 · Accepted Answer · answered Dec 01 '22 at 20:12

3

Here are two ways to get rotated axes:

Using the fifth argument of Inset:
```
Graphics[
 Inset[Graphics[{}, Axes -> True], {0, 0}, {0, 0}, {2, 2}, {{1, 1}, {0, 1}}],
 PlotRange -> 1
]
```
This will shear everything inside the inner Graphics expression. As you can see, even the labels of the axes are sheared.
Using AxisObject (new in 12.3):
```
Graphics[
 {AxisObject[Line@{{-1, -1}/Sqrt[2], {1, 1}/Sqrt[2]}], 
  AxisObject[Line@{{0, -1}, {0, 1}}]},
 PlotRange -> 1
]
```
Here, you can directly specify from where to where the axes should point. Only the direction of the axes is affected. As you can see, labels of the axes are not affected.

answered Dec 01 '22 at 20:12

Lukas Lang

33,963
1
51
97

Thank you, your comment has been very useful to me. Just one more thing, is this possible tu with manipulate so you can rotate the axis like that??? – Javieer Picazo Dec 04 '22 at 17:59
With the AxisObject approach, you should be able to add interactivity just as if you had a normal line, e.g. Manipulate[Graphics[{AxisObject[Line@{{0, 0}, Dynamic@p}]}, PlotRange -> 1], {{p, {1, 1}}, Locator}] – Lukas Lang Dec 04 '22 at 21:37

How can I rotate the x and y axis?

1 Answers1