Rotation Slider Control

Question

Mathematica seems to support no "rotation slider" Control which might be used, for instance, in setting an angular direction ($0 \leq \theta \leq 2 \pi$) on a plane. I couldn't find one in the documentation. One can constrain a Slider2D to have a unit length, so that the resulting slider performs as I need, but that seems kludgy and the interface inelegant and non-obvious.

Is there any code creating what we might call a SliderAngle or equivalent, with nice graphics that can be scaled, colored, and such? We should be able to "wind up" the control... that is continually increase the angle clockwise or counterclockwise through multiple revolutions.

see also: Dynamic Linkage of LocatorPane and InputField, Dynamic Linkage of LocatorPane and InputField, How to rotate a graph with a locator? — kglr, Jan 26 '24 at 07:43
try NotebookTools`AngularSliderTest[] to play with features of Experimental`AngularSlider — kglr, Jan 26 '24 at 07:46
Oh... hadn't seen that. Thanks. But I don't see how to use this as a genuine Control (like a Slider or Slider2D). Can you post a minimal Manipulate that rotates a vector using this new slider? Regardless, my recommendation to WRI: incorporate such a true Control into the next release—it would be very useful. — David G. Stork, Jan 26 '24 at 07:57
ClockGauge may be customized to get something close to what you need. — kglr, Jan 26 '24 at 07:58
I tried ClockGauge, but it started getting rather awkward and I never figured out how to use it as a true Control in a Manipulate. — David G. Stork, Jan 26 '24 at 08:01

kglr · Accepted Answer · 2024-01-26T09:28:11.903

Manipulate[
 ParametricPlot[{Cos[x], Sin[3  x]}, {x, 0, 5 Pi}, 
  MeshFunctions -> {#3 &}, 
  Mesh -> {{Abs @ z}},
  PlotLabel -> z, 
  MeshStyle -> Directive[Red, AbsolutePointSize @ 15]], 
{{z, Pi/4}, Experimental`AngularSlider[#] &}]

Manipulate[
 ParametricPlot[{Cos[x], Sin[3  x]}, {x, 0, 5 Pi}, 
  MeshFunctions -> {#3 &}, 
  Mesh -> {{Abs@z}}, 
  PlotLabel -> Style[Round[z, Pi/32], 16], 
  MeshStyle -> Directive[Red, AbsolutePointSize@15]], 
{{z, Pi/4}, 
  Experimental`AngularSlider[#, 
    Appearance -> Dynamic @ Graphics @
       Text[Style[Round[z, Pi/32], 16], {0, 0}, {0, -1.1},  
          - Cross @ {Cos @ z, Sin @ z}], 
    FrameMargins -> 30] &}]

NotebookTools`AngularSliderTest[]

Options[Experimental`AngularSlider] // Column

Alright! I'd expect nothing less from the legendary kglr. Thanks! ($+1$,$\checkmark$) — David G. Stork, Jan 26 '24 at 08:24

Rotation Slider Control

1 Answers1