How to select three points $A$, $B$, $C$ from the following list so that the circle passing $A$, $B$, $C$ has centre $(1,2,3)$?

Question

I have the sphere $$(x-1)^2 + (y-2)^2 + (z-3)^2 = 36.$$ From the sphere, I find some points with integral coordinates. And select three points from this list so that the triangles are not right triangle. I tried

ClearAll[a, b, r];
a = 1;
b = 2;
c = 3;
r = 6;
ss = Subsets[{x, y, z} /. 
    Solve[{(x - a)^2 + (y - b)^2 + (z - c)^2 == r^2, x != a, y != b, 
      z != c}, {x, y, z}, Integers], {3}];
Pick[ss, (FreeQ[#, \[Pi]/2] &) /@ ({VectorAngle[#2 - #1, #3 - #1], 
      VectorAngle[#1 - #2, #3 - #2], 
      VectorAngle[#1 - #3, #2 - #3]} & @@@ ss)]

Now, I want to select three points $A$, $B$, $C$ so that the circle passing through points $A$, $B$, $C$ take the point $(1,2,3)$ as its centre. How can I select them?

You are wrong. For example three points (-3, -2, 1), (-3, -2, 5) and (-3, 0, -1) has centre (-3,2,3). — minthao_2011, Nov 15 '13 at 14:59
You can find such points by writing 36 as a sum of three squares, and adding the integer square roots to the center coordinates. Choose one pair to be polar opposites (to enforce that the circle be a great circle), and take any third such point. — Daniel Lichtblau, Nov 15 '13 at 16:58
@SjoerdC.deVries Please check my code. Am I wrong? I want to choose the triangles aree not right triangle. — minthao_2011, Nov 16 '13 at 16:13
36 = 4^2+4^2+4^2 so (4,4,2) + (1,2,3) = (5,6,5) and (-4,-4,-2) + (1,2,3) = (-3,-2,1) are on the sphere and are polar opposites. Also 36 = 5^2+3^2+0^2 so (5,3,0) + (1,2,3) = (6,5,3) is on the sphere. That gives a third point on a great circle for the sphere in question. — Daniel Lichtblau, Nov 17 '13 at 19:41

Dr. belisarius · Answer 1 · 2013-11-17T14:31:09.273

1

By using a circumcenter formula:

(* Your code *)
ClearAll[a, b, r];
a = 1;  b = 2; c = 3; r = 6;
ss = Subsets[{x, y, z} /. 
    Solve[{(x - a)^2 + (y - b)^2 + (z - c)^2 == r^2, x != a, y != b, z != c}, {x, y, z}, Integers], {3}];
tt = Pick[
   ss, (FreeQ[#, π/2] &) /@ ({VectorAngle[#2 - #1, #3 - #1], 
        VectorAngle[#1 - #2, #3 - #2], 
        VectorAngle[#1 - #3, #2 - #3]} & @@@ ss)];

(* and now *)
circumCoords[{A_, B_, C_}] := Module[{a = A - C, b = B - C},
         Cross[(Norm[a]^2 b - Norm[b]^2 a), Cross[a, b]]/(2 Norm[Cross[a, b]]^2) + C]
tt1 = Quiet@Select[Tuples[Union@Flatten[tt, 1], {3}], circumCoords[#] == {1, 2, 3} &]

edited Nov 17 '13 at 14:31

answered Nov 15 '13 at 15:18

Dr. belisarius

115,881
13
203
453

@belisarus You wrote Flatten[tt, 1], {3}]. What is the tt? – minthao_2011 Nov 16 '13 at 15:42
@minthao_2011 tt is your Pick[...] – Dr. belisarius Nov 17 '13 at 05:07
I check some circle. It's wrong. That is mean center not at $(1,2,3). – minthao_2011 Nov 17 '13 at 05:42
For example {-3, 4, -1}, {-1, 6, 7}, {3, 6, 7} – minthao_2011 Nov 17 '13 at 05:51
Maybe my Pick[...] is wrong. Please help me. – minthao_2011 Nov 17 '13 at 05:59
@minthao_2011 See edit – Dr. belisarius Nov 17 '13 at 14:31
I want the triangle ABC is not a right triangle. But with three vertices {{-3, -2, 1}, {-3, -2, 5}, {5, 6, 1}}, this is a right triangle. where is wrong in my code? – minthao_2011 Nov 17 '13 at 15:19
1

@minthao_2011 Sorry, I don't understand your last comment – Dr. belisarius Nov 17 '13 at 19:12
@minthao_2011 Ok, I understand now. You want to exclude "right" (Pi/2) triangles ... Let's see how. – Dr. belisarius Nov 17 '13 at 19:36
let us continue this discussion in chat – minthao_2011 Nov 18 '13 at 04:20

Michael E2 · Accepted Answer · 2013-11-17T19:29:39.330

From where you are...

ClearAll[a, b, r];
a = 1;
b = 2;
c = 3;
r = 6;
ss = Subsets[{x, y, z} /. 
    Solve[{(x - a)^2 + (y - b)^2 + (z - c)^2 == r^2, x != a, y != b, 
      z != c}, {x, y, z}, Integers], {3}];
nonright = Pick[ss, (FreeQ[#, \[Pi]/2] &) /@ ({VectorAngle[#2 - #1, #3 - #1], 
      VectorAngle[#1 - #2, #3 - #2], 
      VectorAngle[#1 - #3, #2 - #3]} & @@@ ss)];

...the easiest way is to pick the triangles that are coplanar with the center {1, 2, 3}:

Pick[
 nonright,
 Det /@ Map[# - {1, 2, 3} &, nonright, {2}],
 0]

Coplanarity is detected by translating the figure so that the center {1, 2, 3} moves to the origin.

Alternatively, one can select them directly from ss. In addition to picking triangles coplanar with the center, we must exclude ones for which an edge is collinear with the center. (If a side were collinear with the center, the side would be a diagonal and the triangle would be right.)

Here we test the ranks of several matrices form by coordinates of three points chosen in all possible ways from the center and three vertices of a triangle, where as above the figure has been translated so that the center is at the origin. The total of the ranks should be 8. (It may take a little thought to convince yourself this is correct. One key observation is that if two points on the sphere are collinear with the center, then the center of the circle passing through the vertices of the triangle is the center of the sphere, and in fact the triangle is right.)

Pick[
  ss,
  Total[MatrixRank /@ 
      Table[Delete[Transpose@(Transpose@# - {1, 2, 3})~Append~{0, 0, 0}, i],
            {i, 4}]] & /@ ss,
  8]

Unfortunately, there are no such triangles.

Your code spits out some errors here. Is it me? – Dr. belisarius Nov 17 '13 at 19:18 — Dr. belisarius, Nov 17 '13 at 19:18
@belisarius No, I copied the wrong lines...Thanks! – Michael E2 Nov 17 '13 at 19:30 — Michael E2, Nov 17 '13 at 19:30

How to select three points $A$, $B$, $C$ from the following list so that the circle passing $A$, $B$, $C$ has centre $(1,2,3)$?

2 Answers2