How to plot a 3D-subspace of a $\mathbb{C}^2$ curve?

Question

I am trying to visualize the intersection of a complex curve in $\mathbb{C}^2$ with various 3D subspaces but I am not sure how to get Mathematica to do it (so far I have been able to visualize intersections with 2D subspaces using ReIm and ContourPlot). For example, say I have the curve $p^4+qp^2+1=q^8$ in $\mathbb{C^2}$, how would I get Mathematica to plot all values where $p \in \mathbb{R}$ and $q \in \mathbb{C}$?

Thanks in advance!

People here generally like users to post code as copyable Mathematica code as well as images or TeX, so they can copy-paste it. It makes it convenient for them and more likely you will get someone to help you. You may find the meta Q&A, How to copy code from Mathematica so it looks good on this site, helpful — Michael E2, Sep 08 '23 at 21:25

score 2 · Answer 1 · answered Sep 08 '23 at 21:30

Using the method in Plotting implicitly-defined space curves

Block[{F},
 F[p_, q_] := p^4 + q*p^2 - q^8 + 1;
 ContourPlot3D[
  ComplexExpand@ReIm@F[pR + I*pI, qR + I*qI] /. pI -> 0 // Evaluate,
  {pR, -4, 4}, {qR, -4, 4}, {qI, -2, 2},
  MaxRecursion -> 3, PlotPoints -> 25,
  Contours -> {0}, ContourStyle -> Opacity[0], Mesh -> None, 
  BoundaryStyle -> {1 -> None, 
    2 -> None, {1, 2} -> {{Green, Tube[.03]}}}, Boxed -> False]
 ]

How to plot a 3D-subspace of a $\mathbb{C}^2$ curve?

1 Answers1