Unable to improve accuracy of MethodOfLines

Question

I'm studying a PDE which roughly models a rope subjected to driving on one end. The coordinate $v$ is related to physical time $t$ via the relation $v=t-x$. I'd like to solve the initial value problem using the method of lines. The following Mathematica code returns a solution, but the accuracy is rather low. Passing the WorkingPrecision option to NDSolveValue throws the following error:

The initialization of the method NDSolve`StateSpace failed

How can one systematically improve the solution accuracy?

Clear["Global`*"]
vmax = 10;
f[v_] := Sin[v]^2;
method := {
   "MethodOfLines",
   "TemporalVariable" -> v,
   "SpatialDiscretization" -> {
     "TensorProductGrid",
     "DifferenceOrder" -> "Pseudospectral", MaxPoints -> 100}};
{timing, uinterp} = Timing@NDSolveValue[{
     2 Derivative[1, 1][u][x, v] == Derivative[2, 0][u][x, v],
     u[x, 0] == 0,
     u[0, v] == f[v],
     u[1, v] == 0}
    , u, {x, 0, 1}, {v, 0, vmax}, Method -> method, MaxStepSize -> 0.1]
Animate[Plot[If[x < t, uinterp[x, t - x], 0], {x, 0, 1}, PlotRange -> {-1, 1.1}, AxesLabel -> {x, u}], {t, 0, vmax}]

Answer 1

Once again, rule of thumb: if NDSolve doesn't work well on solving PDE, and you're sure you haven't made any simple mistake, then usually the problem lies in spatial discretization.

So the WorkingPrecision should be the last thing to touch. Let's adjust the spatial and temporal grid a bit:

mol[n : _Integer | {_Integer ..}, o_ : "Pseudospectral"] := {"MethodOfLines", 
    "SpatialDiscretization" -> {"TensorProductGrid", "MaxPoints" -> n, 
        "MinPoints" -> n, "DifferenceOrder" -> o}}
vmax = 10;
f[v_] := Sin[v]^2;
{timing, uinterp} = 
 Timing@NDSolveValue[{2  Derivative[1, 1][u][x, v] == Derivative[2, 0][u][x, v], 
    u[x, 0] == 0, u[0, v] == f[v], u[1, v] == 0}, u, {x, 0, 1}, {v, 0, vmax}, 
   Method -> mol[200, 2], MaxStepSize -> {Automatic, 0.001}]
(* {0.65625, …} *)
Plot3D[If[x < t, uinterp[x, t - x], 0], {x, 0, 1}, {t, 0, vmax}, 
 PlotRange -> {-1, 1.1}, PlotPoints -> 50, Exclusions -> None]

Animate[Plot[If[x < t, uinterp[x, t - x], 0], {x, 0, 1}, PlotRange -> {-1, 1.1}, 
  AxesLabel -> {x, u}], {t, 0, vmax}]

In example above I've used second order spatial discretization. "Pseudospectral" method can be used if you like, just set e.g. mol[101]. Interestingly, unlike the problem in your previous question, fourth order grid e.g. mol[100, 4] also produces reasonable result.

You can adjust the parameters related to discretization further to see what will happen.