What is the real default CellEvaluationFunction?

Question

The default CellEvaluationFunction is Identity but one can quickly see that this is handled specially as an equivalent function, (# &), does not work at all the same. The sole example in the documentation uses ToExpression but this also does not work the same, returning only the output of the last line in the Input Cell:

SetOptions[EvaluationNotebook[], CellEvaluationFunction -> ToExpression]

Now in one cell:

2 + 2
5 + 7

12

My question is then: What is the real default function that correctly handles multi-line input/output including the Out[xx]= cell labels?

Answer 1

I don't think you can modify the CellEvaluationFunction to achieve your goal. On the other hand, you can modify MakeExpression instead, as MakeExpression is called on each line of input. So:

MakeExpression[x_,form_] /; !TrueQ@flag && TrueQ@override := Block[{flag=True},
    List/@MakeExpression[x,form]
]

The above code will add a List wrapper to every evaluated expression, but only when the override variable is True:

override = True;
2+2
5+7

{4}

{12}

Setting override back to False will restore the normal behavior:

override = False;
2+2
5+7

{Null}

4

12

Answer 2

The documentations says that "CellEvaluationFunction is applied to the BoxData expression representing the input to be evaluated". So I think Identity is working normally here. See the followings:

SetOptions[EvaluationNotebook[], CellEvaluationFunction -> function]

In[1]:= 2 + 2
        5 + 7

Out[1]= function[BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}], StandardForm]

So, if we take the BoxData structure of the above input, we can do some tests:

Identity[BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}]]
(* BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}] *)

# &[BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}]]
(* BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}] *)

So, Identity sends the expression BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}] to the kernel and it produces the two lines of output with different Out[number] like

In[1]:= 2 + 2
        5 + 7

On the other hand, ToExpression is declared as working on strings and boxes interpreting them as inputs, that means if set as CellEvaluationFunction it manipulates the box structure before to send it to the kernel:

ToExpression[BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}]]

12 

So, I guess Identity is actually the CellEvaluationFunction's default. The only think I cannot understand is why when we set an arbitrary function (like in my first example) as CellEvaluationFunction, the result includes the StandardForm as second argument (function[BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}], StandardForm]) while Identity doesn't accept a second argument and, indeed, it's not used.

EDIT

Using (#&) it fails but using (#)& it works:

SetOptions[EvaluationNotebook[], CellEvaluationFunction -> (# &)]

In[78]:= 2 + 2

Out[78]= BoxData[RowBox[{"2", "+", "2"}]]

In[79]:= 2 + 2
5 + 7

Out[79]= BoxData[{RowBox[{"2", "+", "2"}], RowBox[{"5", "+", "7"}]}]


SetOptions[EvaluationNotebook[], CellEvaluationFunction -> (#) &]

In[74]:= 2 + 2

Out[74]= 4

In[75]:= 2 + 2
5 + 7

Out[75]= 4

Out[76]= 12

Answer 3

The front-end sends a EnterExpressionPacket to the kernel, which contains a expression like MakeExpression[]. As you had found, it has a different behavior to the real MakeExpression which exposed to users.

However, there is a kernel function for users which is able to handle multi-line input:

BoxForm`TopLevelMakeExpression

But it's still not exactly the real default one. For any CellEvaluationFunction except MakeExpression, the kernel

• always single ReturnExpressionPacket except multiple packets
• always use ReturnExpressionPacket instead of ReturnInputFormPacket etc.
• never send OutputNamePacket["Out[1]= //MatrixForm"] etc. for $OutputForms

Seems that CellEvaluationFunction is not a interface good enough for user-customization.