How to determine coordinates of a shape in an image?

Question

I have a pre-processed image, from which I have to get coordinates of some components.

sample image

There are 7 green components (pigs actually) that I have already isolated from an angry bird screen shot. So what I want is to locate those six components on the image.

I tried

ImageValuePositions[u, RGBColor[1, 0, 0], .1]
{ Mean[#1], Mean[#2]}& @@@ Transpose /@ FindClusters[%];
LocatorPane[ %, sample image]

But it doesn't work at all. Could anyone help me out?

sample2

How should I figure this out?

"There are 7 green components (pigs actually)" .... "what I want is to locate those six components" ... So ... six or seven? Do you want partial matches or not? — Dr. belisarius, Nov 11 '13 at 14:24

Dr. belisarius · Answer 1 · 2013-11-11T04:51:27.250

6

Show[i, Graphics@{PointSize[Large], 
                  Point@ComponentMeasurements[
                           MorphologicalComponents[DeleteSmallComponents[
                                        ChanVeseBinarize[i, TargetColor -> Green], 10]], 
                           "Centroid"][[All, 2]]}]

Mathematica graphics

Edit

You can specify a convex method for the morph. components and then you won't need deleting the small components:

Show[i, Graphics@{PointSize[Medium], 
                  Point@ComponentMeasurements[
                           MorphologicalComponents[
                              ChanVeseBinarize[i, TargetColor -> Green], 
                           Method -> "Convex"],
                        "Centroid"][[All, 2]]}]

Mathematica graphics

edited Nov 11 '13 at 04:51

answered Nov 11 '13 at 03:22

Dr. belisarius

115,881
13
203
453

Thank you, that's really fancy!! – user10495 Nov 11 '13 at 08:01
It seems like when I apply this method, it can only detect two black dots, maybe because they are not separated? HELP ME !!! Thank you so much – user10495 Nov 11 '13 at 08:19
I mean the new picture I posted above. – user10495 Nov 11 '13 at 08:36

bill s · Answer 2 · 2013-11-11T04:50:56.627

Here's an approach quite similar to what you tried. First, allG is all the green points which are then clustered into the 7 groups called clus. The mean of each group provides an approximation to the central point of the clusters.

img=Import["https://i.stack.imgur.com/uO8QJ.png"];
allG = ImageValuePositions[img, Green];
clus = FindClusters[allG, 7];
Mean[clus[[#]]] & /@ Range[7]
{{182.542, 179.264}, {288.831, 20.1529}, {299.942, 18.1395}, {315.611, 15.8951}, 
 {255.067, 13.1082}, {230.66, 5.70168}, {255.8, 4.24286}}

Consolidating this into one command yields:

Mean[FindClusters[ImageValuePositions[img, Green], 7][[#]]] & /@ Range[7]

which gives the same answer as above.

How to determine coordinates of a shape in an image?

2 Answers2