Selective evaluation of blocks of code in a Manipulate

Question

Is it possible to attach certain pieces of code to certain controls in a Manipulate? For example, consider the following Manipulate

Manipulate[
 data = Table[function[x], {x, -Pi*10, Pi*10, Pi/1000}];
 ListPlot[{x, data}, PlotRange -> {{start, stop}, Automatic}]
 , {function, {Sin, Cos, Tan}}
 , {start, 1, Length[data]}
 , {{stop, 300}, 1, Length[data]}
 ]

Generation of the data is expensive but it only needs to be done if I change function. So, I'd like the line

data = Table[function[x], {x, -Pi*10, Pi*10, Pi/1000}];

to only run when I change the function control...i.e. I want to attach that line of code to the 'function' control. As it stands, the data is generated when I move the plot range too which is not what I want.

Answer 1

Here's a fairly simple way to fix your Manipulate by applying Dynamic to ListPlot.

Manipulate[
 (* Beep[]; *)
 data = function @ Range[-Pi*10., Pi*10, Pi/1000];
 Dynamic @ ListPlot[data, PlotRange -> {{start, stop}, Automatic}],
 {function, {Sin, Cos, Tan}},
 {start, 1, Length[data]},
 {{stop, 300}, 1, Length[data]},
 {data, ControlType -> None}]

Uncomment Beep[] to hear when data is reevaluated.

There are several questions on this site whose answers discuss using Dynamic for such a purpose. This one is more general than most: Using Refresh[..] with TrackedSymbols

Answer 2

In such cases, you can get better flexibility by switching to a DynamicModule and building up the GUI yourself. Then, you can pull the data generating step out of the plotting dynamic, so that the latter can be manipulated freely without regenerating the data.

DynamicModule[{function = Sin, start, stop = 300, x = Range[-10 Pi, 10 Pi, Pi/100]},
    Dynamic@With[{data = function[x], s = Spacer@10, f = Print@10},
        Panel@Column[{
            Row[{"function", s, Control[{function, {Sin, Cos, Tan}}]}],
            Row[{"start", s, Slider[Dynamic@start, {1, Length@data}]}],
            Row[{"stop", s, Slider[Dynamic@stop, {1, Length@data}]}],
            Dynamic@ListPlot[data, PlotRange -> {{start, stop}, Automatic}, 
                ImageSize -> 400, Background -> White]
        }]
    ]
]

Note that the f = Print@10 is there just to observe evaluation of data. You can check for yourself that nothing is printed when you move the sliders and prints only when the tabs are changed.

Answer 3

This is good reason to use the second argument of dynamics.

Manipulate[     
 function; (*just to allow tracking, since not explicity in the command*)     
 ListLinePlot[data, PlotRange -> {{start, stop}, Automatic}, 
  ImageSize -> 300, ImagePadding -> 30, Frame -> True, 
  FrameLabel -> {{None, None}, {"x", function}}
  ],

 Grid[
  {
   {"function", SetterBar[Dynamic[function, {function = #; 
        data = Table[function[x], {x, -Pi*10, Pi*10, Pi/10}]} &], {Sin, Cos, Tan}]
   },

   {"start", Manipulator[Dynamic[start, {start = #} &], {1, Dynamic@Length@data, 1}],
    Dynamic[start]
   },

   {"stop",Manipulator[Dynamic[stop, {stop = #} &], {300, Dynamic@Length@data, 1}], 
     Dynamic[stop]
   }       
   }],

 {{start, 1}, None},
 {{stop, 300}, None},
 {{data, Table[Sin[x], {x, -Pi*10, Pi*10, Pi/10}]}, None},
 {{function, Sin}, None},
 {{x, Symbol}, None},
 TrackedSymbols :> {function, start, stop}
 ]