What is the fastest way to replace all zeros in a matrix?

Question

In the following matrix m every 0 should be replaced with a 1:

m = {{0,1,2},{5,0,3},{8,0,0}}

Desired result:

m' = {{1,1,2},{5,1,3},{8,1,1}}

What is the fastest way to do this for a matrix with 200-1000 elements?

bill s · Accepted Answer · 2013-10-24T15:11:54.017

13

m + 1 - Unitize[m]

might be faster because it preserves packed arrays, but we'd need a real test.

edited Oct 24 '13 at 15:11

answered Oct 24 '13 at 15:04

bill s

68,936
4
101
191

You likely need Unitize in place of UnitStep. – Leonid Shifrin Oct 24 '13 at 15:09
This is wrong if the matrix contains negative integers. Like @LeonidShifrin said, Unitize is the correct function here. – RunnyKine Oct 24 '13 at 15:10
@Leonid Shifrin and RunnyKine - thanks. Indeed, I was taking the example quite literally -- Unitize is more general and does handle negative numbers. – bill s Oct 24 '13 at 15:13
It's definitely fast so +1. – RunnyKine Oct 24 '13 at 15:16
For me this is the fastest – Danvil Oct 26 '13 at 15:42

Leonid Shifrin · Answer 2 · 2013-10-24T16:42:21.980

6

Just for fun: the following hack is even slightly faster than the solution using Unitize and vectorization, on really large matrices:

replaceZeros[m_?MatrixQ] := 
   Normal[
      SparseArray[m] /. HoldPattern[SparseArray[s___]] :>
          Module[{parts = {s}},
            parts[[3]] = 1;
            SparseArray @@ parts
          ]
   ];

but, in this forms at least, it explicitly uses the fact that elements being replaced are zeros. This is just for fun, in any case.

edited Oct 24 '13 at 16:42

answered Oct 24 '13 at 15:33

Leonid Shifrin

114,335
15
329
420

Unitize is twice as fast on my PC for 10^7 element matrix. – RunnyKine Oct 24 '13 at 15:36
@RunnyKine I used also 10^7 elements, and on my machine (Mac OS X 10.7.5 64 bit), Unitize is about 10-20 % slower. Which version of Mathematica you used? – Leonid Shifrin Oct 24 '13 at 15:40
Perhaps you 2 used different proportion of zeros? If lots of zeros probably Leonid's wins, and viceversa – Rojo Oct 24 '13 at 15:46
I'm using V9.0.1 Windows 8.1 64bit – RunnyKine Oct 24 '13 at 15:46
@Rojo Yes, I already noticed that too. But even if the zeros are very scarce, on my machine my code then is just the same speed as the one with Unitize. – Leonid Shifrin Oct 24 '13 at 15:47
@RunnyKine Well, I am using a different M version - this could be the reason for the difference, apart from a different platform. – Leonid Shifrin Oct 24 '13 at 15:48
I suppose, since I've tried different generation of the matrix (even limiting the Random generator to only 0 and 1) and every time, Unitize is at least twice as fast on my machine. – RunnyKine Oct 24 '13 at 15:50
If the element to be replaced were a common element, then I don't see why it would kill the speed advantage. Just change the common element using SparseArray[m, Automatic, toBeReplaced], instead. – rcollyer Oct 24 '13 at 16:35
@rcollyer Yes, you are right, and I was wrong. Still, this is a hack, because it uses the implementation details of SparseArray to achieve its goals. But I like it. – Leonid Shifrin Oct 24 '13 at 16:41
Dangit, I wanted to post this. +1 :-) – Mr.Wizard Oct 24 '13 at 19:12
Hack, yes. Useful, yes. +1 – rcollyer Oct 24 '13 at 22:29

score 4 · Answer 3 · answered Oct 24 '13 at 14:56

4

m = {{0, 1, 2}, {5, 0, 3}, {8, 0, 0}} /. 0 -> 1
{{1, 1, 2}, {5, 1, 3}, {8, 1, 1}}

It's certainly the fastest to write down.

answered Oct 24 '13 at 14:56

bill s

68,936
4
101
191

Why //. instead of /.? – Timothy Wofford Oct 24 '13 at 14:56
@Timothy Wofford -- habit, I guess. /. is shorter. Rojo -- habit again. I"m always nervous when a white space means something though, as in: /. 0->1 is OK but /.0->1 is not. – bill s Oct 24 '13 at 14:58
For me /. is 25% faster than //. – Danvil Oct 24 '13 at 15:02

score 3 · Answer 4 · answered Oct 24 '13 at 15:00

3

Replace[m, 0 -> 1, Infinity]

{{1, 1, 2}, {5, 1, 3}, {8, 1, 1}}

answered Oct 24 '13 at 15:00

RunnyKine

33,088
3
109
176

Pankaj Sejwal · Answer 5 · 2013-10-24T17:03:52.577

0

{{0, 1, 2}, {5, 0, 3}, {8, 0, 0}} //. {a___, 0, b___} -> {a, 1, b}

{{1, 1, 2}, {5, 1, 3}, {8, 1, 1}}

For,

RandomInteger[0, {100000, 3}] //. {a___, 0, b___} -> {a, 1, b};

2.62 Sec

edited Oct 24 '13 at 17:03

answered Oct 24 '13 at 16:57

Pankaj Sejwal

2,063
14
23

Try with RandomInteger[{0, 5}, {10^7, 3}] – RunnyKine Oct 24 '13 at 17:13
@RunnyKine : ya you seem to be right, upto 10^6 its taking 16 sec, after that sort of bottleneck. – Pankaj Sejwal Oct 24 '13 at 17:28

What is the fastest way to replace all zeros in a matrix?

5 Answers5

Linked