Plotting different plot in a single grid frame without combining them

Question

We can show the plot together, but how do we show different plots in the same grid frame without combining them? I have tried the GraphicsColumn and it shows the plots separately.

Answer 1

Show[
 Plot[Sin[x] + 0, {x, 0, 2 Pi}, PlotStyle -> Red],
 Plot[Cos[x] + 2, {x, 0, 2 Pi}, PlotStyle -> Darker @ Green],
 Graphics[AxisObject[{"Horizontal", 0}]],
 Graphics[AxisObject[{"Horizontal", 2}]],
 Frame -> True,
 PlotRange -> All]

Without Ticklabels (like in the image of the question)

Show[
 Plot[Sin[x] + 0, {x, 0, 2 Pi}, PlotStyle -> Red],
 Plot[Cos[x] + 2, {x, 0, 2 Pi}, PlotStyle -> Darker @ Green],
 Graphics[AxisObject[{"Horizontal", 0}, TickLabels -> {None, All}]],
 Graphics[AxisObject[{"Horizontal", 2}, TickLabels -> {None, All}]],
 Frame -> True,
 PlotRange -> All]

Answer 2

You can use the PlotLayout option if the $x$-axis of your plot is not changing instead of using Grid or GraphicsColumn for a column representation.

A sample code:

Plot[{Sin[x], Cos[x] }, {x, 0, 4 Pi}, PlotLayout -> "Column", 
 FrameLabel -> {"x", "y"}, AspectRatio -> 0.5]

However, if I understood the "representation of different plots in the same grid frame without combining them" correctly, what you want is something like this:

data = Table[Sin[x], {x, 0, 4 Pi, 0.1}];
dwd = DiscreteWaveletTransform[data, Automatic, 3]
WaveletListPlot[dwd, PlotLayout -> "CommonXAxis"]

If this is not what you want, please share the equations responsible for the above plot.