How to unprotect GeneratingFunction

Question

I'm trying to add custom downvalues for GeneratingFunction, and to do so I thought I just had to Unprotect it. However, that doesn't work:

Unprotect[GeneratingFunction]

{"GeneratingFunction"}

GeneratingFunction[2] = 3

During evaluation of In[3]:= Set::write: Tag GeneratingFunction in 
GeneratingFunction[2] is Protected. >>
3

GeneratingFunction[2]

During evaluation of In[4]:= GeneratingFunction::argmu: GeneratingFunction
called with 1 argument; 3 or more arguments are expected. >>
GeneratingFunction[2]

I'm running Mathematica 9 64 bit on Linux. What do I need to do to really remove protection from this symbol?

score 8 · Accepted Answer · edited May 23 '17 at 12:35

GeneratingFunction by default is not a function: it is a stub which loads corresponding .mx package. You can see this with the following:

ClearAttributes[GeneratingFunction,{Protected,ReadProtected}]
OwnValues@GeneratingFunction

{HoldPattern[GeneratingFunction] :>
System`Dump`AutoLoad[Hold[GeneratingFunction], Hold[GeneratingFunction, GenerateConditions`TopLevelCode], "Discrete`GeneratingFunction`"] /; System`Dump`TestLoad}

The functions ClearAttributes and OwnValues have Hold* attributes and so the above code does not evaluate GeneratingFunction. After first evaluation it's Attributes and Options are redefined by the loaded package:

GeneratingFunction;
Attributes[GeneratingFunction]
Options[GeneratingFunction]

{Protected, ReadProtected}

{Assumptions :> $Assumptions, GenerateConditions -> False, Method -> Automatic, VerifyConvergence -> True}

I do not know why we can't see any top-level code for GeneratingFunction with Information, but Tracing its evaluation reveals a bunch of top-level functions it uses:

Trace[GeneratingFunction[1, n, x], TraceInternal -> True]

For the original discussion of this issue see this answer by Sasha (Wolfram Research) with comments under it.

score 3 · Answer 2 · answered Sep 17 '13 at 21:48

3

I do not know why Unprotectdoes not work (bug, feature?). The following does work though:

ClearAttributes[GeneratingFunction, Protected]
GeneratingFunction[2] = 3
GeneratingFunction[2]

3

answered Sep 17 '13 at 21:48

Hector

6,428
15
34

hmm, that's not working for me – Andrew Sep 17 '13 at 22:37
1

clearing the attribute, attempting to set a value, receiving an error, then clearing the attribute again and setting a value seems to work though – Andrew Sep 17 '13 at 22:39
2

@Andrew May be the situation is similar to this? – Alexey Popkov Sep 18 '13 at 02:11
1

@AndrewMacFie: You need to run it twice so Wolfram can confirm your intentions with absolute certainty. ;-) On a serious note, what kind of "feature" is that?! – Hector Sep 18 '13 at 03:49
@AlexeyPopkov ah yes... this question is very similar to that one – Andrew Sep 18 '13 at 20:24

How to unprotect GeneratingFunction

2 Answers2

Linked

Related