How can trigonometric equations be solved with PI?

Question

Known conditions: both angles a and b are obtuse angles

AND

\[Pi]/2 < a < \[Pi], \[Pi]/2 < b < \[Pi], 
Sin[a/2]^2 + Cos[a + \[Pi]/3] == (5 - Sqrt[15])/10, 
Sin[b] == Sqrt[10]/10

Required values for angles a+b

Reduce[{\[Pi]/2 < a < \[Pi], \[Pi]/2 < b < \[Pi], 
   Sin[a/2]^2 + Cos[a + \[Pi]/3] == (5 - Sqrt[15])/10, 
   Sin[b] == Sqrt[10]/10, t == a + b}, t, {a, b}, 
  Reals] // FullSimplify

The above methods did not obtain accurate values

To get the value of the question is: (7 π)/4

"The above methods did not obtain accurate values" They're accurate values, but expressed as Root[…]s. Please read this post for more info: https://mathematica.stackexchange.com/a/126156/1871 Since you can read Chinese, read this also: https://tieba.baidu.com/p/7231221217 — xzczd, Jul 26 '23 at 13:11
Please clarify the following: 1. Is my understanding in my previous comment correct? 2. Is your actual goal obtaining (7 π)/4 as the answer? — xzczd, Jul 26 '23 at 23:59
以防你没看懂我的话，我现在用汉语重复一遍：1. 我之前的评论对不对？你是不是误解了Reduce的输出？ 2. 你真正的目标，是不是想让Mathematica输出(7 π)/4作为答案？ — xzczd, Jul 27 '23 at 02:22
如果是的话，你把你的问题改一改写清楚，这个问题是完全可以重开的。当然，如果你觉得你已经拿到你想要的东西了，懒得费时间改帖子，那也是你的自由。 — xzczd, Jul 27 '23 at 02:23
我前面已经说过了，你这问题陈述是错的，Reduce输出的已经是准确答案了，只不过它用了Root来表示它。请注意，跟“准确答案”相对的是“近似答案”！ — xzczd, Jul 27 '23 at 02:41

cvgmt · Accepted Answer · 2023-07-26T13:22:04.930

6

a + b /. 
  First@Solve[{π/2 < a < π, π/2 < b < π, 
     Sin[a/2]^2 + Cos[a + π/3] == (5 - Sqrt[15])/10, 
     Sin[b] == Sqrt[10]/10}, {a, b}, Reals] // FullSimplify

(7 π)/4

edited Jul 26 '23 at 13:22

answered Jul 26 '23 at 13:03

cvgmt

72,231
4
75
133

score 4 · Answer 2 · answered Jul 26 '23 at 13:27

Probably OP won't bother to understand this, but here's a direct fix for OP's approach:

Reduce[{π/2 < a < π, π/2 < b < π, 
  Sin[a/2]^2 + Cos[a + π/3] == (5 - Sqrt[15])/10, Sin[b] == Sqrt[10]/10, 
  t == a + b}, t, {a, b}, Reals] // FullSimplify
% /. 
  a_Root :> Select[x /. Solve[a[[1, 1]][x] == 0, x], # == a[[1, 2]] &][[1]] // 
 Map@FullSimplify
(* t == (7 π)/4 *)

Bob Hanlon · Answer 3 · 2023-07-27T02:09:36.493

$Version

(* "13.3.0 for Mac OS X ARM (64-bit) (June 3, 2023)" *)

Clear["Global`*"]

sys = {π/2 < a < π, π/2 < b < π, 
   Sin[a/2]^2 + Cos[a + π/3] == (5 - Sqrt[15])/10, Sin[b] == Sqrt[10]/10, 
   t == a + b};

sol = Reduce[sys, t, {a, b}, Reals] // FullSimplify // ToRules

Pi*RootApproximant[(t /. sol // N)/Pi]
(* (7 π)/4 *)
sol2 = Map[FullSimplify, Reduce[sys, {t, a, b}, Reals] // ToRules, {2}]
(* {t -> (7 π)/4, a -> 4 ArcTan[2 - Sqrt[5] + Sqrt[10 - 4 Sqrt[5]]], 
 b -> -a + t} *)

Verification is quite slow

sys //. sol2 // FullSimplify // AbsoluteTiming
(* {30.8832, {True, True, True, True, True}} *)

EDIT: Using Backsubstitution

sol2r = Map[FullSimplify, 
  Reduce[sys, {t, a, b}, Reals, Backsubstitution -> True] // ToRules, {2}]
(* {t -> (7 π)/4, a -> 4 ArcTan[2 - Sqrt[5] + Sqrt[10 - 4 Sqrt[5]]], 
 b -> π - ArcCot[3]} *)
sys //. sol2r // FullSimplify // AbsoluteTiming
(* {20.2925, {True, True, True, True, True}} *)

How can trigonometric equations be solved with PI?

3 Answers3

Linked