Function to subdivide interval into n evenly-spaced points

Question

[This post needs better tags than I could come up with. Edits to the tags would be particularly welcome.]

I realize that it is trivial to define a function that takes an interval (i.e. two endpoints, $a < b$), and an integer $n > 1$, and returns a list of $n$ evenly spaced points $x_1 = a, x_2, \dots, x_{n-1}, x_n = b$,¹ but still, given that this functionality is frequently needed, and is commonplace in other scientific computing environments, I am surprised not to be able to find a Mathematica built-in for it in the docs.

Did I miss it?

(BTW: I'd love to lay my hand on some stash of such "useful functions that should be included-by-default in Mathematica but aren't".)

¹ For example,

linearmesh[a_, b_, n_Integer /; n > 1] := Range[a, b, (b - a)/(n - 1)]
linearmesh[10, 20, 300] // N // Short
{10.,10.0334,10.0669,10.1003,<<292>>,19.8997,19.9331,19.9666,20.}

Some may prefer this instead:

linearmesh2[a_, b_, n_Integer /; n > 0] := Range[a, b, (b - a)/n]
linearmesh2[10, 20, 300] // N // Short
{10.,10.0333,10.0667,10.1,10.1333,<<292>>,19.9,19.9333,19.9667,20.}

Etc.

I'm sure there are more clueful ways to implement this...

@m_goldberg, instead of pairwise comparison b/w users' desired functions, what about pooling all users and rank ordering preferences. Think of FAQs or even SE which relies on tagging and synonyms to relate similar questions. — alancalvitti, Dec 16 '14 at 14:44

score 22 · Accepted Answer · edited Apr 13 '17 at 12:55

22

The three argument form of Array is convenient and I've used this a few times in different answers (example). The definition is quite simple:

linearmesh[a_, b_, n_Integer] := Array[# &, n, {a, b}]

and it gives you the same answers as your first example. Note that in your second example (with spacing $(b-a)/n$), you have 301 samples. This definition is used when you want 300 partitions, not 300 points.

edited Apr 13 '17 at 12:55

Community

1

answered Sep 20 '13 at 18:03

rm -rf

88,781
21
293
472

P.S. I thought this must have been asked before, but the only post I could find was a question on MATLAB's logspace. – rm -rf Sep 20 '13 at 18:05
2

You can also use Identity instead of # &. – klimenkov Oct 09 '16 at 11:40

score 21 · Answer 2 · edited Jul 01 '15 at 22:05

21

In version 10.1 the function Subdivide was introduced which does precisely that.

Subdivide[10]
(* {0, 1/10, 1/5, 3/10, 2/5, 1/2, 3/5, 7/10, 4/5, 9/10, 1} *)

Subdivide[10, 5]
(* {0, 2, 4, 6, 8, 10} *)

Note that the number 5 equals the number of intervals not the amount of entries in the list (which is higher by one).

edited Jul 01 '15 at 22:05

Mr.Wizard

271,378
34
587
1,371

answered Jul 01 '15 at 21:50

Sjoerd C. de Vries

65,815
14
188
323

Unfortunately, Subdivide is not very convenient when it comes to extremities which you have to handle manually (in contrast to Array). Array[# &, 1, {2, -2}] returns {0} while Subdivide[2, -2, 0] returns error. I could've settle with min or max or mean, but not with an error... – István Zachar Sep 20 '16 at 10:04

score 2 · Answer 3 · answered Dec 16 '14 at 11:41

2

This function works exactly like MATLAB's linspace as it gives you n points (rather than n+1):

linspace[x0_, x1_, n_] := Range[x0, x1, (x1 - x0)/(n - 1)];

answered Dec 16 '14 at 11:41

Eddy

263
3
8

2

How is this different from the OP's linearmesh? – Michael E2 Dec 16 '14 at 12:14

score 1 · Answer 4 · answered Jul 01 '15 at 21:38

1

From the Manual https://reference.wolfram.com/language/ref/FindDivisions.html this can be easily solved:

FindDivisions[{1,10},9]

will produce {1, 2, 3, 4, 5, 6, 7, 8, 9, 10} which are 10 in number though...

answered Jul 01 '15 at 21:38

user30545

11
1

4

The manual also says: "finds a list of about n "nice" numbers that divide the interval around to into equally spaced parts." The keyword here is "about". – Sjoerd C. de Vries Jul 01 '15 at 21:47

Function to subdivide interval into n evenly-spaced points

4 Answers4

Linked

Related