How to get a black transparent background in Plot3D?

Question

Is there a way to manually make a black transparent background like the one in the Marketing theme? As an example, let's say I have the following code:

Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, PlotTheme -> "Marketing"]

which gives me the following result:

Suppose I wish to manually make the transparent black background of the Marketing theme or maybe change it to any other color, or shift the background from back to front or left to right.

How to manually accomplish this task without invoking PlotTheme -> Marketing?

Strongly related: https://mathematica.stackexchange.com/q/51846/1871 https://mathematica.stackexchange.com/q/54545/1871 — xzczd, Feb 22 '24 at 05:17
Look at: https://mathematica.stackexchange.com/questions/17250/how-to-change-plot-style-or-other-options-after-it-was-created — Daniel Huber, Feb 22 '24 at 10:45

azerbajdzan · Answer 1 · 2024-02-23T12:13:55.520

6

This is just for changing the color.

color = ColorData[97, 3];
Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, PlotTheme -> "Marketing"] /. 
 Thread[{GrayLevel[0, 0.5`], GrayLevel[0, 0.7`], 
    GrayLevel[0, 0.9`]} -> {Opacity[0.5, color], Opacity[0.7, color], 
    Opacity[0.9, color]}]

shift the background from back to front or left to right

This would need more work which I am lazy to do.

edited Feb 23 '24 at 12:13

answered Feb 23 '24 at 12:03

azerbajdzan

15,863
1
16
48

score 5 · Answer 2 · answered Feb 24 '24 at 10:34

5

A shorter variant of azerbajdzan's answer

Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, PlotTheme -> "Marketing"] /. 
 GrayLevel[_, _] :> Opacity[1, ColorData[97, 1]]

answered Feb 24 '24 at 10:34

eldo

67,911
5
60
168

score 5 · Accepted Answer · answered Feb 24 '24 at 19:18

I will show how to find out how "Marketing" works. You can adopt and adapt its features to suit yourself.

One can find how a plot theme works as follows:

Charting`ResolvePlotTheme["Marketing", Plot3D] // Map@InputForm // 
 Column[#, Dividers -> All] &
(* output is a somewhat lengthy list of options *)

The style of background in "Marketing" depends on three options, DisplayFunction, FaceGrids, and FaceGridsStyle. The display function manually constructs the rectangles using scaled coordinates so that they always align with faces of the bounding box. You can change the scaled coordinates to change their placement.

DisplayFunction /. Charting`ResolvePlotTheme["Marketing", Plot3D] // InputForm
(*
Charting`noShow[#1, Graphics3D[{{JoinForm["Round"], EdgeForm[{}], 
     Polygon[{Scaled[{0, 0, 0}], Scaled[{0, 1, 0}], Scaled[{1, 1, 0}], 
       Scaled[{1, 0, 0}]}, VertexColors -> {GrayLevel[0, 0.7], GrayLevel[0, 0.9], 
        GrayLevel[0, 0.7], GrayLevel[0, 0.5]}], 
     Polygon[{Scaled[{0, 0, 0}], Scaled[{0, 0, 1}], Scaled[{0, 1, 1}], 
       Scaled[{0, 1, 0}]}, VertexColors -> {GrayLevel[0, 0.9], GrayLevel[0, 0.5], 
        GrayLevel[0, 0.5], GrayLevel[0, 0.9]}], 
     Polygon[{Scaled[{0, 1, 0}], Scaled[{0, 1, 1}], Scaled[{1, 1, 1}], 
       Scaled[{1, 1, 0}]}, VertexColors -> {GrayLevel[0, 0.9], GrayLevel[0, 0.5], 
        GrayLevel[0, 0.5], GrayLevel[0, 0.9]}]}, 
    {Thick, Gray, Line[{Scaled[{0, 0, 0}], Scaled[{0, 1, 0}], 
       Scaled[{0, 1, 1}]}], Line[{Scaled[{0, 1, 0}], Scaled[{1, 1, 0}]}]}}]] &
*)

Extract the background rectangles:

myBackground = 
  Graphics3D[{{JoinForm["Round"], EdgeForm[{}], 
     Polygon[{Scaled[{0, 0, 0}], Scaled[{0, 1, 0}], Scaled[{1, 1, 0}], 
       Scaled[{1, 0, 0}]}, 
      VertexColors -> {GrayLevel[0, 0.7], GrayLevel[0, 0.9], 
        GrayLevel[0, 0.7], GrayLevel[0, 0.5]}], 
     Polygon[{Scaled[{0, 0, 0}], Scaled[{0, 0, 1}], Scaled[{0, 1, 1}], 
       Scaled[{0, 1, 0}]}, 
      VertexColors -> {GrayLevel[0, 0.9], GrayLevel[0, 0.5], 
        GrayLevel[0, 0.5], GrayLevel[0, 0.9]}], 
     Polygon[{Scaled[{0, 1, 0}], Scaled[{0, 1, 1}], Scaled[{1, 1, 1}], 
       Scaled[{1, 1, 0}]}, 
      VertexColors -> {GrayLevel[0, 0.9], GrayLevel[0, 0.5], 
        GrayLevel[0, 0.5], GrayLevel[0, 0.9]}]}, {Thick, Gray, 
     Line[{Scaled[{0, 0, 0}], Scaled[{0, 1, 0}], Scaled[{0, 1, 1}]}], 
     Line[{Scaled[{0, 1, 0}], Scaled[{1, 1, 0}]}]}}];

Instead of using the internal function, use Show for the display function. I copied the face grid and style from the output of ResolvePlotTheme.

Plot3D[Sin[x  y], {x, 0, 3}, {y, 0, 3},
 DisplayFunction -> (Show[#, myBackground] &),
 FaceGrids -> {{-1, 0, 0}, {0, 1, 0}, {0, 0, -1}},
 FaceGridsStyle -> Directive[AbsoluteThickness[1], GrayLevel[0, 0.2]]]

Giving colors to each vertex of the polygons in the background creates a gradient. It makes the back corners look like they're in a shadow. You can remove the vertex color options from the polygons and style them with a plain color if you wish. Or keep the options and change the colors and opacities.

score 1 · Answer 4 · answered Feb 23 '24 at 11:27

1

Try

pic=Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, PlotTheme -> "Marketing"]
AbsoluteOptions[bild, BaseStyle]
(*{BaseStyle -> Specularity[GrayLevel[0.5], 30.]}*)

answered Feb 23 '24 at 11:27

Ulrich Neumann

53,729
2
23
55

Have you tried? What did you get? – azerbajdzan Feb 23 '24 at 11:39
Specularity[GrayLevel[0.5], 30.] – Ulrich Neumann Feb 23 '24 at 11:52
2

I see but show us how to use it to change the background color. – azerbajdzan Feb 23 '24 at 11:55

How to get a black transparent background in Plot3D?

4 Answers4

Linked