How to obtain all definitions in which a symbol appears?

Question

My question is very similar to https://stackoverflow.com/questions/5840313/how-to-get-all-definitions-associated-with-other-symbols except I am looking to find all definitions in which a symbol appears.

I.e. I want an ever more full definition than FullDefinition.

Taking their example:

g[x_] := x^3;
f[x_] := g[x^2];

I want something to return the definition of f[x_] when asking for the fullestDefinition[g]. (Also perhaps a better example would be if f was replaced by CenterDot since I also want to consider built-in functions.)

---

My attempt, which actually works better now than when I started asking this question, but errors are popping up when I start checking the RHS of rules ;) :

SetAttributes[otherValues,HoldFirst]
otherValues[sym_]:=With[{names=MakeExpression/@Names["*"] },
    Join[
        Cases[DownValues@@@names,HoldPattern[RuleDelayed[in_,out_]/;Not[FreeQ[in,sym]]],{2}],
        Cases[SubValues@@@names,HoldPattern[RuleDelayed[in_,out_]/;Not[FreeQ[in,sym]]],{2}],
        Cases[UpValues@@@names,HoldPattern[RuleDelayed[in_,out_]/;Not[FreeQ[in,sym]]],{2}],
        Cases[NValues@@@names,HoldPattern[RuleDelayed[in_,out_]/;Not[FreeQ[in,sym]]],{2}],
        Select[Join@@FormatValues@@@names,!FreeQ[#,HoldPattern@sym]&]]]

---

WReach suggested

Needs["GeneralUtilities`"];
DefinitionCases["Global`", g]

But in the example:

g[x_] := x^3;
CenterDot[x_] := g[x^2];
DefinitionCases["Global`", g]

This does not return the CenterDot definition containing g. I also tried DefinitionCases["*", g] but it returned an empty list.

However, we can search in System`:

DefinitionCases["System`", g]

which returns what we want (but also returns historic In and Output that contains the symbol it would be nice if we could exclude this.).

Answer 1

One way is to use GeneralUtilities`DefinitionCases:

g[x_] := x^3
f[x_] := g[x^2]
CenterDot[x_] := g[x^2]
Needs["GeneralUtilities`"];
DefinitionCases["Global`", g]
(* {HoldPattern[f[x_]] :> g[x^2], HoldPattern[g[x_]] :> x^3} *)

DefinitionCases has some limitations. Notice how the definition for CenterDot was not listed. That is because the symbol is in the System context. We can scan the system context, but there are caveats:

(* not recommended, see discussion *)
Block[{In, Out}, DefinitionCases["System`", g]]

First, we had to block the In and Out symbols to suppress any references to g in the history. Second, and more important, there are a great many auto-loaded symbols in System which trigger side-effects such as connecting to Wolfram cloud, downloading content, etc. In practice, I find the reflection side-effects can be harmful so scanning the system context is not always practical. Beware that any strategy that ends up scanning all symbols can run afoul of these side-effects.

One can also specify DefinitionCases[All, ...] to scan all contexts but it suffers from the same issues as scanning the system context. And it can sometimes take quite a long time as well.

Finally, I will note that there also exists PrintDefinitionCases which produces a human-readable display, But this feature seems to have become neglected in recent releases and the display is not as pretty as it once was.