Finding the Degree of a Differential Equation (ODE or PDE)

Question

How to create a Mathematica code for finding degree of a Differential Equation (ODE or PDE)?

For example;

1. The degree of the following ODE is 2.

   eq1=(D[u[t], {t,3}])^2-D[u[t], {t,2}] u[t] +D[u[t],t]==0

2. The degree of the following PDE is 3.

eq2=D[u[x,y], x] + (D[u[x,y], x,y])^3==0

3. As far as I know, the degree is not defined since the PDE is not in polynomial form.

eq3=D[u[x,y], x] + Sin[D[u[x,y], x,y]]==0

4. The degree of the following PDE is 2.

eq4=(1 + y'[x]^2)^(3/2) == y''[x]

Answer 1

This is too long to post in comment.

These are the tests I use to finding ode degree. Could be used to verify your answers. Each list has the ode as first entry, and the degree expected. Some ode's have no defined degree. Feel free to edit this community wiki post and add your own tests to this list.

test1 = {{y'[x] == y[x]^(1/2), 1},
   {y'[x] + y''[x] == 0, 1},
   {y'[x] + y''[x]^2 == 0, 2},
   {y''[x] + y'[x]^(1/2) == y[x], 2},
   {(1 + y'[x]^2)^(3/2) == y''[x], 2},
   {3*y[x]^2*y'[x]^3 - y''[x] == Sin[x^2], 1},
   {Sqrt[1 + y'[x]^2] == y[x]*y'''[x], 2},
   {Sqrt[1 + y'[x]^2] == y[x]*y'''[x]^2, 4},
   {Sin[y'[x]] + y'''[x] + 3*x == 0, "undefined"},
   {Exp[y''[x]] + Sin[x]*y'[x] == 1, "undefined"},
   {k*y''[x]^2 == (1 + y''[x]^2)^3, 6},
   {x*y''[x]^3*y'[x] - 5*Exp[x]*y''[x] + y[x]*Log[y[x]] == 0, 3},
   {2*Log[x]*y'[x]^2 + 7*Cos[x]*y''[x]^4*y'[x]^7 + x*y[x] == 0, 4},
   {y[x] - x*y'[x] - 1/(2*y'[x]^2) == 0, 3},
   {y''[x] - a*(c + b*x + y[x])*(y'[x]^2 + 1)^(3/2) == 0, 2}
   };

To find max derivative (not degree), this is the code I use in case it is needed also.

(*This function getPatterns is thanks to Carl Woll,see https://mathematica.stackexchange.com/questions/151850/using-cases-and-when-to-make-input-a-list-or-not*)
getPatterns[expr_, pat_] := 
 Last@Reap[expr /. a : pat :> Sow[a], _, Sequence @@ #2 &];
getMaxOrder[ode_, y_, x_] := Module[{der, n},
  der = getPatterns[ode, Derivative[n_][y][x]];
  Max[Cases[der, Derivative[n_][y][x] :> n]]
  ]

This gives against the above tests the following

getMaxOrder[First[#], y, x] & /@ tests
(* {1, 2, 2, 2, 2, 2, 3, 3, 3, 2, 2, 2, 2, 1, 2} *)

The definition of degree used is from Ince book

Update

This test table is based on definition of degree for ode suggested by Michael below which is different from the one in Ince book. So solution based on this definition should be OK also. I've updated the above to reflect this new definition.

test2 = {{y'[x] == y[x]^(1/2), 1}, 
    {y'[x] + y''[x] == 0, 1}, 
    {y'[x] + y''[x]^2 == 0, 2}, 
    {y''[x] + y'[x]^(1/2) == y[x], 1}, 
    {(1 + y'[x]^2)^(3/2) == y''[x], 1}, 
    {3*y[x]^2*y'[x]^3 - y''[x] == Sin[x^2], 1}, 
    {Sqrt[1 + y'[x]^2] == y[x]*y'''[x], 1}, 
    {Sqrt[1 + y'[x]^2] == y[x]*y'''[x]^2, 2}, 
    {Sin[y'[x]] + y'''[x] + 3*x == 0, 1}, 
    {Exp[y''[x]] + Sin[x]*y'[x] == 1, "undefined"}, 
    {k*y''[x]^2 == (1 + y''[x]^2)^3, 6}, 
    {x*y''[x]^3*y'[x] - 5*Exp[x]*y''[x] + y[x]*Log[y[x]] == 0,3}, 
    {2*Log[x]*y'[x]^2 + 7*Cos[x]*y''[x]^4*y'[x]^7 + x*y[x] == 0, 4}, 
    {y[x] - x*y'[x] - 1/(2*y'[x]^2) == 0, "undefined"}, 
    {y''[x] - a*(c + b*x + y[x])*(y'[x]^2 + 1)^(3/2) == 0, 1}, 
    {Cos[y'[x]^2] + y''[x]^2 == 0, 2}, 
    {Cos[y''[x]^2] + y'[x]^2 == 0, "undefined"}
   };

Answer 2

There seems to be more than one definition for degree of ode. Lets call the one in Ince book (reference given in the above wiki post) the strict definition, which require first converting the ode to polynomial in all the derivatives, and definition mentioned by Michael above from another text which we can call the non strict definition. In this definition, the ode just have to be a polynomial in the highest order term.

test2 table given in the above wiki post is based on the non strict definition. While test1 table is based on the strict definition

This code below implements non strict definition to finding the degree of an ode.

(*This function getPatterns is thanks to Carl Woll,see https://mathematica.stackexchange.com/questions/151850/using-cases-and-when-to-make-input-a-list-or-not*)
getPatterns[expr_, pat_] := 
  Last@Reap[expr /. a : pat :> Sow[a], _, Sequence @@ #2 &];
getMaxOrder[ode_, y_Symbol, x_Symbol] := Module[{der, n},
   der = getPatterns[ode, Derivative[n_][y][x]];
   Max[Cases[der, Derivative[n_][y][x] :> n]]
   ];
getDegree[odeIn_Equal, y_Symbol, x_Symbol] := 
 Module[{ode = First@odeIn - Last@odeIn, order, z, degree},
  order = getMaxOrder[ode, y, x];
  ode = ode /. Derivative[order][y][x] :> z;
  If[PolynomialQ[ode, z],
   degree = Exponent[ode, z];
   ,
   degree = "undefined"
   ];
  degree
  ]

And now

data = {First[#], getMaxOrder[First[#], y, x], getDegree[First[#], y, x]} & /@ test2;
PrependTo[data, {"ode", "order", "degree"}];
Grid[data, Frame -> All]

The table test2 can be found in the above wiki post.

Answer 3

Sort of a hack is to make a string out of the full form and then extract the order of the derivatives and finally convert it back to an expression and taking the max. Here is an example:

getDeg[ex_] := Module[{str},
  str = ToString[FullForm@ex]; Print[str];
  str = StringCases[str, 
    RegularExpression["Derivative\\[(\\d,*\\s*\\d*)\\]"] :> 
     StringReplace["$1", "," -> "+"]];
  Max[Total @@@ ToExpression /@ str]
  ]

Now, as already mentioned, your examples give wrong degrees. With the above we get:

getDeg[eq1]   
3
getDeg[eq2]
2
getDeg[eq3]
2