Convert list of lists to cumulative join

Question

I have this:

list[1]={1,2,3};
list[2]={7,8,9};
list[3]={15,20,22};

I want this:

cumulativeList[1]={1,2,3};
cumulativeList[2]={1,2,3,7,8,9};
cumulativeList[3]={1,2,3,7,8,9,15,20,22};

Sort of like Accumulate, but using Join instead of Sum. I think it might be possible using FoldList but I'm getting confused.

Answer 1

Rather than using FoldList, this seems to be a perfect application of recursion and memoization, which leads to a very elegant solution:

(* Your original list *)
list[1] = {1, 2, 3};
list[2] = {7, 8, 9};
list[3] = {15, 20, 22};

(* The cumulative list *)
cumulativeList[0] = {};
cumulativeList[n_] := cumulativeList[n] = cumulativeList[n - 1] ~Join~ list[n]

Now you just need to evaluate cumulativeList[3] and automatically, all the other values (i.e. 1, 2) are calculated.

cumulativeList[3]
(* {1, 2, 3, 7, 8, 9, 15, 20, 22} *)

Table[cumulativeList[n], {n, 3}]
(* {{1, 2, 3}, {1, 2, 3, 7, 8, 9}, {1, 2, 3, 7, 8, 9, 15, 20, 22}} *)

Answer 2

list[1] = {1, 2, 3};
list[2] = {7, 8, 9};
list[3] = {15, 20, 22};

With[{x = Array[cumulativelist, 3]}, 
 x = Rest@FoldList[Join, {}, Array[list, 3]]]

{{1, 2, 3}, {1, 2, 3, 7, 8, 9}, {1, 2, 3, 7, 8, 9, 15, 20, 22}}

cumulativelist[3]

{1, 2, 3, 7, 8, 9, 15, 20, 22}

Answer 3

Here is a solution :

list[1] = {1, 2, 3};
list[2] = {7, 8, 9};
list[3] = {15, 20, 22};

Fold[Join[#1, #2] &, {}, {list[1]}]
Fold[Join[#1, #2] &, {}, {list[1], list[2]}]
Fold[Join[#1, #2] &, {}, {list[1], list[2], list[3]}]

{1, 2, 3}
{1, 2, 3, 7, 8, 9}
{1, 2, 3, 7, 8, 9, 15, 20, 22}

Note that the variable list begins with a lowercase. Using a uppercase is not recommended. It enters in conflict with Mathematica symbol names.

Answer 4

Table offers a simple approach without recursion and memoization.

concatenate[f_, {n_, m_}] := Join @@ Table[f[k], {k, n, m}]

Example

concatenate[list, {1, 3}]

{1, 2, 3, 7, 8, 9, 15, 20, 22}

Answer 5

Perhaps even simpler is to use Map

list[1] = {1, 2, 3};
list[2] = {7, 8, 9};
list[3] = {15, 20, 22}; 
Flatten[list[#] & /@ Range[3]]

{1, 2, 3, 7, 8, 9, 15, 20, 22}

You can make this into a function easily

cumList[list_] := Flatten[list[#] & /@ Range[Length[DownValues[list]]]]

Calling cumList[list] then gives the same answer as above. (Thanks to Anon for noticing the extra Join).

Answer 6

Perhaps the shortest solution is this:

Flatten@DownValues[list][[All, 2]]

{1, 2, 3, 7, 8, 9, 15, 20, 22}

And the requested function cumulativeList:

cumulativeList[n_] := Flatten@DownValues[list][[1 ;; n, 2]]

In case you chose to write your list like this instead, it would be simpler:

list = {{1, 2, 3}, {7, 8, 9}, {15, 20, 22}}

Namely,

cumulativeList[n_] := Flatten[list[[1 ;; n]]]

Answer 7

Flatten[list /@ #] & /@ Range[Range[3]]

{{1, 2, 3}, {1, 2, 3, 7, 8, 9}, {1, 2, 3, 7, 8, 9, 15, 20, 22}}

Answer 8

Here is an iterative example:

(* Your lists *)
Clear[cumulativeList]
cumulativeList[n_] := Module[{},
  cumulativeList[0] = {};
  For[x = 0, x < n, x++,
   Print[cumulativeList[x + 1] = 
     Join[cumulativeList[x], list[x + 1]]]]]

 cumulativeList[1]

 (*{1, 2, 3}*)
 cumulativeList[2]

 (*{1, 2, 3, 7, 8, 9}*)
 cumulativeList[3]

 (*{1, 2, 3, 7, 8, 9, 15, 20, 22}*)

Answer 9

FoldList[(cumulativeList[#2[[1, 1, 1]]] = Join[#1, #2[[2]]]) &, {}, 
 DownValues[list]]

This gives you all the indexed variables at once (which is what you asked), rather than providing a function to calculate them. Works for all available indices, even with gaps in numbering and even for non-numeric indices.

Answer 10

Here's a one-liner using Join and a pure function:

list[1] = {1, 2, 3};
list[2] = {7, 8, 9};
list[3] = {15, 20, 22};

JoinList[number_] := Join @@ (list[#] & /@ Range[number]);

Then you can evaluate

JoinList[1]

{1, 2, 3}

JoinList[2]

{1, 2, 3, 7, 8, 9}

JoinList[3]

{1, 2, 3, 7, 8, 9, 15, 20, 22}

Hope this helps!

Answer 11

Terse syntax for FoldList:

FoldList[Join, Array[list, 3]]

{{1, 2, 3}, {1, 2, 3, 7, 8, 9}, {1, 2, 3, 7, 8, 9, 15, 20, 22}}

Reference:

• Shorter syntax for Fold and FoldList?