Issue evaluating integral: seems to lead to incorrect answer

Question

I am trying to compute the integral

$$ F(i, j) = \int_0^1 \phi_i(x) \phi_j(x) dx, \quad \mbox{where}~~ \phi_k(x) = \sqrt{2} \sin\Big(\frac{2 k - 1}{2} \pi x\Big) $$

The integer $k \geq 1$. The answer should be $F(i,j) = \delta_{ij}$ so that $F(i,i) = 1$ for all integers $i \geq 1$ and $F(i,j) = 0$ for positive integers $i \neq j$.

The answer I get from Mathematica is wrong:

In[27]:= EigFun[j_, x_] = Sqrt[2] * Sin[Pi * x * (2*j - 1)/2]
Out[27]= Sqrt[2] Sin[1/2 (-1 + 2 j) [Pi] x]
In[29]:= 
ExpVal[i_, j_] = Integrate[EigFun[i, x] * EigFun[j, x], {x, 0, 1}]
Out[29]= (
Sin[(i - j) [Pi]]/(i - j) - 
 Sin[(-1 + i + j) [Pi]]/(-1 + i + j))/[Pi]
In[30]:= FullSimplify[%29, 
 Assumptions -> {i >= 1 && j >= 1 && i [Element] Integers && 
    j [Element] Integers}]
Out[30]= 0

Is there an easy fix for this? Or what is the explanation for this issue?

Answer 1

The integral behaves reasonably well if one takes limits.

eij = Integrate[EigFun[i, x]*EigFun[j, x], {x, 0, 1}];
limsameij = Limit[eij, j -> i]
Simplify[limsameij, Assumptions -> Element[i, Integers]]
(* Out[324]= 1 + Sin[2 i [Pi]]/((-1 + 2 i) [Pi])
Out[325]= 1 *)
limdiffij = Limit[eij, j -> i + k, Assumptions -> k >= 1]
Simplify[limdiffij, Assumptions -> Element[{i, k}, Integers] && k >= 1]
(* Out[326]= (
Sin[k [Pi]]/k - Sin[(-1 + 2 i + k) [Pi]]/(-1 + 2 i + k))/[Pi]
Out[327]= 0 *)

Answer 2

Clear["Global`*"]

EigFun[j_, x_] = Sqrt[2]*Sin[Pi*x*(2*j - 1)/2];

ExpVal[i_Integer?Positive, j_Integer?Positive] = 
 Evaluate@Assuming[{i, j} ∈ PositiveIntegers,
   Piecewise[{
     {Integrate[EigFun[i, x]*EigFun[j, x], {x, 0, 1}], i != j},
     {Integrate[EigFun[i, x]^2, {x, 0, 1}], i == j}}]]

(* Piecewise[{{0, i != j}, {1, i == j}}, 0] *)

or, more compactly,

ExpVal[i_Integer?Positive, j_Integer?Positive] = 
 Evaluate@Assuming[{i, j} ∈ PositiveIntegers,
   Piecewise[{
       {Integrate[EigFun[i, x]*EigFun[j, x], {x, 0, 1}], i != j},
       {Integrate[EigFun[i, x]^2, {x, 0, 1}], i == j}}] // 
     Simplify]
(* Piecewise[{{0, i != j}}, 1] *)