6

Suppose that I have two plots (e.g., Plot, ListPlot, etc) that cover two regions of space. I would like to display them "stacked" vertically, so that they align nicely in publication-quality form.

Suppose that I am dealing with ListPlot and I have the following data:

xdata = Range[0, 2 Pi, 0.2];
ydata1 = Sin[xdata];
ydata2 = 1 + Sin[xdata];

So for plot1, I will plot Transpose[{xdata, ydata1}]; for plot2, I will plot Transpose[{xdata, ydata2}] (both using ListPlot). Plot1 covers both negative and positive $y$ values, whereas plot2 covers only positive $y$ values; this fact will be important later. For both plots, I will use BaseStyle -> {18, FontFamily -> "Arial"} so that the labels are large and legible. I will also use Frame -> True and will include frame labels with FrameLabel -> {"x (Meter)", "y (Meter)"}.

Now if I do the following...

plot1 = ListPlot[Transpose[{xdata, ydata1}], Frame -> True, 
  FrameLabel -> {"x (Meter)", "y (Meter)"}, 
  BaseStyle -> {18, FontFamily -> "Arial"}, PlotStyle -> Red, ImageSize -> 375]

plot2 = ListPlot[Transpose[{xdata, ydata2}], Frame -> True, 
  FrameLabel -> {"x (Meter)", "y (Meter)"}, 
  BaseStyle -> {18, FontFamily -> "Arial"}, PlotStyle -> Blue, ImageSize -> 375]

...I get the following...

Image1

Notice that above, the frames are not aligned. To fix this, I can specify the same ImagePadding for both plots...

plot1 = ListPlot[Transpose[{xdata, ydata1}], Frame -> True, 
  FrameLabel -> {"x (Meter)", "y (Meter)"}, 
  BaseStyle -> {18, FontFamily -> "Arial"}, PlotStyle -> Red, ImageSize -> 375,
  ImagePadding -> {{70, 10}, {55, 10}}]

plot2 = ListPlot[Transpose[{xdata, ydata2}], Frame -> True, 
  FrameLabel -> {"x (Meter)", "y (Meter)"}, 
  BaseStyle -> {18, FontFamily -> "Arial"}, PlotStyle -> Blue, ImageSize -> 375,
  ImagePadding -> {{70, 10}, {55, 10}}]

...which gives me the following output...

Image2

Now the frames are nicely aligned. However, the $y$ axis frame labels are not aligned. This is because plot1 includes negative $y$ values in addition to positive ones, and the negative signs "push away" the $y$ axis frame label (i.e., "y (Meter)") in plot1.

So, my question is: is it possible to somehow align the $y$ axis frame labels? Apparently, ImagePadding does not do the trick for that particular issue. Thanks for your time.

Andrew
  • 10,569
  • 5
  • 51
  • 104
  • This is hardly noticeable ... Could you put y-label on the right perhaps? FrameLabel -> {"x (Meter)", None, None, "y (Meter)"} – BoLe Oct 12 '13 at 18:09
  • 1
    Bad trick #2: FrameTicks -> {Automatic, {{.5, "+\[VeryThinSpace]0.5"}}}. – BoLe Oct 12 '13 at 18:12

1 Answers1

5

You could use Labeled to label the frame. Then the ImagePadding trick will work.

xdata = Range[0, 2 Pi, 0.2];
ydata1 = Sin[xdata];
ydata2 = 1 + Sin[xdata];
imsize = 375;
impad = {{40, 10}, {25, 10}};

plot1 = Labeled[
  ListPlot[Transpose[{xdata, ydata1}], Frame -> True, 
   BaseStyle -> {18, FontFamily -> "Arial"}, PlotStyle -> Red, 
   ImageSize -> imsize, ImagePadding -> impad],
  {"x (Meter)", "y (Meter)"}, {Bottom, Left}, RotateLabel -> True, 
  LabelStyle -> {18, FontFamily -> "Arial"}
  ]

plot2 =
 Labeled[
  ListPlot[Transpose[{xdata, ydata2}], Frame -> True, 
   PlotStyle -> Blue, BaseStyle -> {18, FontFamily -> "Arial"}, 
   ImageSize -> imsize, ImagePadding -> impad],
  {"x (Meter)", "y (Meter)"}, {Bottom, Left}, RotateLabel -> True, 
  LabelStyle -> {18, FontFamily -> "Arial"}
  ]

Mathematica graphics

Michael E2
  • 235,386
  • 17
  • 334
  • 747