How to make pdConv not show the independent variables of functions

Question

pdConv is a very good tool.

How to modify pdConv (or a better way is to add an option?) to make the independent variables of the functions not show?

That is, display u[r,θ,z] as u.

Thank you!

pdConv[f_] := 
 TraditionalForm[
  f /. Derivative[inds__][g_][vars__] :> 
    Apply[Defer[D[g[vars], ##]] &, 
     Transpose[{{vars}, {inds}}] /. {{var_, 0} :> 
        Sequence[], {var_, 1} :> {var}}]]

@xzczd Thank you, your method is feasible, but there is a small flaw, the 0th order derivative still displays the independent variables. Could this be improved by modifying pdConv? :) — xinxin guo, Jan 30 '24 at 08:19
Have you read e.g. https://mathematica.stackexchange.com/a/241634/1871 ? — xzczd, Jan 30 '24 at 08:29

xzczd · Accepted Answer · 2024-01-31T08:09:54.130

Clear@pdConv;
pdConv[f_, pat_List] := pdConv[f, Alternatives @@ pat]

defaultpat = _Subscript | _Symbol?(Context[#] === Context[] &);

pdConv[f_, pat_ : defaultpat] := 
 f /. {Derivative[inds__][g : pat][vars__] :> 
     Apply[Defer@
        D[g, ##] &, {{vars}, {inds}}\[Transpose] /. {{var_, 0} :> 
         Sequence[], {var_, 1} :> {var}}], (g : pat)[__] :> g} // TraditionalForm

Please read the document carefully to understand why the code is modified in this manner.

The function can be used in 2 ways. The one-argument syntax should handle most of the usual cases:

D[Subscript[f, 1][x, y], x, x] + D[g[x, y], y] + 
  Subscript[f, 1][x, y] + g[x, y] == 0 // pdConv

For edge cases, set a second argument to specify functions whose independent variables should be omitted:

pdConv[D[\[FormalA][x, y], x] + D[OverTilde[v][x, y], y] + 
       f[\[FormalA][x, y], OverTilde[v][x, y]] == 0, {\[FormalA], OverTilde[v]}]

How to make pdConv not show the independent variables of functions

1 Answers1

Linked