How to post message about invalid options and return unevaluated input?

Question

Consider this function.

Options[foo]={WorkingPrecision->MachinePrecision};
SyntaxInformation[foo]={"ArgumentsPattern"->{_,OptionsPattern[]}};
foo[expr_,OptionsPattern[foo]]:=
  With[{prec=OptionValue@WorkingPrecision},
  If[TrueQ[0<prec<=Infinity],N[expr,prec],(* else *)Indeterminate]
];

In this case it does what I want.

But when given invalid options, foo should display a message and return what it was given. This is an example.

The Message above can be displayed using this:

Message[foo::optx,PlotRange,
  Inactive@foo[Sqrt[2],WorkingPrecision->20,PlotRange->All]
]

So how do I get my code to find the invalid option and return the expression it was given?

Have you seen CheckArguments[]? Its docs give a model for this sort of behavior under "Applications". — Michael E2, Sep 07 '23 at 15:24
Another example (bit more complicated): https://mathematica.stackexchange.com/a/116633/4999 — Michael E2, Sep 07 '23 at 15:28
Potentially related, although not direct answers to your question: How do I get Mathematica to return a function call unevaluated? and How does MMA return an unevaluated expression on errors without going into an infinite loop?. — MarcoB, Sep 07 '23 at 18:04

score 5 · Accepted Answer · answered Sep 07 '23 at 19:04

CheckArguments was mentioned in a comment, here is how you can modify your code to use it:

ClearAll @ foo;
Options[foo] = {WorkingPrecision -> MachinePrecision};
SyntaxInformation[foo] = {"ArgumentsPattern" -> {_, OptionsPattern[]}};
foo[expr_, o:OptionsPattern[]] /; CheckArguments[foo[expr, o], 1] := With[
    {prec = OptionValue @ WorkingPrecision},
    If[TrueQ[0 < prec <= Infinity],
        N[expr, prec],
        Indeterminate
    ]
];

The pattern /; condition on the left hand side of the := is the key to returning unevaluated.

In[45]:= foo[Sqrt[2], WorkingPrecision -> 20]
Out[45]= 1.4142135623730950488
In[46]:= foo[Sqrt[2], WorkingPrecision -> 20, PlotRange -> All]
During evaluation of In[46]:= foo::optx: Unknown option PlotRange in foo[Sqrt[2],WorkingPrecision->20,PlotRange->All].
Out[46]= foo[Sqrt[2], WorkingPrecision -> 20, PlotRange -> All]

score 1 · Answer 2 · answered Sep 07 '23 at 15:16

This does almost exactly what I asked for

Options[foo]={WorkingPrecision->MachinePrecision};
SyntaxInformation[foo]={"ArgumentsPattern"->{_,OptionsPattern[]}};
foo[expr_,OptionsPattern[foo]]:=Module[{prec,validOptions},
  {prec,validOptions}=Check[{OptionValue[WorkingPrecision],True},{0,False},OptionValue::nodef];
  Which[
    (* Test 1 *)Infinity===prec,expr,
    (* Test 2 *)TrueQ[0<prec<=Infinity],N[expr,prec],
    (* Test 3 *)True,Indeterminate
  ]/;validOptions
];

Now for a screenshot showing how it works.

The second example in the screenshot made the Message. That is good enough, but I still wonder how I could get the names of the invalid options and use them in my Message.

How to post message about invalid options and return unevaluated input?

2 Answers2