1

I want to look if a term is <0,>0 or ==0. What is wrong when I write

a < 2 b;
b > 0;
a > 0;
TrueQ[Re[(3 a + 6 b + 
    Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
      4 (-45 + 16 a^2) b^2 + 32 ab^3])/4 (a + b)] < 0]

It gives me FALSE every time regardless of whether I say <0,>0 or ==0. But I took the real part, hence it one case has to be TRUE!

For a=2b

Simplify[Re[(-3 a - 6 b + 
   Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
     4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] < 0, 
Assumptions -> {a > 0, b > 0, a = 2 b}]

I get

Re[Sqrt[-9 - 4 b^2 + 16 b^4]] < True

What does this means?

EDIT*EDIT*

For 

Simplify[Re[(-3 a - 6 b + 
   Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
     4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] < 0, 
Assumptions -> {a > 0, b > 0, a == 2 b}]

I get

Re[Sqrt[-9 - 4 b^2 + 16 b^4]] < 2 b

Does this means that this is only true if Re[Sqrt[-9 - 4 b^2 + 16 b^4]] < 2 b

?

Szabolcs
  • 234,956
  • 30
  • 623
  • 1,263
user2098925
  • 13
  • 5
  • 5
    TrueQ returns False for anything that is not explicitly True. Since you have a symbolic expression the truth can not be determined explicitly. – Sjoerd C. de Vries Sep 26 '13 at 15:09
  • What do you think the first three inequalities do here? They do not put any constraints upon a and b in what follows! – murray Sep 26 '13 at 15:19
  • But when a and b >0 and with a=2b you can decide if its larger than 0 or not? Is there a possibility in mathematica to do that? – user2098925 Sep 26 '13 at 15:20
  • the point is your first three lines do not do what you think. In fact they do nothing.. Think about it. – george2079 Sep 26 '13 at 16:34
  • You seem to think that the line a<2b is an assertion, in which you declare a certain truth, but it is not. It is a Boolean test. You may need $Assumptions and a function using them like Simplify. – Sjoerd C. de Vries Sep 26 '13 at 17:03

3 Answers3

6

When you do

a<0

you are not affecting a in any way. i.e. you are not saying to Mathematica 'a is less than zero'. I think that what you intend to do is 

Simplify[Re[(3 a + 6 b + 
       Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
         4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] < 0, 
 Assumptions -> {a > 0, b > 0, a < 2 b}]

This will simplify your expression and, in this case, it returns False. So, your expression is not less than 0 given the constraints.

WalkingRandomly
  • 4,107
  • 1
  • 20
  • 36
5

May be try Assuming as follows:

Assuming[{b > 0, a > 0 && a < 2 b}, 
 Refine[Re[(3 a + 6 b + Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
          4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] > 0]]

Which gives:

True

Whereas

Assuming[{b > 0, a > 0 && a < 2 b}, 
 Refine[Re[(3 a + 6 b + Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
          4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] < 0]]

gives

False

Edit

And for the case a == 2b

 Assuming[{b > 0, a > 0 && a == 2 b}, 
     Refine[Re[(3 a + 6 b + Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
              4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] < 0]]

We get:

False

RunnyKine
  • 33,088
  • 3
  • 109
  • 176
4

You can define global assumptions

$Assumptions = {b > 0, a > 0, a < 2 b};

Re[(3 a + 6 b + 
   Sqrt[9 (-36 + 7 a^2) + 4 a (-27 + 8 a^2)*b + 
     4 (-45 + 16 a^2) b^2 + 32 a b^3])/4 (a + b)] > 0 // Simplify

True

ybeltukov
  • 43,673
  • 5
  • 108
  • 212