Embedding text on an opaque plane in 3D

Question

A simplified specification of what I am trying to accomplish would be to construct a cube each face with a different color and each face having a text label that can be seen only when viewing from the front direction of the face (I do not want the labels on the back and side faces to show through the cube.) I also want the labels to be in the plane of the face and to remain in the plane of the face as I rotate the cube.

Like a Texture[]? http://reference.wolfram.com/mathematica/ref/Texture.html — Dr. belisarius, Jul 14 '13 at 03:41
@belisarius I guess that could work for me. I do not know how to create the textures on the fly as color and text will be variable in what I want to actually do. I will try to look into Texture and any hints would be appreciated! I hoped I could just use Text and perhaps Glow for the colors in some way. — Ron Burns, Jul 14 '13 at 04:10
Also related: http://mathematica.stackexchange.com/questions/637/character-edge-finding — Sjoerd C. de Vries, Jul 14 '13 at 11:17

score 4 · Answer 1 · edited Apr 13 '17 at 12:55

Graphics3D[
 GraphicsComplex[
  Tuples[{0, 1}, 3],
   MapThread[
    {Texture[
       Graphics[ImportString[ExportString[#1, "PDF"], "PDF"][[1, 1]], Background -> #3]],
     Polygon[#2, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]} &,
    {Characters["ABCDEF"],
     {{1, 2, 4, 3}, {1, 5, 6, 2}, {1, 3, 7, 5}, {8, 6, 5, 7}, {8, 7, 
       3, 4}, {8, 4, 2, 6}},
     Table[Hue[i/6], {i, 6}]}
    ]
   ],
 Lighting -> "Neutral"]

Mathematica graphics

Note that this extracts a FilledCurve from the list of Graphics returned by ImportString (see also this question):

ImportString[ExportString[#1, "PDF"], "PDF"][[1, 1]]

+1 Very clean. The use to which Tuples was put was especially clever! — DavidC, Jul 14 '13 at 06:44

Dr. belisarius · Answer 2 · 2013-07-14T05:01:05.520

0

vtc    =  {{0, 0}, {1, 0}, {1, 1}, {0, 1}};
coords = {{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}}, 
          {{0, 0, 0}, {1, 0, 0}, {1, 0, 1}, {0, 0, 1}}, 
          {{1, 0, 0}, {1, 1, 0}, {1, 1, 1}, {1, 0, 1}}, 
          {{1, 1, 0}, {0, 1, 0}, {0, 1, 1}, {1, 1, 1}}, 
          {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}, {0, 1, 1}}, 
          {{0, 0, 1}, {1, 0, 1}, {1, 1, 1}, {0, 1, 1}}};

tt = Table[Texture@Image[Rasterize@Style[RandomInteger@10, 30]], {i, 6}];
Graphics3D[Table[{tt[[i]], Polygon[coords[[i]],
           VertexTextureCoordinates -> vtc]}, {i, 6}]]

Mathematica graphics

edited Jul 14 '13 at 05:01

answered Jul 14 '13 at 04:29

Dr. belisarius

115,881
13
203
453

Thank you for the example. As posted vtc is not defined, but I am beginning to get the idea anyway. – Ron Burns Jul 14 '13 at 04:57
@RonBurns Sorry, I forgot to paste it. Corrected – Dr. belisarius Jul 14 '13 at 05:01

Embedding text on an opaque plane in 3D

2 Answers2

Linked