Make fraction with selection in denominator

Question

Using ctrl/ you can make a fraction. If you have selected something it will appear in the numerator.

Does there exist a shortcut to make the selected text appear in the denominator instead? If not, is it possible to create a shortcut that does this?

score 2 · Accepted Answer · edited May 23 '17 at 12:35

Update: Just reverse the output of usual Ctrl+/!

Add the following lines to KeyEventTranslations.tr:

Item[KeyEvent["?", Modifiers -> {Control}],
    FrontEndExecute[{
        FrontEndTokenExecute["Fraction"],
        FrontEndTokenExecute["ExpandSelection"],
        NotebookWrite[InputNotebook[], Reverse@NotebookRead@InputNotebook[], Placeholder]
    }], 
    MenuEvaluator -> Automatic       
  ],

and press Ctrl+Shift+/ (? is Shift+/ on my keyboard).

This method is fully compatible with brackets, functions, etc. When nothing is selected the cursor is in the numerator. If you prefer the denominator than use the following

Item[KeyEvent["?", Modifiers -> {Control}],
    FrontEndExecute[{
        FrontEndTokenExecute["Fraction"],
        FrontEndTokenExecute["ExpandSelection"],
        NotebookWrite[InputNotebook[], Reverse@NotebookRead@InputNotebook[]],
        NotebookFind[InputNotebook[], "\[Placeholder]", Previous, AutoScroll -> False]
    }], 
    MenuEvaluator -> Automatic       
  ],

Previous method:

Item[KeyEvent["?", Modifiers -> {Control}],
    FrontEndExecute@Module[{den=NotebookRead@InputNotebook[]},
        If[den=={},
           SelectionMove[InputNotebook[], All, Expression];
           den=NotebookRead@InputNotebook[]];
        If[den=={},den="\[Placeholder]"];
        NotebookWrite[InputNotebook[],FractionBox["\[Placeholder]",den]];
        SelectionMove[InputNotebook[], Previous, Word];
        SelectionMove[InputNotebook[], Next, Character]; 
        SelectionMove[InputNotebook[], All, Character]
    ],
    MenuEvaluator -> Automatic 
  ],

MenuEvaluator -> Automatic is important because without it an unevaluated expression is written.

See also: Customizing Mathematica shortcuts

Nice! You could replace the SelectionMove stuff with Placeholder as third argument of NotebookWrite — ssch, Oct 04 '13 at 15:46
If it works perfectly except one thing: When nothing is selected the cursor should be in the denominator. — Tyilo, Oct 07 '13 at 12:40
@Tyilo I added the version with the cursor in the denominator. — ybeltukov, Oct 07 '13 at 13:04

score 2 · Answer 2 · edited Apr 13 '17 at 12:55

2

Using same approach as Rolf did here

Putting this in KeyEventTranslations.tr does the job:

Item[KeyEvent["?", Modifiers -> {Control}],
 FrontEndExecute@With[
  {nb = InputNotebook[]},
  If[NotebookRead@nb === {},
    SelectionMove[nb, All, Expression];
    If[NotebookRead@nb =!= {}, FrontEndTokenExecute["ExpandSelection"]]
  ];
  NotebookApply[
    nb,
    FractionBox["\[Placeholder]", "\[SelectionPlaceholder]"],
    Placeholder]
 ], MenuEvaluator->Automatic],

Here I used Ctrl+Shift+/ as it for some reason didn't work with Ctrl+\ (I tried with "\\" and "Backslash" perhaps it has another name)

Edit: Took keyboard shortcut from ybeltukov
Edit2: Also "ExpandSelection"

edited Apr 13 '17 at 12:55

Community

1

answered Oct 04 '13 at 11:22

ssch

16,590
2
53
88

I enjoy your approach with NotebookApply (+1). Do you know how to modify it for cases 2 and 3 in my answer? – ybeltukov Oct 04 '13 at 12:24
@ybeltukov No, having trouble with SelectionMove. I think I'll add a check and only use SelectionMove if den == {} – ssch Oct 04 '13 at 12:28
@ybeltukov Now it works as it should, where did you find out about MenuEvaluator? Without it I couldn't use If – ssch Oct 04 '13 at 12:49
@ybeltukov Any ideas how to make things like f[x] work? Currently only ] is selected – ssch Oct 04 '13 at 13:03
1

I could do nothing, until I accidentally came across this post. Then I found many other examples: http://mathematica.stackexchange.com/search?q=KeyEvent+MenuEvaluator – ybeltukov Oct 04 '13 at 13:42
There are many other bad examples: (a+b),a^b, a@b, f[x][y], ... – ybeltukov Oct 04 '13 at 14:02
I found fully compatible method, see my update. – ybeltukov Oct 04 '13 at 15:39
@ssch Doesn't work at all for me, I always get this no matter if I have selected something: http://i.tyilo.com/YR6ZL.png – Tyilo Oct 07 '13 at 12:38
@ssch Nevermind it actually works, but ybeltukov's version is better. – Tyilo Oct 07 '13 at 13:10

Make fraction with selection in denominator

2 Answers2