Convert Cauchy Riemann equations from cartesian to polar coordinates

Question

We know that the Cauchy Riemann equations in cartesian coordinates are:

$\frac{\partial u}{\partial x}=\frac{\partial v}{\partial y} \quad$ , $\quad \frac{\partial u}{\partial y}=-\frac{\partial v}{\partial x}$

I want to change them to the polar form:

$\frac{\partial u}{\partial \rho}=\frac{1}{\rho} \frac{\partial v}{\partial \varphi}, \quad \frac{\partial u}{\partial \varphi}=-\rho \frac{\partial v}{\partial \rho}$

The following is my code (using DSolveChangeVariables). But the results are very complex. How can I simplify the results to obtain the above form? The result is too long to paste. You can obtain it by running my code.

Clear["Global`*"];
DSolveChangeVariables[
  Inactive[DSolve][{D[u[x, y], x] - D[v[x, y], y] == 0, 
                    D[u[x, y], y] + D[v[x, y], x] == 0}, 
                   {u, v}, {x, y}], 
  {u, v}, {ρ, ϕ}, "Cartesian" -> "Polar"] // Simplify
(*
Inactive[DSolve][{(
   Sin[ϕ] Derivative[0, 1][u][ρ, ϕ] + Cos[ϕ] Derivative[0, 1][v][ρ, ϕ] - 
   ρ Cos[ϕ] Derivative[1, 0][u][ρ, ϕ] + ρ Sin[ϕ] Derivative[1, 0][v][ρ, ϕ])/ρ == 0, 
   (Cos[ϕ] Derivative[0, 1][u][ρ, ϕ] - Sin[ϕ] Derivative[0, 1][v][ρ, ϕ] + 
   ρ Sin[ϕ] Derivative[1, 0][u][ρ, ϕ] + ρ Cos[ϕ] Derivative[1, 0][v][ρ, ϕ])/ρ == 0}, 
     {u, v}, {ρ, ϕ}]
 *)

I have also tried using DChange to solve this problem, but the results are also very complex and I don't know how to simplify it.

score 2 · Accepted Answer · answered Jun 25 '23 at 05:52

expr = DSolveChangeVariables[
        Inactive[DSolve][{D[u[x, y], x] - D[v[x, y], y] == 0, 
                          D[u[x, y], y] + D[v[x, y], x] == 0}, {u, v}, {x, y}], 
        {u, v}, {ρ, ϕ}, "Cartesian" -> "Polar"];

Eliminate[expr[[1]], Derivative[0, 1][v][ρ, ϕ]] // Simplify
(* Derivative[0, 1][u][ρ, ϕ] + ρ Derivative[1, 0][v][ρ, ϕ] == 0 *)
Eliminate[expr[[1]], Derivative[1, 0][v][ρ, ϕ]] // Simplify
(* Derivative[0, 1][v][ρ, ϕ] == ρ Derivative[1, 0][u][ρ, ϕ] *)

Roland F · Answer 2 · 2023-06-25T05:48:05.890

The Euler-Jacobian apparatus of differential transforms is nothing else, but linearizing functions with maps as arguments and switching between maps ad libitum. In this case: Write the Cartesina map functions as polar map of the Cartesian map ${x,y}\to ( r(x,y),\phi(x,y) ) \to f(x,y)$

$$ \text{Solve}\left[\left\{\frac{\partial u\left(\sqrt{x^2+y^2},\tan ^{-1}(x,y)\right)}{\partial x}=\frac{\partial v\left(\sqrt{x^2+y^2},\tan ^{-1}(x,y)\right)}{\partial y},\frac{\partial u\left(\sqrt{x^2+y^2},\tan ^{-1}(x,y)\right)}{\partial y}=-\frac{\partial v\left(\sqrt{x^2+y^2},\tan ^{-1}(x,y)\right)}{\partial x}\right\}\right. $$ $$ \left.\text{//.}\left\{\left(x^2+y^2\right)^{\text{n$\_$}}:\to r^{2 n},\tan ^{-1}(x,y):\to \phi ,x\to r \cos (\phi ),y\to r \sin (\phi ),\text{f$\_$}(r,\phi )\to f\right\},\left\{u^{(1,0)},u^{(0,1)}\right\}\right] $$

$$\left\{\left\{u^{(1,0)}\to \frac{v^{(0,1)}}{r},u^{(0,1)}\to -r v^{(1,0)}\right\}\right\}$$

For copy and paste

Solve[{
 D[u[Sqrt[x^2+y^2 ] ,ArcTan[x,y]],x] ==D[v[Sqrt[x^2+y^2 ],ArcTan[x,y]],y],
 D[u[Sqrt[x^2+y^2 ] ,ArcTan[x,y]],y] == -D[v[Sqrt[x^2+y^2 ],ArcTan[x,y]],x]
} //.
 {  (x^2+y^2)^n_:>r^(2n), ArcTan[x,y]:>\[Phi],
     x->r Cos[\[Phi]],y->rSin[\[Phi]],
     f_[r,\[Phi]]->f},{Derivative[1,0][u],Derivative[0,1][u]
} ]

Of course there is a fast track via conformal maps. Any differentiable complex map respects the Cauchy-Riemann equations, that are nothing more than differentiability in $(z,z^\star) = (x+iy, x-i y ) $ and dependence on one of variables $z$ or $z^\star$ only:

$\partial_{x-i y} f(x+i y) ==0$

$\partial_{u-i v} f(e^{u + i v}) == \partial_u f(e^{u + i v}) - i \partial_v f(e^{u + i v})== 0$

with $r = e^u$ and linearity in the tangent space.

Convert Cauchy Riemann equations from cartesian to polar coordinates

2 Answers2