1
Solve[{TrigExpand[Tan[2 α]] == Cos[α]/(2 - Sin[α]), 
       tanα == Sin[α]/Cos[α], 
       0 < α < π/2}, tanα, {Sin[\[Alpha]], Cos[\[Alpha]]}]

It returns {{t -> ConditionalExpression[Tan[\[Alpha]], 0 < \[Alpha] < \[Pi]/4 || \[Pi]/4 < \[Alpha] < \[Pi]/2]}}, which is incorrect.

the correct answer is tan α=√15/15

csn899
  • 3,953
  • 6
  • 13
  • It looks like alpha became x in the solve variables. – Daniel Lichtblau May 16 '23 at 14:14
  • Cos[\[Alpha]]/(2 - Sin[\[Alpha]]), t == Sin[\[Alpha]]/Cos[\[Alpha]], 0 < \[Alpha] < \[Pi]/2}, t, {Sin[\[Alpha]], Cos[\[Alpha]]}]```The result calculated in this way is also incorrect – csn899 May 16 '23 at 14:19
  • One should evaluate Solve[{TrigExpand[Tan[2 α]] == Cos[α]/(2 - Sin[α]), tanα == Sin[α]/Cos[α], 0 < α < π/2}, tanα, {Sin[α], Cos[α]}, MaxExtraConditions -> All] or Reduce[{TrigExpand[Tan[2 α]] == Cos[α]/(2 - Sin[α]), tanα == Sin[α]/Cos[α], 0 < α < π/2}, tanα]. Why it should be is explained in What is the difference between Reduce and Solve? – Artes May 16 '23 at 14:20
  • @Artes The results obtained from both of your methods are incorrect. The real situation is that we cannot calculate the result – csn899 May 16 '23 at 14:22
  • It returns "Solve::fdimc: When parameter values satisfy the condition 0<[Alpha]<[Pi]/2, the solution set contains a full-dimensional component; use Reduce for complete solution information." and {} in 13.2.1 on Windows 10. – user64494 May 16 '23 at 14:25
  • @csn899 The both results are correct... You simply incorrectly use such a sophisticated function as Solve. – Artes May 16 '23 at 14:28
  • @Artes tan\[Alpha] -> ConditionalExpression[Tan[\[Alpha]], 0 < \[Alpha] < \[Pi]/2]the answer is incorrect – csn899 May 16 '23 at 14:31
  • @csn899 Why is it incorrect, have I missed anything? – Artes May 16 '23 at 14:33
  • In 13.2.1 the command from your latest edit produces "Solve::fdimc: When parameter values satisfy the condition 0<[Alpha]<[Pi]/2, the solution set contains a full-dimensional component; use Reduce for complete solution information." and {}. – user64494 May 16 '23 at 14:44
  • @Artes Did not calculate the final real number solution – csn899 May 16 '23 at 14:45
  • 1
    @csn899 Once more: the result is correct. You litter up this site! I pointed it out you incorrectly demand full information from Solve. It works correctly. You haven't read the link I provided. All what you need can be found there. – Artes May 16 '23 at 14:48
  • 1
    Not certain, but maybe this is along the lines of what is wanted? `In[128]:= tpolys0 = Numerator[ Together[{TrigExpand[Tan[2*alf]] - Cos[alf]/(2 - Sin[alf]), tan*Cos[alf] - Sin[alf]}]]; tpolys = Join[tpolys0 /. {Sin[_] -> s, Cos[_] -> c}, {c^2 + s^2 - 1}]

    Out[129]= {-c (c^2 - 4 s + s^2), -s + c tan, -1 + c^2 + s^2}

    In[131]:= Solve[tpolys == 0, tan, {c, s}]

    Out[131]= {{tan -> -(1/Sqrt[15])}, {tan -> 1/Sqrt[15]}}`

     – Daniel Lichtblau May 16 '23 at 15:19

3 Answers3

3

Weierstrass substitution \[Alpha] -> 2 ArcTan[u] gives the solution

eq = Tan[2 \[Alpha]] ==Cos[\[Alpha]]/(2 - Sin[\[Alpha]]) /. \[Alpha] -> 2 ArcTan[u] // TrigExpand // Simplify
(*1/2 (-1 + u^2) (1/(1 - u + u^2) - (8 u)/(1 - 6 u^2 + u^4)) == 0*)

solu=Solve[eq, u]  (* four solutions! )
({{u -> -1}, {u -> 1}, {u -> 4 - Sqrt[15]}, {u -> 4 + Sqrt[15]}}*)


alfa=Tan[2 ArcTan[u]] /. solu // TrigExpand // Simplify
(* {-([Pi]/2), [Pi]/2, 2 ArcTan[4 - Sqrt[15]], 2 ArcTan[4 +Sqrt[15]]} *)


Plot[{Tan[2 [Alpha]],Cos[[Alpha]]/(2 - Sin[[Alpha]])}, {[Alpha], -Pi, Pi},GridLines -> { alfa , None}]

enter image description here

result Tan[\[Alpha]]

Map[Tan,alfa]
(*{ComplexInfinity, ComplexInfinity, Tan[2 ArcTan[4 - Sqrt[15]]],Tan[2 ArcTan[4 + Sqrt[15]]]}*)
Ulrich Neumann
  • 53,729
  • 2
  • 23
  • 55
  • You omitted an equation tanα == Sin[α]/Cos[α] in your eq. – user64494 May 16 '23 at 14:41
  • tan\[Alpha] is a variable to solve. – user64494 May 16 '23 at 14:47
  • @user644494 I don't need this extra equation tanα == Sin[α]/Cos[α] and gave the result for Tan[\[Alpha]]! – Ulrich Neumann May 16 '23 at 14:55
  • However, the system from the question is {TrigExpand[Tan[2 α]] == Cos[α]/(2 - Sin[α]), tanα == Sin[α]/Cos[α], 0 < α < π/2}. You also do not take into account 0 < α < π/2. – user64494 May 16 '23 at 15:03
  • 2
    @user64494 Your last three comments are completely neglectable! My solution covers the complete range -Pi<\[Alpha]<Pi, QP surely might select the solutions he is interested in. – Ulrich Neumann May 16 '23 at 15:11
  • Also it is not a good practice to seriously edit a post, not indicating the changes. – user64494 May 16 '23 at 15:13
  • 2
    I have expanded my answer due to YOUR first two comments, which showed me that you didn't unterstand my answer. And now I'm out of discussion! – Ulrich Neumann May 16 '23 at 15:25
2
$Version

(* "13.2.1 for Mac OS X ARM (64-bit) (January 27, 2023)" *)

Clear["Global`*"]

sol = Solve[{Tan[2 α] == Cos[α]/(2 - Sin[α]), 
    tanα == Sin[α]/Cos[α], 0 < α < π/2}, 
   tanα, MaxExtraConditions -> All] // FullSimplify

(* {{tanα -> 
   ConditionalExpression[1/Sqrt[15], α == 2 ArcTan[4 - Sqrt[15]]]}} *)

Verifying,

alpha = Rule @@ sol[[1, 1, -1, -1]]

(* α -> 2 ArcTan[4 - Sqrt[15]] *)


Tan[α] /. alpha // FullSimplify


(* 1/Sqrt[15] *)
Bob Hanlon
  • 157,611
  • 7
  • 77
  • 198
0

Hope your latest edit is last. The following works.

Reduce[{TrigExpand[Tan[2 \[Alpha]]] == 
Cos[\[Alpha]]/(2 - Sin[\[Alpha]]), tan\[Alpha] == Sin[\[Alpha]]/Cos[\[Alpha]], 
  0 < \[Alpha] < \[Pi]/2}, tan\[Alpha]]

\[Alpha] == 2 ArcTan[4 - Sqrt[15]] && tan\[Alpha] == Sin[2 ArcTan[4 - Sqrt[15]]]/ Cos[2 ArcTan[4 - Sqrt[15]]]

user64494
  • 26,149
  • 4
  • 27
  • 56
  • Sin[2 ArcTan[4 - Sqrt[15]]]/Cos[2 ArcTan[4 - Sqrt[15]]] == Sqrt[15]/15 performs True. – user64494 May 16 '23 at 14:39
  • Cos[\[Alpha]]/(2 - Sin[\[Alpha]]), tan\[Alpha] == Sin[\[Alpha]]/Cos[\[Alpha]], 0 < \[Alpha] < \[Pi]/2}, tan\[Alpha]] // FullSimplify``` – csn899 May 16 '23 at 14:43
  • Thank you for your answer. Why is it that sometimes a solution can solve a trigonometric function equation, and sometimes a reduce is used when it cannot be solved? – csn899 May 16 '23 at 14:44
  • Reduce is a more powerful command than Solve as noticed in the documentation. – user64494 May 16 '23 at 14:45
  • Cos[\[Alpha]]^2 - Sin[\[Alpha]]^2) == Cos[\[Alpha]]/( 2 - Sin[\[Alpha]]), tan\[Alpha] == Sin[\[Alpha]]/Cos[\[Alpha]], 0 < \[Alpha] < \[Pi]/2}, tan\[Alpha], {Sin[\[Alpha]], Cos[\[Alpha]]}] // FullSimplify``` – csn899 May 16 '23 at 14:49
  • Cos[\[Alpha]]^2 - Sin[\[Alpha]]^2) == Cos[\[Alpha]]/( 2 - Sin[\[Alpha]]), tan\[Alpha] == Sin[\[Alpha]]/Cos[\[Alpha]], 0 < \[Alpha] < \[Pi]/2}, tan\[Alpha]] // FullSimplify``` – csn899 May 16 '23 at 14:50
  • The same result as in my answer is produced by Reduce[{TrigExpand[Tan[2 \[Alpha]]] == Cos[\[Alpha]]/(2 - Sin[\[Alpha]]), tan\[Alpha] == Sin[\[Alpha]]/Cos[\[Alpha]], 0 < \[Alpha] < \[Pi]/2}, {tan\[Alpha], \[Alpha]}]. – user64494 May 16 '23 at 14:50
  • Is there any reason why this{Sin[\[Alpha]], Cos[\[Alpha]]} can lead to the ability to calculate the correct result? – csn899 May 16 '23 at 14:51
  • @csn899 Sorry, don't understand you. Please present the whole working command. – user64494 May 16 '23 at 15:08