How to combine several legends in one frame?

Question

I'm using Show to combine three plots. The code I write is as follows:

g1 = Plot[x^2 + 3, {x, 0, 3}, 
   PlotLegends -> 
    Placed[LineLegend[{TraditionalForm[k == 1]}, 
      LegendLayout -> "Row", 
      LegendFunction -> (Framed[#1, FrameMargins -> 0] & )], Below], 
   AxesOrigin -> {0, 0}, PlotStyle -> Red];
g2 = Plot[x^3 + x, {x, 1, 4}, 
   PlotLegends -> 
    Placed[LineLegend[{TraditionalForm[k == 2]}, 
      LegendLayout -> "Row", 
      LegendFunction -> (Framed[#1, FrameMargins -> 0] & )], Below], 
   AxesOrigin -> {0, 0}, PlotStyle -> Blue];
g3 = Plot[20/x, {x, 1/2, 4}, 
   PlotLegends -> 
    Placed[LineLegend[{TraditionalForm[k == 3]}, 
      LegendLayout -> "Row", 
      LegendFunction -> (Framed[#1, FrameMargins -> 0] & )], Below], 
   AxesOrigin -> {0, 0}, PlotStyle -> Black];
Show[{g1, g2, g3}, PlotRange -> {{0, 4}, {0, All}}]

The output is the following:

As we can see in the output, the three legends are seperate in three frames. How can I place the three legends in a row in one frame?

This answer might be useful: https://mathematica.stackexchange.com/a/127213/8822 — mattiav27, Apr 30 '23 at 11:31

score 6 · Answer 1 · answered Apr 30 '23 at 11:32

6

show = Show[{g1, g2, g3}, PlotRange -> {{0, 4}, {0, All}}];

Extract the main plot and legends from show and reorganize them in desired form:

plot = Cases[show, _Graphics, All][[1]];
legendargs = Transpose @
   Cases[show, LineLegend[arg1_, arg2_, opts___] :> {arg1, arg2, opts}, All];
newlegend = Placed[LineLegend @@ legendargs, 
    ## & @@ First @ Cases[show, Placed[_, a___] :> {a}, All]];
Legended[plot, newlegend]

answered Apr 30 '23 at 11:32

kglr

394,356
18
477
896

It indicates an error when I run the code newlegend = Placed[LineLegend @@ legendargs, ## & @@ First @ Cases[show, Placed[_, a___] :> {a}, All]]. Did you miss something in this code? – Ya He Apr 30 '23 at 12:51
@YaHe, what is the error message? – kglr Apr 30 '23 at 12:54
It indicates that "First::nofirst, the length of {} is zero, there is no first element" – Ya He Apr 30 '23 at 13:02
how about Cases[show, _Graphics, All][[1]]? what does it give? – kglr Apr 30 '23 at 13:05
It is normal. The only abnormal one is newlegend = Placed[LineLegend @@ legendargs, ## & @@ First @ Cases[show, Placed[_, a___] :> {a}, All]]; – Ya He Apr 30 '23 at 13:08
1

It could be version/os difference (I am using V13.1.0 on Linux). Try newlegend=Placed[LineLegend @@ legendargs, Below]. – kglr Apr 30 '23 at 13:12
Let us continue this discussion in chat. – Ya He Apr 30 '23 at 13:21
1

Many thanks. It works now (I'm also using V13.1). Besides, by reducing the FrameMargins in the plot g1, g2, g3, I can reduce the margin of the legends frame in the final output. – Ya He Apr 30 '23 at 13:43

score 4 · Answer 2 · answered Apr 30 '23 at 11:53

4

With[{ll = LineLegend}, 
 ToExpression@
   ToBoxes@Show[{g1, g2, g3}, 
     PlotRange -> {{0, 4}, {0, All}}] //. {ll[{a1__}, {b1__}, c__], 
    ll[{a2_}, {b2_}, c__], rest___} :> {ll[{a1, a2}, {b1, b2}, c], rest}]

To understand why ToBoxes and ToExpression are used, read the following:

Graphics in Notebook Different from Graphics Expression?

Function equal to Ctrl+Shift+I

answered Apr 30 '23 at 11:53

xzczd

65,995
9
163
468

Thanks! Your proposal works well! – Ya He Apr 30 '23 at 13:46
I have one question about your code. Sometimes the combined legend may be displayed in two rows (this happens when each legend is a bit long). Do you know how to make the combined legend always shown in one row? – Ya He May 02 '23 at 00:47
@YaHe It's answered in this post: https://mathematica.stackexchange.com/q/26231/1871 – xzczd May 02 '23 at 02:09
Thanks! I have solved the problem. – Ya He May 02 '23 at 02:20
@YaHe Then you should tell kglr you've solved this. – xzczd May 02 '23 at 02:45
Ok, I will tell him – Ya He May 03 '23 at 05:29

How to combine several legends in one frame?

2 Answers2